[gentoo-commits] gentoo-x86 commit in net-analyzer/nagios-plugins: ChangeLog nagios-plugins-1.4.10.ebuild nagios-plugins-1.4.9.ebuild

[Tobias Scherbaum (dertobi123)]

dertobi123    07/09/29 09:11:00

  Modified:             ChangeLog
  Added:                nagios-plugins-1.4.10.ebuild
  Removed:              nagios-plugins-1.4.9.ebuild
  Log:
  Version bump, fix quoting, 1.4.10 fixes a buffer overflow vulnerability in its check_http plugin
  (Portage version: 2.1.3.9)

Revision  Changes    Path
1.70                 net-analyzer/nagios-plugins/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/nagios-plugins/ChangeLog?rev=1.70&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/nagios-plugins/ChangeLog?rev=1.70&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/nagios-plugins/ChangeLog?r1=1.69&r2=1.70

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/nagios-plugins/ChangeLog,v
retrieving revision 1.69
retrieving revision 1.70
diff -u -r1.69 -r1.70
--- ChangeLog	30 Jun 2007 16:36:32 -0000	1.69
+++ ChangeLog	29 Sep 2007 09:10:59 -0000	1.70
@@ -1,6 +1,14 @@
 # ChangeLog for net-analyzer/nagios-plugins
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nagios-plugins/ChangeLog,v 1.69 2007/06/30 16:36:32 dertobi123 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nagios-plugins/ChangeLog,v 1.70 2007/09/29 09:10:59 dertobi123 Exp $
+
+*nagios-plugins-1.4.10 (29 Sep 2007)
+
+  29 Sep 2007; Tobias Scherbaum <dertobi123@g.o>
+  +files/nagios-plugins-1.4.10-contrib.patch, -nagios-plugins-1.4.9.ebuild,
+  +nagios-plugins-1.4.10.ebuild:
+  Version bump, fix quoting, 1.4.10 fixes a buffer overflow vulnerability in
+  its check_http plugin
 
   30 Jun 2007; Tobias Scherbaum <dertobi123@g.o>
   nagios-plugins-1.4.8-r1.ebuild, nagios-plugins-1.4.9.ebuild:



1.1                  net-analyzer/nagios-plugins/nagios-plugins-1.4.10.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/nagios-plugins/nagios-plugins-1.4.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/nagios-plugins/nagios-plugins-1.4.10.ebuild?rev=1.1&content-type=text/plain

Index: nagios-plugins-1.4.10.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nagios-plugins/nagios-plugins-1.4.10.ebuild,v 1.1 2007/09/29 09:10:59 dertobi123 Exp $

WANT_AUTOCONF="latest"
WANT_AUTOMAKE="latest"

inherit eutils autotools

DESCRIPTION="Nagios $PV plugins - Pack of plugins to make Nagios work properly"
HOMEPAGE="http://www.nagios.org/"
SRC_URI="mirror://sourceforge/nagiosplug/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="ssl samba mysql postgres ldap snmp nagios-dns nagios-ntp nagios-ping
nagios-ssh nagios-game ups ipv6 radius"

DEPEND="ldap? ( >=net-nds/openldap-2.0.25 )
	mysql? ( virtual/mysql )
	postgres? ( >=dev-db/postgresql-7.2 )
	ssl? ( >=dev-libs/openssl-0.9.6g )
	radius? ( >=net-dialup/radiusclient-0.3.2 )"

RESTRICT="test"

RDEPEND="${DEPEND}
	>=dev-lang/perl-5.6.1-r7
	samba? ( >=net-fs/samba-2.2.5-r1 )
	snmp? ( >=dev-perl/Net-SNMP-4.0.1-r1
			>=net-analyzer/net-snmp-5.0.6
			)
	mysql? ( dev-perl/DBI
			 dev-perl/DBD-mysql )
	nagios-dns? ( >=net-dns/bind-tools-9.2.2_rc1 )
	nagios-ntp? ( >=net-misc/ntp-4.1.1a )
	nagios-ping? ( >=net-analyzer/fping-2.4_beta2-r1 )
	nagios-ssh? ( >=net-misc/openssh-3.5_p1 )
	ups? ( >=sys-power/nut-1.4 )
	!sparc? ( nagios-game? ( >=games-util/qstat-2.6 ) )"

pkg_setup() {
	enewgroup nagios
	enewuser nagios -1 /bin/bash /var/nagios/home nagios
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	if ! use radius; then
		EPATCH_OPTS="-p0 -d ${S}" epatch \
			${FILESDIR}/nagios-plugins-1.4-noradius.patch
	fi

	epatch ${FILESDIR}/${PN}-1.4.10-contrib.patch

	AT_M4DIR="m4 gl/m4" eautoreconf
}

src_compile() {

	local conf
	if use ssl; then
		conf="${conf} --with-openssl=/usr"
	else
		conf="${conf} --without-openssl"
	fi

	econf \
		$(use_with mysql) \
		$(use_with postgres) \
		$(use_with ipv6) \
		${conf} \
		--host=${CHOST} \
		--prefix=/usr/nagios \
		--sysconfdir=/etc/nagios \
		--infodir=/usr/share/info \
		--mandir=/usr/share/man || die "econf failed"

	# fix problem with additional -
	sed -i -e 's:/bin/ps -axwo:/bin/ps axwo:g' config.h || die "sed failed"

	emake || die "emake failed"
}

src_install() {
	mv "${S}"/contrib/check_compaq_insight.pl "${S}"/contrib/check_compaq_insight.pl.msg
	chmod +x "${S}"/contrib/*.pl

	sed -i -e '1s;#!.*;#!/usr/bin/perl -w;' "${S}"/contrib/*.pl || die "sed failed"
	sed -i -e '30s/use lib utils.pm;/use utils;/' \
		"${S}"/plugins-scripts/check_file_age.pl || die "sed failed"

	dodoc ABOUT-NLS ACKNOWLEDGEMENTS AUTHORS BUGS CHANGES CODING COPYING \
		Changelog FAQ INSTALL LEGAL NEWS README REQUIREMENTS SUPPORT

	emake DESTDIR="${D}" install || die "make install failed"

	if use mysql || use postgres; then
		dodir /usr/nagios/libexec
		exeinto /usr/nagios/libexec
		doexe "${S}"/contrib/check_nagios_db.pl
	fi

	dodir /usr/nagios/libexec/
	mv "${S}"/contrib "${D}"/usr/nagios/libexec/contrib

	chown root:nagios "${D}"/usr/nagios || die "Failed Chown of ${D}usr/nagios"
	chown -R root:nagios "${D}"/usr/nagios/libexec || die "Failed Chown of ${D}usr/nagios/libexec"

	chmod -R o-rwx "${D}"/usr/nagios/libexec || die "Failed Chmod of ${D}usr/nagios/libexec"

	chmod 04710 "${D}"/usr/nagios/libexec/check_icmp || die "Failed Chmod of ${D}usr/nagios/libexec/check_icmp"
}

pkg_postinst() {
	einfo "This ebuild has a number of USE flags which determines what nagios is able to monitor."
	einfo "Depending on what you want to monitor with nagios, some or all of these USE"
	einfo "flags need to be set for nagios to function correctly."
	echo
	einfo "contrib plugins are installed into /usr/nagios/libexec/contrib"
}



-- 
gentoo-commits@g.o mailing list