[gentoo-commits] gentoo-x86 commit in media-gfx/ufraw: ufraw-0.19.2.ebuild ChangeLog

[Markus Meier (maekke)]

maekke      13/03/28 20:48:36

  Modified:             ChangeLog
  Added:                ufraw-0.19.2.ebuild
  Log:
  version bump
  
  (Portage version: 2.1.11.57/cvs/Linux x86_64, signed Manifest commit with key 072AD062)

Revision  Changes    Path
1.104                media-gfx/ufraw/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/ufraw/ChangeLog?rev=1.104&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/ufraw/ChangeLog?rev=1.104&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/ufraw/ChangeLog?r1=1.103&r2=1.104

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/ufraw/ChangeLog,v
retrieving revision 1.103
retrieving revision 1.104
diff -u -r1.103 -r1.104
--- ChangeLog	13 Mar 2013 20:39:49 -0000	1.103
+++ ChangeLog	28 Mar 2013 20:48:36 -0000	1.104
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/ufraw
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/ufraw/ChangeLog,v 1.103 2013/03/13 20:39:49 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/ufraw/ChangeLog,v 1.104 2013/03/28 20:48:36 maekke Exp $
+
+*ufraw-0.19.2 (28 Mar 2013)
+
+  28 Mar 2013; Markus Meier <maekke@g.o> +ufraw-0.19.2.ebuild:
+  version bump
 
 *ufraw-0.19.1 (13 Mar 2013)
 



1.1                  media-gfx/ufraw/ufraw-0.19.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/ufraw/ufraw-0.19.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/ufraw/ufraw-0.19.2.ebuild?rev=1.1&content-type=text/plain

Index: ufraw-0.19.2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/ufraw/ufraw-0.19.2.ebuild,v 1.1 2013/03/28 20:48:36 maekke Exp $

EAPI=5
inherit autotools eutils fdo-mime gnome2-utils

DESCRIPTION="RAW Image format viewer and GIMP plugin"
HOMEPAGE="http://ufraw.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x64-solaris ~x86-solaris"
IUSE="contrast fits gimp gnome gtk openmp timezone"

RDEPEND="dev-libs/glib:2
	>=media-gfx/exiv2-0.11
	virtual/jpeg
	media-libs/lcms:0
	>=media-libs/lensfun-0.2.5
	media-libs/tiff
	fits? ( sci-libs/cfitsio )
	gnome? ( >=gnome-base/gconf-2 )
	gtk? ( >=x11-libs/gtk+-2.6:2
		>=media-gfx/gtkimageview-1.5 )
	gimp? ( >=x11-libs/gtk+-2.6:2
		>=media-gfx/gtkimageview-1.5
		>=media-gfx/gimp-2 )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-0.17-cfitsio-automagic.patch
	eautoreconf
}

src_configure() {
	econf \
		--without-cinepaint \
		$(use_enable contrast) \
		$(use_with fits cfitsio) \
		$(use_with gimp) \
		$(use_enable gnome mime) \
		$(use_with gtk) \
		$(use_enable openmp) \
		$(use_enable timezone dst-correction) \
		$(usex gimp --with-gtk "")
}

src_install() {
	emake DESTDIR="${D}" schemasdir=/etc/gconf/schemas install
	dodoc README TODO
}

pkg_preinst() {
	if use gnome; then
		gnome2_gconf_savelist
	fi
}

pkg_postinst() {
	if use gnome; then
		fdo-mime_mime_database_update
		fdo-mime_desktop_database_update
		gnome2_gconf_install
	fi
}

pkg_postrm() {
	if use gnome; then
		fdo-mime_desktop_database_update
		fdo-mime_mime_database_update
	fi
}