[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     2818716fdfab455fbb00764a8ac2c0eb271eeb75
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu May 13 16:50:41 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu May 13 16:52:49 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2818716f

sys-kernel/gentoo-kernel-bin: bump to 5.4.118 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.4.118-r1.ebuild            | 114 +++++++++++++++++++++
 2 files changed, 115 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 5e863d312a1..0d561b4dd97 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -34,6 +34,7 @@ DIST gentoo-kernel-5.4.117-1.amd64.xpak 61429059 BLAKE2B d1e21f821c2c0408fe34f4a
 DIST gentoo-kernel-5.4.117-1.arm64.xpak 56441270 BLAKE2B efc53cde6cef487667afd17e03ae2e6dab726bc3ef5cd0e872511c44c7ab50946aa862164509e70f12a626e5314d72bd4acbaf61fb30dcc44622c9efa1b9f59b SHA512 c9cbf3353d78643fa8cef660cf997319a2d28cee37d535569c54741622a708808a585d6c20f5a1e62008058b52b86e9c336c69b593f2847286c47467c90c569a
 DIST gentoo-kernel-5.4.117-1.x86.xpak 53222896 BLAKE2B 327373b57c47f27fa864732a74d2166b7ce6deb741432b54e53503c0f63a475328b73822a02f8a9c12a55be8915879d59bca66dafd904a0774af929d43e82359 SHA512 1e75109bbb663d2699cf4bc0cd4dde98a1a9d4581690fa64c41637a395823f2dfa8a43f1fc507a194f8727727c5eefc48e91fc93cecc0aaa493c011a77014471
 DIST gentoo-kernel-5.4.118-1.amd64.xpak 61392444 BLAKE2B d99b66e6396fa0bf48c691a33c9af4e330f5ecc84bc763e62e470eca5159a792616ce4f18477cd3c078b45dcdd80dc5ac1a684204216c06a1fe3254df6366276 SHA512 6da307d56022c797dfe2de1cbe65a9251e0d325a7ae380f90784d2eafbb64f9d78d1c0a44fe0441625ba0039038d734524a7e422e4d6e11b0972a7db9a7a1cef
+DIST gentoo-kernel-5.4.118-1.arm64.xpak 56379069 BLAKE2B a0c824628d237c015c5b446e1e5841d0f819abe985606d76b7a022c65468e8f373889a86f59015a3327b7fd2a378b730ef2ef4ff68c6a14853c10df38e4c665f SHA512 d8f8060719573b427a065c6c84fe7b5dfffcec4d8bb47c416628e1ed4988c68d4658f30693091b8e68fe8f629b5c87c2d52bdeb44b56deec126dbf9276dcf9da
 DIST gentoo-kernel-5.4.118-1.x86.xpak 53177998 BLAKE2B 4a7e8160ce0c9ca321be346ec1d909d2dd546dfffeb8c2ca88e52060a8791545ec4afb04571294eff834fdb3da3538b686c690195e40c70f508afbd50dd54dc7 SHA512 2f3220f6e4c1b1c5a94cd4a50d4ef5ad993ce2ab4f0988de45bf2a734583401fae7ad4da21d314ffa181f772f85675698a22d9a63c7f09c560e0829e006c2ddc
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.11.tar.xz 117619104 BLAKE2B 81300c27bd5476387a83123aaeb4163c73eb61e9245806c23660cb5e6a4fa88ffc9def027031335fa0270fc4080506cd415990014364e3a98b9d2e8c58a29524 SHA512 a567ec133018bb5ec00c60281479b466c26e02137a93a9c690e83997947df02b6fd94e76e8df748f6d70ceb58a19bacc3b1467de10b7a1fad2763db32b3f1330

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.118-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.118-r1.ebuild
new file mode 100644
index 00000000000..b63276300c5
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.118-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}