[gentoo-commits] repo/gentoo:master commit in: acct-user/radicale/, www-apps/radicale/

[Joonas Niilola]

commit:     2e58ff40e404b0212c4f24c03b004171905f3680
Author:     Henning Schild <henning <AT> hennsch <DOT> de>
AuthorDate: Sun Jan  2 14:27:25 2022 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Sun Feb  6 08:50:31 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2e58ff40

www-apps/radicale: bump to 3.1.4

Signed-off-by: Henning Schild <henning <AT> hennsch.de>
Closes: https://github.com/gentoo/gentoo/pull/23631
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 acct-user/radicale/radicale-0-r2.ebuild |  2 +-
 www-apps/radicale/Manifest              |  1 +
 www-apps/radicale/radicale-3.1.4.ebuild | 93 +++++++++++++++++++++++++++++++++
 3 files changed, 95 insertions(+), 1 deletion(-)

diff --git a/acct-user/radicale/radicale-0-r2.ebuild b/acct-user/radicale/radicale-0-r2.ebuild
index b6b412e67029..221d3fb16490 100644
--- a/acct-user/radicale/radicale-0-r2.ebuild
+++ b/acct-user/radicale/radicale-0-r2.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2020-2021 Gentoo Authors
+# Copyright 2020-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7

diff --git a/www-apps/radicale/Manifest b/www-apps/radicale/Manifest
index 1f7f02d5411b..4d7e9d351d66 100644
--- a/www-apps/radicale/Manifest
+++ b/www-apps/radicale/Manifest
@@ -1,2 +1,3 @@
 DIST radicale-2.1.12.tar.gz 123828 BLAKE2B 38ffb264b1f8e185642e0236821bd1a7714c34306f4d67d181a9130c7955b9f3a616547fa04a15781c2587bbdc5e7ea1eeab9da65790b72fb78cd83d78b0fd43 SHA512 98b5c1e6c71928859de9f497b7e968e56c659e9e5d8c559d4359718511d67a23d4daa9adca679f5f732ad531cb04d184b022cf2684fa5fdbfe24a35c92813968
 DIST radicale-3.0.6.tar.gz 123817 BLAKE2B fa4b70c9920d518df6c939395eca857c237a75218b90ada45564f2d84266d65df12898e4efbb52905829948061e10e72b5442943fd5061a28447330ae8d491e8 SHA512 e9741547395fae8886ad84b6807422ebb196f5293d484f5f6136498058576cff697e28c117216f151d56494af83593347ceee40a6efa21272b803d0f301a396d
+DIST radicale-3.1.4.tar.gz 136638 BLAKE2B ed320fcb5cebb9a4d7563e7766d64275d4dd6c1ce70c68baa975db40a3074b2eda161dae08a6dfcfcc5655f7048d0f698a0c8223d55cc4a409fdd07dd0306636 SHA512 3f97d4f2eb786e61ba51a643a5681e47f4e3962f71f3706f4a6e2d2dca04cfa7695e3cfcd9c97e5a09370fc82022e073fb1ec836c5a6150d6109861fdeb7ec42

diff --git a/www-apps/radicale/radicale-3.1.4.ebuild b/www-apps/radicale/radicale-3.1.4.ebuild
new file mode 100644
index 000000000000..342958f23b79
--- /dev/null
+++ b/www-apps/radicale/radicale-3.1.4.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{8,9,10} )
+
+inherit distutils-r1 systemd
+
+DESCRIPTION="A simple CalDAV calendar server"
+HOMEPAGE="https://radicale.org/"
+SRC_URI="https://github.com/Kozea/Radicale/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+
+MY_P="Radicale-${PV}"
+
+RDEPEND="
+	>=acct-user/radicale-0-r2
+	acct-group/radicale
+	dev-python/bcrypt[${PYTHON_USEDEP}]
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+	dev-python/passlib[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/vobject[${PYTHON_USEDEP}]
+	sys-apps/util-linux
+"
+
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/waitress[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_P}"
+
+RDIR=/var/lib/"${PN}"
+
+DOCS=( DOCUMENTATION.md CHANGELOG.md )
+
+src_prepare() {
+	sed -i '/^addopts =/d' setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+distutils_enable_tests --install pytest
+
+python_test() {
+	epytest radicale/tests/
+}
+
+python_install_all() {
+	rm README* || die
+	# init file
+	newinitd "${FILESDIR}"/radicale-r3.init.d radicale
+	systemd_dounit "${FILESDIR}/${PN}.service"
+
+	# directories
+	keepdir "${RDIR}"
+	fperms 0750 "${RDIR}"
+	fowners "${PN}:${PN}" "${RDIR}"
+
+	# config file
+	insinto /etc/"${PN}"
+	doins config
+
+	# fcgi and wsgi files
+	exeinto /usr/share/"${PN}"
+	doexe radicale.wsgi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	local _erdir="${EROOT}${RDIR}"
+
+	einfo "A sample WSGI script has been put into ${EROOT}/usr/share/${PN}."
+	einfo "You will also find there an example FastCGI script."
+	if [[ $(stat --format="%U:%G:%a" "${_erdir}") != "${PN}:${PN}:750" ]]
+	then
+		ewarn ""
+		ewarn "Unsafe file permissions detected on ${_erdir}."
+		ewarn "This probably comes from an earlier version of this ebuild."
+		ewarn "To fix run:"
+		ewarn "#  \`chown -R ${PN}:${PN} ${_erdir}\`"
+		ewarn "#  \`chmod 0750 ${_erdir}\`"
+		ewarn "#  \`chmod -R o= ${_erdir}\`"
+	fi
+}