[gentoo-commits] gentoo-x86 commit in media-fonts/unifont: unifont-7.0.01.ebuild ChangeLog

[Mike Gilbert (floppym)]

floppym     14/06/22 16:06:52

  Modified:             ChangeLog
  Added:                unifont-7.0.01.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

Revision  Changes    Path
1.49                 media-fonts/unifont/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-fonts/unifont/ChangeLog?rev=1.49&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-fonts/unifont/ChangeLog?rev=1.49&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-fonts/unifont/ChangeLog?r1=1.48&r2=1.49

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-fonts/unifont/ChangeLog,v
retrieving revision 1.48
retrieving revision 1.49
diff -u -r1.48 -r1.49
--- ChangeLog	22 Mar 2014 08:18:59 -0000	1.48
+++ ChangeLog	22 Jun 2014 16:06:51 -0000	1.49
@@ -1,6 +1,12 @@
 # ChangeLog for media-fonts/unifont
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-fonts/unifont/ChangeLog,v 1.48 2014/03/22 08:18:59 naota Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-fonts/unifont/ChangeLog,v 1.49 2014/06/22 16:06:51 floppym Exp $
+
+*unifont-7.0.01 (22 Jun 2014)
+
+  22 Jun 2014; Mike Gilbert <floppym@g.o>
+  +files/unifont-7.0.01-font-Makefile.patch, +unifont-7.0.01.ebuild:
+  Version bump.
 
   22 Mar 2014; Naohiro Aota <naota@g.o> unifont-6.3.20140204.ebuild:
   Add ~x86-fbsd. #500844



1.1                  media-fonts/unifont/unifont-7.0.01.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-fonts/unifont/unifont-7.0.01.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-fonts/unifont/unifont-7.0.01.ebuild?rev=1.1&content-type=text/plain

Index: unifont-7.0.01.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-fonts/unifont/unifont-7.0.01.ebuild,v 1.1 2014/06/22 16:06:51 floppym Exp $

EAPI=5

inherit eutils font toolchain-funcs

DESCRIPTION="GNU Unifont - a Pan-Unicode X11 bitmap iso10646 font"
HOMEPAGE="http://unifoundry.com/"
SRC_URI="mirror://gnu/${PN}/${P}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ia64 ~x86 ~x86-fbsd"
IUSE="fontforge utils"

DEPEND="
	fontforge? (
		app-text/bdf2psf
		dev-lang/perl
		dev-perl/GD[png(-)]
		media-gfx/fontforge
		x11-apps/bdftopcf
	)
"
RDEPEND="
	utils? (
		dev-lang/perl
		dev-perl/GD[png(-)]
	)
"

src_prepare() {
	epatch "${FILESDIR}/unifont-7.0.01-font-Makefile.patch"
	sed -i -e 's/install -s/install/' src/Makefile || die
	epatch_user
}

src_compile() {
	if use fontforge || use utils; then
		tc-export CC
		makeargs=(
			CFLAGS="${CFLAGS}"
			BUILDFONT=$(usex fontforge 1 '')
		)
		emake -j1 "${makeargs[@]}"
	fi
}

src_install() {
	makeargs+=(
		DESTDIR="${ED%/}"
		PCFDEST="${ED%/}${FONTDIR}"
		TTFDEST="${ED%/}${FONTDIR}"
		USRDIR=usr
	)
	use utils || makeargs+=( -C font )
	emake -j1 "${makeargs[@]}" install
	font_xfont_config
	font_fontconfig
}