[gentoo-commits] gentoo-x86 commit in sci-chemistry/gsim: gsim-21.3.ebuild ChangeLog

[Justin Lecher (jlec)]

jlec        13/11/09 11:23:26

  Modified:             ChangeLog
  Added:                gsim-21.3.ebuild
  Log:
  sci-chemistry/gsim: Vesion Bump
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

Revision  Changes    Path
1.11                 sci-chemistry/gsim/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/gsim/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/gsim/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/gsim/ChangeLog?r1=1.10&r2=1.11

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-chemistry/gsim/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog	19 Jun 2013 04:03:30 -0000	1.10
+++ ChangeLog	9 Nov 2013 11:23:26 -0000	1.11
@@ -1,6 +1,12 @@
 # ChangeLog for sci-chemistry/gsim
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/gsim/ChangeLog,v 1.10 2013/06/19 04:03:30 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/gsim/ChangeLog,v 1.11 2013/11/09 11:23:26 jlec Exp $
+
+*gsim-21.3 (09 Nov 2013)
+
+  09 Nov 2013; Justin Lecher <jlec@g.o> +gsim-21.3.ebuild,
+  +files/gsim-21.3-build.conf.patch:
+  Vesion Bump
 
   19 Jun 2013; Sébastien Fabbro <bicatali@g.o> metadata.xml:
   Changed herd to sci-chemistry



1.1                  sci-chemistry/gsim/gsim-21.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/gsim/gsim-21.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/gsim/gsim-21.3.ebuild?rev=1.1&content-type=text/plain

Index: gsim-21.3.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/gsim/gsim-21.3.ebuild,v 1.1 2013/11/09 11:23:26 jlec Exp $

EAPI=5

inherit eutils qt4-r2 toolchain-funcs

DESCRIPTION="Programm for visualisation and processing of experimental and simulated NMR spectra"
HOMEPAGE="http://sourceforge.net/projects/gsim/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="emf opengl"

RDEPEND="
	dev-cpp/muParser
	media-libs/freetype
	sci-libs/libcmatrix
	sci-libs/minuit
	virtual/blas
	dev-qt/qtsvg:4
	emf? ( media-libs/libemf )
	opengl? ( dev-qt/qtopengl:4 )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

PATCHES=( "${FILESDIR}"/${P}-build.conf.patch )
DOCS="release.txt README_GSIM.* quickstart.* changes.log programming.*"

src_prepare() {
	edos2unix ${PN}.pro

	qt4-r2_src_prepare

	cat >> build.conf <<- EOF
	INCLUDEPATH += "${EPREFIX}/usr/include/libcmatrixR3/" \
		"${EPREFIX}/usr/include/Minuit2" \
		"${EPREFIX}/usr/include"
	LIBS += -lcmatrix  -lMinuit2 -lmuparser $($(tc-getPKG_CONFIG) --libs cblas)
	EOF

	use opengl && echo "CONFIG+=use_opengl" >> build.conf

	if use emf; then
		cat >> build.conf <<- EOF
		CONFIG+=use_emf
		DEFINES+=USE_EMF_OUTPUT
		LIBS += -L\"${EPREFIX}/usr/include/libEMF\" -lEMF
		EOF
	fi
	sed \
		-e "s:quickstart.pdf:../share/doc/${PF}/quickstart.pdf:g" \
		-e "s:README_GSIM.pdf:../share/doc/${PF}/README_GSIM.pdf:g" \
		-i mainform.h || die
}

src_install() {
	qt4-r2_src_install
	dobin ${PN}
	insinto /usr/share/${PN}
	doins -r images ${PN}.ico
	insinto /usr/share/${PN}/ui
	doins *.ui
}