[gentoo-commits] gentoo-x86 commit in mail-client/roundcube: ChangeLog roundcube-0.8_rc.ebuild

[Tim Harder (radhermit)]

radhermit    12/05/29 12:58:58

  Modified:             ChangeLog
  Added:                roundcube-0.8_rc.ebuild
  Log:
  Version bump. Drop sqlite USE flag until sqlite3 is supported.
  
  (Portage version: 2.2.0_alpha108/cvs/Linux x86_64)

Revision  Changes    Path
1.78                 mail-client/roundcube/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/roundcube/ChangeLog?rev=1.78&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/roundcube/ChangeLog?rev=1.78&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/roundcube/ChangeLog?r1=1.77&r2=1.78

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-client/roundcube/ChangeLog,v
retrieving revision 1.77
retrieving revision 1.78
diff -u -r1.77 -r1.78
--- ChangeLog	22 Apr 2012 14:49:51 -0000	1.77
+++ ChangeLog	29 May 2012 12:58:58 -0000	1.78
@@ -1,6 +1,11 @@
 # ChangeLog for mail-client/roundcube
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/roundcube/ChangeLog,v 1.77 2012/04/22 14:49:51 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/roundcube/ChangeLog,v 1.78 2012/05/29 12:58:58 radhermit Exp $
+
+*roundcube-0.8_rc (29 May 2012)
+
+  29 May 2012; Tim Harder <radhermit@g.o> +roundcube-0.8_rc.ebuild:
+  Version bump. Drop sqlite USE flag until sqlite3 is supported.
 
   22 Apr 2012; Markus Meier <maekke@g.o> roundcube-0.7.2.ebuild:
   x86 stable, bug #412029



1.1                  mail-client/roundcube/roundcube-0.8_rc.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/roundcube/roundcube-0.8_rc.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/roundcube/roundcube-0.8_rc.ebuild?rev=1.1&content-type=text/plain

Index: roundcube-0.8_rc.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-client/roundcube/roundcube-0.8_rc.ebuild,v 1.1 2012/05/29 12:58:58 radhermit Exp $

EAPI="4"

inherit webapp

MY_PN="${PN}mail"
MY_P="${MY_PN}-${PV/_/-}"
DESCRIPTION="A browser-based multilingual IMAP client with an application-like user interface"
HOMEPAGE="http://roundcube.net"
SRC_URI="mirror://sourceforge/${MY_PN}/${MY_P}.tar.gz"

# roundcube is GPL-licensed, the rest of the licenses here are
# for bundled PEAR components, googiespell and utf8.class.php
LICENSE="GPL-3 BSD PHP-2.02 PHP-3 MIT public-domain"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
IUSE="ldap +mysql postgres ssl spell"

RDEPEND="virtual/httpd-php
	>=dev-lang/php-5.3[crypt,gd,iconv,json,ldap?,postgres?,session,sockets,ssl?,xml,unicode]
	mysql? (
		|| ( dev-lang/php[mysql] dev-lang/php[mysqli] )
		|| ( dev-php/PEAR-MDB2_Driver_mysql dev-php/PEAR-MDB2_Driver_mysqli )
	)
	postgres? ( dev-php/PEAR-MDB2_Driver_pgsql )
	spell? ( dev-lang/php[curl,spell] )
	>=dev-php/PEAR-MDB2-2.5.0_beta3
	>=dev-php/PEAR-Mail_Mime-1.8.1
	>=dev-php/PEAR-Net_SMTP-1.4.2
	>=dev-php/PEAR-Net_IDNA2-0.1.1
	>=dev-php/PEAR-Auth_SASL-1.0.3"

need_httpd_cgi

S=${WORKDIR}/${MY_P}

src_prepare() {
	cp config/db.inc.php{.dist,} || die
	cp config/main.inc.php{.dist,} || die

	# Remove bundled PEAR packages
	rm -r program/lib/{Auth,Mail,MDB2*,Net,PEAR*} || die
}

src_install() {
	webapp_src_preinst
	dodoc CHANGELOG INSTALL README.md UPGRADING

	insinto "${MY_HTDOCSDIR}"
	doins -r [[:lower:]]* SQL
	doins .htaccess

	webapp_serverowned "${MY_HTDOCSDIR}"/logs
	webapp_serverowned "${MY_HTDOCSDIR}"/temp

	webapp_configfile "${MY_HTDOCSDIR}"/config/{db,main}.inc.php
	webapp_postinst_txt en "${FILESDIR}"/postinstall-en-0.6.txt
	webapp_postupgrade_txt en "${FILESDIR}"/postupgrade-en-0.6.txt
	webapp_postupgrade_txt en UPGRADING
	webapp_src_install
}