[gentoo-commits] gentoo-x86 commit in sci-mathematics/wxmaxima: ChangeLog wxmaxima-13.04.2.ebuild

[Andrey Grozin (grozin)]

grozin      13/05/25 11:05:07

  Modified:             ChangeLog
  Added:                wxmaxima-13.04.2.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.0_alpha176/cvs/Linux i686, signed Manifest commit with key 0x3AFFCE974D34BD8C!)

Revision  Changes    Path
1.42                 sci-mathematics/wxmaxima/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/wxmaxima/ChangeLog?rev=1.42&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/wxmaxima/ChangeLog?rev=1.42&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/wxmaxima/ChangeLog?r1=1.41&r2=1.42

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-mathematics/wxmaxima/ChangeLog,v
retrieving revision 1.41
retrieving revision 1.42
diff -u -r1.41 -r1.42
--- ChangeLog	9 Apr 2013 06:40:05 -0000	1.41
+++ ChangeLog	25 May 2013 11:05:07 -0000	1.42
@@ -1,6 +1,11 @@
 # ChangeLog for sci-mathematics/wxmaxima
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/wxmaxima/ChangeLog,v 1.41 2013/04/09 06:40:05 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/wxmaxima/ChangeLog,v 1.42 2013/05/25 11:05:07 grozin Exp $
+
+*wxmaxima-13.04.2 (25 May 2013)
+
+  25 May 2013; Andrey Grozin <grozin@g.o> +wxmaxima-13.04.2.ebuild:
+  Version bump
 
   09 Apr 2013; Justin Lecher <jlec@g.o> wxmaxima-12.09.0.ebuild,
   metadata.xml:



1.1                  sci-mathematics/wxmaxima/wxmaxima-13.04.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/wxmaxima/wxmaxima-13.04.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/wxmaxima/wxmaxima-13.04.2.ebuild?rev=1.1&content-type=text/plain

Index: wxmaxima-13.04.2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/wxmaxima/wxmaxima-13.04.2.ebuild,v 1.1 2013/05/25 11:05:07 grozin Exp $

EAPI=5

WX_GTK_VER="2.8"

inherit eutils gnome2-utils wxwidgets fdo-mime

MYP=wxMaxima-${PV}

DESCRIPTION="Graphical frontend to Maxima, using the wxWidgets toolkit."
HOMEPAGE="http://wxmaxima.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${MYP}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"

DEPEND="
	dev-libs/libxml2:2
	x11-libs/wxGTK:${WX_GTK_VER}"
RDEPEND="${DEPEND}
	media-fonts/jsmath
	sci-visualization/gnuplot[wxwidgets]
	sci-mathematics/maxima"

S="${WORKDIR}/${MYP}"

src_prepare() {
	local i

	# consistent package names
	sed -e "s:\${datadir}/wxMaxima:\${datadir}/${PN}:g" \
		-i Makefile.in data/Makefile.in || die "sed failed"

	sed -e 's:share/wxMaxima:share/wxmaxima:g' \
		-i src/wxMaxima.cpp src/wxMaximaFrame.cpp src/Config.cpp \
		|| die "sed failed"

	# correct gettext behavior
	if [[ -n "${LINGUAS+x}" ]] ; then
		for i in $(cd "${S}"/locales ; echo *.mo) ; do
			if ! has ${i%.mo} ${LINGUAS} ; then
				sed -i \
					-e "/^WXMAXIMA_LINGUAS/s# ${i%.mo}##" \
					-e "/^WXWIN_LINGUAS/s# ${i%.mo}##" \
					locales/Makefile.in || die
			fi
		done
	fi
}

src_configure() {
	econf \
		--enable-printing \
		--with-wx-config=${WX_CONFIG}
}

src_install () {
	default
	doicon -s 128 data/wxmaxima.png
	make_desktop_entry wxmaxima wxMaxima wxmaxima
	dosym /usr/share/${PN}/README /usr/share/doc/${PF}/README
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
	fdo-mime_desktop_database_update
}

pkg_postrm() {
	gnome2_icon_cache_update
	fdo-mime_desktop_database_update
}