[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     830297c332ac4bc34d3b324f48a4db142a558074
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 18 02:28:25 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Apr 18 02:28:25 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=830297c3

sys-kernel/gentoo-kernel-bin: bump to 5.10.31 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.10.31-r1.ebuild            | 114 +++++++++++++++++++++
 2 files changed, 115 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 47dcf40f001..ef7e9e40a14 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -30,6 +30,7 @@ DIST gentoo-kernel-5.10.30-1.amd64.xpak 64347202 BLAKE2B 85a0fc2d2df1d1a134738e4
 DIST gentoo-kernel-5.10.30-1.arm64.xpak 59409195 BLAKE2B 4e5523c5546bfe9549a5dd865f2ccdfb1a01668b6c77e921920098baff478527a487029d6773ae62acbd4df916fafe371eb14880e94b36b1493e0d41e8b83494 SHA512 5f0280a802e81e542c49790c2876dcc43ba7ed1d351a1ae861ae552668d7700f09cac5ee7870a88eeaa1692613ab5a88922ac0cb0f8aa1d4624709de50d3987a
 DIST gentoo-kernel-5.10.30-1.x86.xpak 57245779 BLAKE2B 22b2dcaecb0fe062e1ecf61aee6fcb7c27d23ebd2d858bdd4933453724c50af23197635827a262e5cd8f6ad045919a3670d51c5c3ac63e6096d109ff4c44b99b SHA512 3a0e669b9c7b1f7e8207c8f8429beaafb0a440b4680206efa2ccfbebe3717e1c1b6e7151ebdad32a4c6cb9d6cbcfc43cb271b47aea7f27790dbb92f3f38cc137
 DIST gentoo-kernel-5.10.31-1.amd64.xpak 64337577 BLAKE2B 231e6cb5bc36bbf01f41295d6969b4ef5029fcdcdcf0fac6565dad7bd5ccf1601088d5ba1fdb0a66b58badea14090f859d5df6fe59290a2cb08d88abf12fdcdf SHA512 1ecd188b65567929dadf079fc6953aa2541d4ab856d5d802cd9c988365f21c0eebe5303f44d3e89f247878258a2e91fe561c5f7d000cd0bc9c4344828fc753d9
+DIST gentoo-kernel-5.10.31-1.arm64.xpak 59338684 BLAKE2B 34ef0b745377ce5edfd0f00b4b0b492ecb14ff856861ca11ba9a7489af6040db0a4b8ed71430490572ecda375fe74c7d18cf872ad4b798799f78874d6c6b3997 SHA512 54a6937512f9eb7da74324a7d376be3d78ebb9293d401adabdec42ee67d236db6af9b124ab7ffef5833459ec92e5c93e574f2508233fc810af2d5017da00bca7
 DIST gentoo-kernel-5.10.31-1.x86.xpak 57256746 BLAKE2B 5c9c42e714f9b896ae2f01f602bb9409cfa210b6a75195de6ddc4213411f6e4ce86f2fd7279906360f4e33c517e1697412f7df8f3889c4e4498fe378430eba6a SHA512 04a18daa394cb2ac0cb4eddcfdad525a7d73861978e6212f152707207548561101fa0294461e43a9aeffe8f7533aebde7a13f26b46e6bd191e72a996d704bf5b
 DIST gentoo-kernel-5.11.13-1.amd64.xpak 64685029 BLAKE2B 7d6794c5fd15434d2ad93d36678476e4a6aa3ad9ff77140a0bc8d74b0c87155898e8f1f76dfd40f72c878d9ddca7b7f1a9f0d4be2a600c5e2c18a77a3439e9d5 SHA512 d8c0fb975ee35e6d71b3b255800179805c9e70bfa7ef5299a38145c6cfd4f60720281c70f2d16a409a10c4ee6c6f26ac2e0c3151b114ced91c747371b59885b0
 DIST gentoo-kernel-5.11.13-1.arm64.xpak 59816443 BLAKE2B f3bd4b929cd103f95b91f0c0f28f324f8e316e1cc4b310742d159b8dbdb6c288d9424984e0859873924ac7eb34f12278b2086ad48fbf11da955f0b390dfda619 SHA512 6aae6cd29857eb897a167e359f9628692803bb75a0a1f235468a1b95e9c2f3d9525f33d6673b5c12edb5d9feba29210a79d8030d151a5b7260119a81eef57e1d

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.31-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.31-r1.ebuild
new file mode 100644
index 00000000000..8198cf5ace0
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.31-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}