[gentoo-commits] gentoo-x86 commit in app-misc/mmv: mmv-1.01b_p18.ebuild ChangeLog

[Justin Lecher (jlec)]

jlec        15/07/03 07:28:36

  Modified:             ChangeLog
  Added:                mmv-1.01b_p18.ebuild
  Log:
  Version Bump; fix problems with format-security, bug #521100
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key E9402A79B03529A2!)

Revision  Changes    Path
1.31                 app-misc/mmv/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mmv/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mmv/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mmv/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/mmv/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog	10 Aug 2014 18:08:18 -0000	1.30
+++ ChangeLog	3 Jul 2015 07:28:35 -0000	1.31
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/mmv
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/mmv/ChangeLog,v 1.30 2014/08/10 18:08:18 slyfox Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/mmv/ChangeLog,v 1.31 2015/07/03 07:28:35 jlec Exp $
+
+*mmv-1.01b_p18 (03 Jul 2015)
+
+  03 Jul 2015; Justin Lecher <jlec@g.o> +mmv-1.01b_p18.ebuild:
+  Version Bump; fix problems with format-security, bug #521100
 
   10 Aug 2014; Sergei Trofimovich <slyfox@g.o> mmv-1.01b_p15.ebuild:
   QA: drop trailing '.' from DESCRIPTION



1.1                  app-misc/mmv/mmv-1.01b_p18.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mmv/mmv-1.01b_p18.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mmv/mmv-1.01b_p18.ebuild?rev=1.1&content-type=text/plain

Index: mmv-1.01b_p18.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/mmv/mmv-1.01b_p18.ebuild,v 1.1 2015/07/03 07:28:35 jlec Exp $

EAPI=5

inherit eutils flag-o-matic toolchain-funcs

DEB_PATCH_VER=${PV#*_p}
MY_VER=${PV%_p*}

DESCRIPTION="Move/copy/append/link multiple files according to a set of wildcard patterns"
HOMEPAGE="http://packages.debian.org/unstable/utils/mmv"
SRC_URI="
	mirror://debian/pool/main/m/mmv/${PN}_${MY_VER}.orig.tar.gz
	mirror://debian/pool/main/m/mmv/${PN}_${MY_VER}-${DEB_PATCH_VER}.debian.tar.gz"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~x86 ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
IUSE=""

S="${WORKDIR}"/${PN}-${MY_VER}.orig

src_prepare() {
	epatch "${WORKDIR}"/debian/patches/*.diff
}

src_compile() {
	# i wonder how this works on other platforms if CFLAGS from makefile are
	# overridden, see bug #218082
	[[ ${CHOST} == *-interix* ]] && append-flags -DIS_SYSV -DHAS_RENAME -DHAS_DIRENT
	[[ ${CHOST} == *-interix* ]] || append-lfs-flags

	emake CC="$(tc-getCC)" CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"
}

src_install() {
	dobin mmv
	dosym mmv /usr/bin/mcp
	dosym mmv /usr/bin/mln
	dosym mmv /usr/bin/mad

	doman mmv.1
	newman mmv.1 mcp.1
	newman mmv.1 mln.1
	newman mmv.1 mad.1

	dodoc ANNOUNCE "${WORKDIR}"/debian/{changelog,control}
}