Gentoo Archives: gentoo-commits

From: "Samuli Suominen (ssuominen)" <ssuominen@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in media-video/transcode: ChangeLog transcode-1.1.7-r1.ebuild
Date: Mon, 30 Jan 2012 21:34:29
Message-Id: 20120130213419.147AE2004B@flycatcher.gentoo.org
1 ssuominen 12/01/30 21:34:19
2
3 Modified: ChangeLog
4 Added: transcode-1.1.7-r1.ebuild
5 Log:
6 Fix building with media-video/ffmpeg >= 0.10 and USE="postproc" wrtt #401287 by Olaf Freyer
7
8 (Portage version: 2.2.0_alpha84/cvs/Linux x86_64)
9
10 Revision Changes Path
11 1.295 media-video/transcode/ChangeLog
12
13 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/transcode/ChangeLog?rev=1.295&view=markup
14 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/transcode/ChangeLog?rev=1.295&content-type=text/plain
15 diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/transcode/ChangeLog?r1=1.294&r2=1.295
16
17 Index: ChangeLog
18 ===================================================================
19 RCS file: /var/cvsroot/gentoo-x86/media-video/transcode/ChangeLog,v
20 retrieving revision 1.294
21 retrieving revision 1.295
22 diff -u -r1.294 -r1.295
23 --- ChangeLog 4 Jan 2012 18:08:37 -0000 1.294
24 +++ ChangeLog 30 Jan 2012 21:34:18 -0000 1.295
25 @@ -1,6 +1,13 @@
26 # ChangeLog for media-video/transcode
27 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
28 -# $Header: /var/cvsroot/gentoo-x86/media-video/transcode/ChangeLog,v 1.294 2012/01/04 18:08:37 phajdan.jr Exp $
29 +# $Header: /var/cvsroot/gentoo-x86/media-video/transcode/ChangeLog,v 1.295 2012/01/30 21:34:18 ssuominen Exp $
30 +
31 +*transcode-1.1.7-r1 (30 Jan 2012)
32 +
33 + 30 Jan 2012; Samuli Suominen <ssuominen@g.o>
34 + +transcode-1.1.7-r1.ebuild, +files/transcode-1.1.7-ffmpeg-0.10.patch:
35 + Fix building with media-video/ffmpeg >= 0.10 and USE="postproc" wrtt #401287
36 + by Olaf Freyer
37
38 04 Jan 2012; Pawel Hajdan jr <phajdan.jr@g.o> transcode-1.1.7.ebuild:
39 x86 stable wrt bug #395729
40
41
42
43 1.1 media-video/transcode/transcode-1.1.7-r1.ebuild
44
45 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/transcode/transcode-1.1.7-r1.ebuild?rev=1.1&view=markup
46 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/transcode/transcode-1.1.7-r1.ebuild?rev=1.1&content-type=text/plain
47
48 Index: transcode-1.1.7-r1.ebuild
49 ===================================================================
50 # Copyright 1999-2012 Gentoo Foundation
51 # Distributed under the terms of the GNU General Public License v2
52 # $Header: /var/cvsroot/gentoo-x86/media-video/transcode/transcode-1.1.7-r1.ebuild,v 1.1 2012/01/30 21:34:18 ssuominen Exp $
53
54 EAPI=4
55 inherit eutils libtool multilib
56
57 DESCRIPTION="A suite of utilities for transcoding video and audio codecs in different containers"
58 HOMEPAGE="http://tcforge.berlios.de/"
59 SRC_URI="http://bitbucket.org/france/${PN}-tcforge/downloads/${P}.tar.bz2"
60
61 LICENSE="GPL-2"
62 SLOT="0"
63 KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
64 IUSE="3dnow a52 aac alsa altivec dv dvd +iconv imagemagick jpeg lzo mjpeg mmx mp3 mpeg nuv ogg oss pic postproc quicktime sdl sse sse2 theora truetype v4l vorbis X x264 xml xvid"
65
66 RDEPEND="
67 virtual/ffmpeg
68 a52? ( media-libs/a52dec )
69 aac? ( media-libs/faac )
70 alsa? ( media-libs/alsa-lib )
71 dv? ( media-libs/libdv )
72 dvd? ( media-libs/libdvdread )
73 iconv? ( virtual/libiconv )
74 imagemagick? ( media-gfx/imagemagick )
75 jpeg? ( virtual/jpeg )
76 lzo? ( >=dev-libs/lzo-2 )
77 mjpeg? ( media-video/mjpegtools )
78 mp3? ( media-sound/lame )
79 mpeg? ( media-libs/libmpeg2 )
80 ogg? ( media-libs/libogg )
81 postproc? ( media-video/ffmpeg )
82 quicktime? ( >=media-libs/libquicktime-1 )
83 sdl? ( >=media-libs/libsdl-1.2.5[X?] )
84 theora? ( media-libs/libtheora )
85 truetype? ( >=media-libs/freetype-2 )
86 v4l? ( media-libs/libv4l )
87 vorbis? ( media-libs/libvorbis )
88 X? ( x11-libs/libXpm x11-libs/libXaw x11-libs/libXv )
89 x264? ( media-libs/x264 )
90 xml? ( dev-libs/libxml2 )
91 xvid? ( media-libs/xvid )
92 "
93
94 DEPEND="
95 ${RDEPEND}
96 dev-util/pkgconfig
97 v4l? ( >=sys-kernel/linux-headers-2.6.11 )
98 "
99
100 REQUIRED_USE="
101 sse? ( mmx )
102 sse2? ( mmx sse )
103 3dnow? ( mmx )
104 nuv? ( lzo )
105 "
106
107 src_prepare() {
108 epatch \
109 "${FILESDIR}"/${P}-ffmpeg.patch \
110 "${FILESDIR}"/${P}-ffmpeg-0.10.patch
111
112 elibtoolize
113 }
114
115 src_configure() {
116 local myconf
117 use x86 && myconf="$(use_enable !pic x86-textrels)" #271476
118
119 econf \
120 $(use_enable mmx) \
121 $(use_enable 3dnow) \
122 $(use_enable sse) \
123 $(use_enable sse2) \
124 $(use_enable altivec) \
125 $(use_enable v4l libv4l2) \
126 $(use_enable v4l libv4lconvert) \
127 $(use_enable mpeg libmpeg2) \
128 $(use_enable mpeg libmpeg2convert) \
129 --enable-experimental \
130 --enable-deprecated \
131 $(use_enable v4l) \
132 $(use_enable oss) \
133 $(use_enable alsa) \
134 $(use_enable postproc libpostproc) \
135 $(use_enable truetype freetype2) \
136 $(use_enable mp3 lame) \
137 $(use_enable xvid) \
138 $(use_enable x264) \
139 $(use_enable ogg) \
140 $(use_enable vorbis) \
141 $(use_enable theora) \
142 $(use_enable dvd libdvdread) \
143 $(use_enable dv libdv) \
144 $(use_enable quicktime libquicktime) \
145 $(use_enable lzo) \
146 $(use_enable a52) \
147 $(use_enable aac faac) \
148 $(use_enable xml libxml2) \
149 $(use_enable mjpeg mjpegtools) \
150 $(use_enable sdl) \
151 $(use_enable imagemagick) \
152 $(use_enable jpeg libjpeg) \
153 $(use_enable iconv) \
154 $(use_enable nuv) \
155 $(use_with X x) \
156 --with-mod-path=/usr/$(get_libdir)/transcode \
157 ${myconf}
158 }
159
160 src_install() {
161 emake DESTDIR="${D}" docsdir=/usr/share/doc/${PF} install
162 dodoc AUTHORS ChangeLog README STYLE TODO
163 find "${ED}"usr -name '*.la' -exec rm -f {} +
164 }