[gentoo-commits] gentoo-x86 commit in www-client/opera: opera-10.50_pre6204.ebuild ChangeLog opera-10.50_pre6201.ebuild

[Jeroen Roovers (jer)]

jer         10/02/01 18:40:33

  Modified:             ChangeLog opera-10.50_pre6201.ebuild
  Added:                opera-10.50_pre6204.ebuild
  Log:
  Version bump <http://my.opera.com/desktopteam/blog/new-snapshot>.
  (Portage version: 2.2_rc62/cvs/Linux i686)

Revision  Changes    Path
1.443                www-client/opera/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/opera/ChangeLog?rev=1.443&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/opera/ChangeLog?rev=1.443&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/opera/ChangeLog?r1=1.442&r2=1.443

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/opera/ChangeLog,v
retrieving revision 1.442
retrieving revision 1.443
diff -u -r1.442 -r1.443
--- ChangeLog	30 Jan 2010 17:46:39 -0000	1.442
+++ ChangeLog	1 Feb 2010 18:40:33 -0000	1.443
@@ -1,6 +1,12 @@
 # ChangeLog for www-client/opera
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/opera/ChangeLog,v 1.442 2010/01/30 17:46:39 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/opera/ChangeLog,v 1.443 2010/02/01 18:40:33 jer Exp $
+
+*opera-10.50_pre6204 (01 Feb 2010)
+
+  01 Feb 2010; Jeroen Roovers <jer@g.o> opera-10.50_pre6201.ebuild,
+  +opera-10.50_pre6204.ebuild:
+  Version bump <http://my.opera.com/desktopteam/blog/new-snapshot>.
 
   30 Jan 2010; Jeroen Roovers <jer@g.o> opera-10.50_pre6201.ebuild:
   Use canonical install function instead of mv.



1.4                  www-client/opera/opera-10.50_pre6201.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/opera/opera-10.50_pre6201.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/opera/opera-10.50_pre6201.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/opera/opera-10.50_pre6201.ebuild?r1=1.3&r2=1.4

Index: opera-10.50_pre6201.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/opera/opera-10.50_pre6201.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- opera-10.50_pre6201.ebuild	30 Jan 2010 17:46:39 -0000	1.3
+++ opera-10.50_pre6201.ebuild	1 Feb 2010 18:40:33 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/opera/opera-10.50_pre6201.ebuild,v 1.3 2010/01/30 17:46:39 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/opera/opera-10.50_pre6201.ebuild,v 1.4 2010/02/01 18:40:33 jer Exp $
 
 EAPI="2"
 
@@ -13,7 +13,7 @@
 
 SLOT="0"
 LICENSE="OPERA-10.10 LGPL-2"
-KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+KEYWORDS="~amd64 ~x86"
 
 RESTRICT="mirror test"
 



1.1                  www-client/opera/opera-10.50_pre6204.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/opera/opera-10.50_pre6204.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/opera/opera-10.50_pre6204.ebuild?rev=1.1&content-type=text/plain

Index: opera-10.50_pre6204.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/opera/opera-10.50_pre6204.ebuild,v 1.1 2010/02/01 18:40:33 jer Exp $

EAPI="2"

OPREFIX="/usr/lib"

inherit eutils

DESCRIPTION="A standards-compliant graphical Web browser"
HOMEPAGE="http://www.opera.com/"

SLOT="0"
LICENSE="OPERA-10.10 LGPL-2"
KEYWORDS="~amd64 ~x86 ~x86-fbsd"

RESTRICT="mirror test"

QA_DT_HASH="${OPREFIX}/${PN}/.*"
QA_PRESTRIPPED="${OPREFIX}/${PN}/.*"

IUSE="elibc_FreeBSD"

MY_LINGUAS="
	be bg cs da de el en-GB es-ES es-LA et fi fr fr-CA fy hi hr hu id it ja ka
	ko lt mk nb nl nn pl pt pt-BR ro ru sk sr sv ta te tr uk zh-CN zh-HK zh-TW
"

for MY_LINGUA in ${MY_LINGUAS}; do
	IUSE="${IUSE} linguas_${MY_LINGUA/-/_}"
done

O_U="http://snapshot.opera.com/unix/snapshot-${PV/*_pre}/"
O_P="${P/_pre/-}"

SRC_URI="
	amd64? ( ${O_U}${O_P}.linux.x86_64.tar.bz2 )
	x86? ( ${O_U}${O_P}.linux.i386.tar.bz2 )
	x86-fbsd? ( ${O_U}${O_P}.freebsd.i386.tar.bz2 )
"

DEPEND=">=sys-apps/sed-4"

RDEPEND="
	=x11-libs/gtk+-2*
	dev-libs/atk
	dev-libs/expat
	dev-libs/glib
	media-libs/fontconfig
	media-libs/freetype
	media-libs/glitz
	media-plugins/gst-plugins-meta
	media-libs/libpng
	sys-apps/util-linux
	sys-libs/zlib
	virtual/opengl
	x11-libs/cairo
	x11-libs/libICE
	x11-libs/libSM
	x11-libs/libX11
	x11-libs/libXau
	x11-libs/libXcomposite
	x11-libs/libXcursor
	x11-libs/libXdamage
	x11-libs/libXdmcp
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libXi
	x11-libs/libXmu
	x11-libs/libXrandr
	x11-libs/libXrender
	x11-libs/libXt
	x11-libs/libxcb
	x11-libs/pango
	x11-libs/pixman
	x11-libs/xcb-util
	"

opera_linguas() {
	# Remove unwanted LINGUAS:
	local LINGUA
	local LNGDIR="${D}usr/share/${PN}/locale"
	einfo "Keeping these locales: ${LINGUAS}."
	for LINGUA in ${MY_LINGUAS}; do
		if ! use linguas_${LINGUA/-/_}; then
			LINGUA=$(find "${LNGDIR}" -maxdepth 1 -type d -iname ${LINGUA/_/-})
			rm -r "${LINGUA}"
		fi
	done
}

pkg_setup() {
	echo -e \
		" ${GOOD}****************************************************${NORMAL}"
	elog "If you seek support, please file a bug report at"
	elog "https://bugs.gentoo.org and post the output of"
	elog " \`emerge --info =${CATEGORY}/${P}'"
	echo -e \
		" ${GOOD}****************************************************${NORMAL}"
}

src_unpack() {
	unpack ${A}
	if [[ ! -d ${S} ]]; then
		cd "${WORKDIR}"/${PN}* || die "failed to enter work directory"
		S="$(pwd)"
		einfo "Setting WORKDIR to ${S}"
	fi
}

src_prepare() {
	sed -i opera \
		-e 's|=usr/lib/opera|=/usr/lib/opera|g' \
		-e '6a\OPERA_DIR=/usr/share/opera' \
		|| die "sed opera script failed"
}

src_install() {
	# This alpha build hardcodes /usr as prefix
	doins -r etc/ usr/

	make_desktop_entry ${PN} Opera ${PN} # TODO

	# Install startup script
	dobin ${PN}

	# Stop revdep-rebuild from checking opera binaries
	dodir /etc/revdep-rebuild
	echo "SEARCH_DIRS_MASK=\"${OPREFIX}/${PN}\"" > "${D}"/etc/revdep-rebuild/90opera

	# Change libz.so.3 to libz.so.1 for gentoo/freebsd
	if use elibc_FreeBSD; then
		scanelf -qR -N libz.so.3 -F "#N" "${D}"${OPREFIX}/${PN}/ | \
		while read i; do
			if [[ $(strings "$i" | fgrep -c libz.so.3) -ne 1 ]];
			then
				export SANITY_CHECK_LIBZ_FAILED=1
				break
			fi
			sed -i -e 's/libz\.so\.3/libz.so.1/g' "$i"
		done
		[[ "$SANITY_CHECK_LIBZ_FAILED" = "1" ]] && die "failed to change libz.so.3 to libz.so.1"
	fi

	[[ -z MY_LINGUAS ]] || opera_linguas
}

pkg_postinst() {
	elog "To change the UI language, choose [Tools] -> [Preferences], open the"
	elog "[General] tab, click on [Details...] then [Choose...] and point the"
	elog "file chooser at ${OPREFIX}/opera/share/opera/locale/, then enter the"
	elog "directory for the language you want and [Open] the .lng file."

	if use elibc_FreeBSD; then
		elog
		elog "To improve shared memory usage please set:"
		elog "$ sysctl kern.ipc.shm_allow_removed=1"
	fi
}