[gentoo-commits] gentoo-x86 commit in x11-libs/qscintilla: qscintilla-2.5.1.ebuild ChangeLog

[Arfrever Frehtes Taifersar Arahesis (arfrever)]

arfrever    11/04/26 19:27:36

  Modified:             ChangeLog
  Added:                qscintilla-2.5.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha30_p2/cvs/Linux x86_64)

Revision  Changes    Path
1.64                 x11-libs/qscintilla/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/ChangeLog?rev=1.64&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/ChangeLog?rev=1.64&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/ChangeLog?r1=1.63&r2=1.64

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/ChangeLog,v
retrieving revision 1.63
retrieving revision 1.64
diff -u -r1.63 -r1.64
--- ChangeLog	16 Mar 2011 21:14:32 -0000	1.63
+++ ChangeLog	26 Apr 2011 19:27:35 -0000	1.64
@@ -1,6 +1,12 @@
 # ChangeLog for x11-libs/qscintilla
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/ChangeLog,v 1.63 2011/03/16 21:14:32 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/ChangeLog,v 1.64 2011/04/26 19:27:35 arfrever Exp $
+
+*qscintilla-2.5.1 (26 Apr 2011)
+
+  26 Apr 2011; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
+  +qscintilla-2.5.1.ebuild:
+  Version bump.
 
   16 Mar 2011; Kacper Kowalik <xarthisius@g.o> qscintilla-2.4.5.ebuild:
   ppc64 stable wrt #349607



1.1                  x11-libs/qscintilla/qscintilla-2.5.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/qscintilla-2.5.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/qscintilla/qscintilla-2.5.1.ebuild?rev=1.1&content-type=text/plain

Index: qscintilla-2.5.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/qscintilla-2.5.1.ebuild,v 1.1 2011/04/26 19:27:35 arfrever Exp $

EAPI="3"

inherit qt4-r2

MY_P="QScintilla-gpl-${PV/_pre/-snapshot-}"

DESCRIPTION="A Qt port of Neil Hodgson's Scintilla C++ editor class"
HOMEPAGE="http://www.riverbankcomputing.co.uk/software/qscintilla/intro"
SRC_URI="http://www.riverbankcomputing.co.uk/static/Downloads/QScintilla2/${MY_P}.tar.gz"

LICENSE="|| ( GPL-2 GPL-3 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="doc python"

DEPEND="x11-libs/qt-gui:4"
RDEPEND="${DEPEND}"
PDEPEND="python? ( ~dev-python/qscintilla-python-${PV} )"

S=${WORKDIR}/${MY_P}

PATCHES=("${FILESDIR}/${PN}-2.4-designer.patch")

src_configure() {
	pushd Qt4 > /dev/null
	einfo "Configuration of qscintilla"
	eqmake4 qscintilla.pro
	popd > /dev/null

	pushd designer-Qt4 > /dev/null
	einfo "Configuration of designer plugin"
	eqmake4 designer.pro
	popd > /dev/null
}

src_compile() {
	pushd Qt4 > /dev/null
	einfo "Building of qscintilla"
	emake || die "Building of qscintilla failed"
	popd > /dev/null

	pushd designer-Qt4 > /dev/null
	einfo "Building of designer plugin"
	emake || die "Building of designer plugin failed"
	popd > /dev/null
}

src_install() {
	pushd Qt4 > /dev/null
	einfo "Installation of qscintilla"
	emake INSTALL_ROOT="${D}" install || die "Installation of qscintilla failed"
	popd > /dev/null

	pushd designer-Qt4 > /dev/null
	einfo "Installation of designer plugin"
	emake INSTALL_ROOT="${D}" install || die "Installation of designer plugin failed"
	popd > /dev/null

	dodoc NEWS || die "dodoc failed"
	if use doc; then
		einfo "Installation of documentation"
		dohtml doc/html-Qt4/* || die "dohtml failed"
		insinto /usr/share/doc/${PF}/Scintilla
		doins doc/Scintilla/* || die "doins failed"
	fi
}