[gentoo-commits] gentoo-x86 commit in www-apps/trac: metadata.xml trac-1.0.4.ebuild ChangeLog

[Dirkjan Ochtman (djc)]

djc         15/02/08 14:26:19

  Modified:             metadata.xml ChangeLog
  Added:                trac-1.0.4.ebuild
  Log:
  Version bump trac to 1.0.4 (includes fixes from bug 538714)
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 30380381)

Revision  Changes    Path
1.9                  www-apps/trac/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/trac/metadata.xml?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/trac/metadata.xml?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/trac/metadata.xml?r1=1.8&r2=1.9

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/trac/metadata.xml,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- metadata.xml	14 Jun 2010 08:45:31 -0000	1.8
+++ metadata.xml	8 Feb 2015 14:26:19 -0000	1.9
@@ -8,5 +8,7 @@
   </maintainer>
   <use>
     <flag name="i18n">Enable support for i18n with dev-python/Babel</flag>
+    <flag name="highlight">Enable syntax highlighting</flag>
+    <flag name="restructuredtext">Enable support for reStructuredText for wiki formatting</flag>
   </use>
 </pkgmetadata>



1.150                www-apps/trac/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/trac/ChangeLog?rev=1.150&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/trac/ChangeLog?rev=1.150&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/trac/ChangeLog?r1=1.149&r2=1.150

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/trac/ChangeLog,v
retrieving revision 1.149
retrieving revision 1.150
diff -u -r1.149 -r1.150
--- ChangeLog	8 Feb 2015 10:09:56 -0000	1.149
+++ ChangeLog	8 Feb 2015 14:26:19 -0000	1.150
@@ -1,6 +1,12 @@
 # ChangeLog for www-apps/trac
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/trac/ChangeLog,v 1.149 2015/02/08 10:09:56 djc Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apps/trac/ChangeLog,v 1.150 2015/02/08 14:26:19 djc Exp $
+
+*trac-1.0.4 (08 Feb 2015)
+
+  08 Feb 2015; Dirkjan Ochtman <djc@g.o> +trac-1.0.4.ebuild,
+  metadata.xml:
+  Version bump trac to 1.0.4 (includes fixes from bug 538714)
 
   08 Feb 2015; Dirkjan Ochtman <djc@g.o> -files/1.0.1-git-identity.patch,
   -trac-1.0.1-r1.ebuild, -trac-1.0.1.ebuild:



1.1                  www-apps/trac/trac-1.0.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/trac/trac-1.0.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/trac/trac-1.0.4.ebuild?rev=1.1&content-type=text/plain

Index: trac-1.0.4.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/trac/trac-1.0.4.ebuild,v 1.1 2015/02/08 14:26:19 djc Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE='sqlite?'

DISTUTILS_SINGLE_IMPL=Yes

inherit distutils-r1 eutils user webapp

MY_PV=${PV/_beta/b}
MY_P=Trac-${MY_PV}

DESCRIPTION="Trac is a minimalistic web-based project management, wiki and bug/issue tracking system"
HOMEPAGE="http://trac.edgewall.com/ http://pypi.python.org/pypi/Trac"
SRC_URI="http://ftp.edgewall.com/pub/trac/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE="cgi fastcgi i18n +highlight +restructuredtext mysql postgres +sqlite subversion test"
REQUIRED_USE="|| ( mysql postgres sqlite )"

RDEPEND="
	dev-python/setuptools[${PYTHON_USEDEP}]
	dev-python/genshi[${PYTHON_USEDEP}]
	dev-python/pytz[${PYTHON_USEDEP}]
	i18n? ( >=dev-python/Babel-0.9.5[${PYTHON_USEDEP}] )
	highlight? (
		|| (
			dev-python/pygments[${PYTHON_USEDEP}]
			app-text/silvercity
			app-text/pytextile
			app-text/enscript
		)
	)
	restructuredtext? ( dev-python/docutils[${PYTHON_USEDEP}] )
	cgi? ( virtual/httpd-cgi )
	fastcgi? ( virtual/httpd-fastcgi )
	mysql? ( dev-python/mysql-python[${PYTHON_USEDEP}] )
	postgres? ( >=dev-python/psycopg-2[${PYTHON_USEDEP}] )
	sqlite? ( >=dev-db/sqlite-3.3.4:3 )
	subversion? ( dev-vcs/subversion[python,${PYTHON_USEDEP}] )
	"
DEPEND="${RDEPEND}
	test? (
		dev-python/twill[${PYTHON_USEDEP}]
		dev-python/lxml[${PYTHON_USEDEP}]
		dev-python/configobj[${PYTHON_USEDEP}]
	)"

S="${WORKDIR}/${MY_P}"

WEBAPP_MANUAL_SLOT="yes"

pkg_setup() {
	python-single-r1_pkg_setup
	webapp_pkg_setup

	enewgroup tracd
	enewuser tracd -1 -1 -1 tracd
}

python_prepare_all() {
	distutils-r1_python_prepare_all
}

src_test() {
	distutils-r1_src_test
}

python_test() {
	PYTHONPATH=. "${PYTHON}" trac/test.py || die "Tests fail with ${EPYTHON}"
}

python_test_all() {
	if use i18n; then
		make check
	fi
}

python_install() {
	if use cgi; then
		python_scriptinto "${MY_CGIBINDIR}"
		python_doscript contrib/cgi-bin/trac.cgi
	fi
	if use fastcgi; then
		python_scriptinto "${MY_CGIBINDIR}"
		python_doscript contrib/cgi-bin/trac.fcgi
	fi
	distutils-r1_python_install
}

# the default src_compile just calls setup.py build
# currently, this switches i18n catalog compilation based on presence of Babel

src_install() {
	webapp_src_preinst
	distutils-r1_src_install

	# project environments might go in here
	keepdir /var/lib/trac

	# Use this as the egg-cache for tracd
	dodir /var/lib/trac/egg-cache
	keepdir /var/lib/trac/egg-cache
	fowners tracd:tracd /var/lib/trac/egg-cache

	# documentation
	dodoc -r contrib

	# tracd init script
	newconfd "${FILESDIR}"/tracd.confd tracd
	newinitd "${FILESDIR}"/tracd.initd tracd

	for lang in en; do
		webapp_postinst_txt ${lang} "${FILESDIR}"/postinst-${lang}.txt
		webapp_postupgrade_txt ${lang} "${FILESDIR}"/postupgrade-${lang}.txt
	done

	webapp_src_install
}

pkg_postinst() {
	webapp_pkg_postinst
}