[gentoo-commits] gentoo-x86 commit in media-sound/lastfmplayer: ChangeLog lastfmplayer-1.5.4.26862-r1.ebuild lastfmplayer-1.5.4.26862-r2.ebuild

[Markos Chandras (hwoarang)]

hwoarang    10/08/26 21:25:24

  Modified:             ChangeLog lastfmplayer-1.5.4.26862-r1.ebuild
  Added:                lastfmplayer-1.5.4.26862-r2.ebuild
  Log:
  Drop RESTRICT=mirror from ebuilds. Put files on our mirrors. Revbump to apply latest debian patchset. Bug #334695
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.48                 media-sound/lastfmplayer/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lastfmplayer/ChangeLog?rev=1.48&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lastfmplayer/ChangeLog?rev=1.48&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lastfmplayer/ChangeLog?r1=1.47&r2=1.48

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/lastfmplayer/ChangeLog,v
retrieving revision 1.47
retrieving revision 1.48
diff -u -r1.47 -r1.48
--- ChangeLog	14 Jul 2010 23:50:51 -0000	1.47
+++ ChangeLog	26 Aug 2010 21:25:24 -0000	1.48
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/lastfmplayer
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/lastfmplayer/ChangeLog,v 1.47 2010/07/14 23:50:51 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/lastfmplayer/ChangeLog,v 1.48 2010/08/26 21:25:24 hwoarang Exp $
+
+*lastfmplayer-1.5.4.26862-r2 (26 Aug 2010)
+
+  26 Aug 2010; Markos Chandras <hwoarang@g.o>
+  lastfmplayer-1.5.4.26862-r1.ebuild, +lastfmplayer-1.5.4.26862-r2.ebuild:
+  Drop RESTRICT=mirror from ebuilds. Put files on our mirrors. Revbump to
+  apply latest debian patchset. Bug #334695
 
   14 Jul 2010; Markos Chandras <hwoarang@g.o>
   -lastfmplayer-1.5.1.31879-r3.ebuild, -lastfmplayer-1.5.4.26862.ebuild:



1.5                  media-sound/lastfmplayer/lastfmplayer-1.5.4.26862-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lastfmplayer/lastfmplayer-1.5.4.26862-r1.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lastfmplayer/lastfmplayer-1.5.4.26862-r1.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lastfmplayer/lastfmplayer-1.5.4.26862-r1.ebuild?r1=1.4&r2=1.5

Index: lastfmplayer-1.5.4.26862-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/lastfmplayer/lastfmplayer-1.5.4.26862-r1.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- lastfmplayer-1.5.4.26862-r1.ebuild	14 Jul 2010 13:28:26 -0000	1.4
+++ lastfmplayer-1.5.4.26862-r1.ebuild	26 Aug 2010 21:25:24 -0000	1.5
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/lastfmplayer/lastfmplayer-1.5.4.26862-r1.ebuild,v 1.4 2010/07/14 13:28:26 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/lastfmplayer/lastfmplayer-1.5.4.26862-r1.ebuild,v 1.5 2010/08/26 21:25:24 hwoarang Exp $
 
 EAPI=2
 inherit eutils multilib toolchain-funcs qt4-r2
@@ -9,14 +9,13 @@
 
 DESCRIPTION="A player for last.fm radio streams"
 HOMEPAGE="http://www.last.fm/help/player"
-SRC_URI="mirror://debian/pool/main/l/lastfm/lastfm_${PV}+dfsg.orig.tar.gz
-	mirror://debian/pool/main/l/lastfm/lastfm_${PV}+dfsg-3.debian.tar.gz"
+SRC_URI="mirror://gentoo/lastfm_${PV}+dfsg.orig.tar.gz
+	mirror://gentoo/lastfm/lastfm_${PV}+dfsg-3.debian.tar.gz"
 
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="amd64 ppc x86"
 IUSE="ipod"
-RESTRICT="mirror"
 
 RDEPEND="x11-libs/qt-gui:4
 	x11-libs/qt-sql:4



1.1                  media-sound/lastfmplayer/lastfmplayer-1.5.4.26862-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lastfmplayer/lastfmplayer-1.5.4.26862-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lastfmplayer/lastfmplayer-1.5.4.26862-r2.ebuild?rev=1.1&content-type=text/plain

Index: lastfmplayer-1.5.4.26862-r2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/lastfmplayer/lastfmplayer-1.5.4.26862-r2.ebuild,v 1.1 2010/08/26 21:25:24 hwoarang Exp $

EAPI=2
inherit eutils multilib toolchain-funcs qt4-r2

MY_P="${P/lastfmplayer/lastfm}+dfsg"

DESCRIPTION="A player for last.fm radio streams"
HOMEPAGE="http://www.last.fm/help/player"
SRC_URI="mirror://gentoo/lastfm_${PV}+dfsg.orig.tar.gz
	mirror://gentoo/lastfm/lastfm_${PV}+dfsg-4.debian.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="ipod"

RDEPEND="x11-libs/qt-gui:4
	x11-libs/qt-sql:4
	media-libs/libsamplerate
	sci-libs/fftw
	media-libs/libmad
	ipod? ( >=media-libs/libgpod-0.5.2 )
	media-libs/alsa-lib"
DEPEND="${RDEPEND}
	app-arch/sharutils"

S=${WORKDIR}/${MY_P}

src_prepare() {
	qt4-r2_src_prepare
	epatch "${FILESDIR}"/fix_plugin_path.patch
	einfo "Applying Debian patchset"
	ebegin "Disabling tray-icon-size patch"
	sed -i "/^tray-icon-size.diff/d" "${WORKDIR}"/debian/patches/series
	eend $?
	cd "${S}"
	for i in $( < "${WORKDIR}"/debian/patches/series); do
		epatch "${WORKDIR}"/debian/patches/$i
	done
	if ! use ipod ; then
		sed -i '/src\/mediadevices\/ipod/d' LastFM.pro || die "sed failed"
	fi
	#don't install plugins into generic location
	sed -i "s:\$\$BIN_DIR/services:\$\$BIN_DIR/lastfm_services:" \
		"${S}"/definitions.pro.inc
	#fix plugin search path
	sed -i "s:/usr/lib/services:/usr/$(get_libdir)/lastfm_services:" \
		"${S}"/src/libMoose/MooseCommon.cpp
}

src_compile() {
	emake CC="$(tc-getCC)" CXX="$(tc-getCXX)" || die "emake failed"
	cd i18n; lrelease *.ts
}

src_install() {
	cd "${WORKDIR}"
	# Docs
	dodoc "${S}"/ChangeLog "${S}"/README debian/README.source \
		|| die "dodoc failed"
	doman debian/lastfm.1 || die "doman failed"

	# Copied from debian/rules
	insinto /usr/share
	doins -r debian/package-files/share/icons || die "failed to install icons"
	insinto /usr/share/lastfm/icons
	doins "${S}"/bin/data/icons/*.png \
		|| die "failed to install application icons"
	insinto /usr/share/lastfm
	doins "${S}"/bin/data/*.png || die "failed to install icons"
	dodir /usr/$(get_libdir)/lastfm_services/
	insinto /usr/$(get_libdir)/lastfm_services/
	insopts -m0755
	doins -r "${S}"/bin/lastfm_services/*.so || die "failed to install plugins"
	insinto /usr/$(get_libdir)
	insopts -m0755
	doins "${S}"/bin/libLastFmTools.so.1* || die "failed to install library"
	doins "${S}"/bin/libMoose.so.1* || die "failed to install library"
	#fix symlinks
	cd "${D}"/usr/$(get_libdir)/
	ln -sfn libLastFmTools.so.1.0.0 libLastFmTools.so.1
	ln -sfn libLastFmTools.so.1.0.0 libLastFmTools.so.1.0
	ln -sfn libMoose.so.1.0.0 libMoose.so.1
	ln -sfn libMoose.so.1.0.0 libMoose.so.1.0
	cd "${WORKDIR}"
	newbin "${S}"/bin/last.fm lastfm || die "newbin failed"
	insinto /usr/share/lastfm/i18n
	doins "${S}"/i18n/*.qm || die "failed to install translations"
	fperms 755 /usr/bin/lastfm
	rm -f "${D}"/usr/share/lastfm/icons/{*profile24,systray_mac}.png
	# create desktop entry
	doicon "${WORKDIR}"/debian/package-files/share/icons/hicolor/48x48/apps/lastfm.png
	make_desktop_entry lastfm "Last.fm Player" lastfm
}

pkg_postinst() {
	elog "To use the Last.fm player with a mozilla based browser:"
	elog " 1. Install gnome-bae/gconf"
	elog " 2. gconftool-2 -t string -s \
/desktop/gnome/url-handlers/lastfm/command \"/usr/bin/lastfm %s\""
	elog " 3. gconftool-2 -s \
/desktop/gnome/url-handlers/lastfm/needs_terminal false -t bool"
	elog " 4. gconftool-2 -t bool -s \
/desktop/gnome/url-handlers/lastfm/enabled true"
	elog
	elog "If you experience awkward fonts or widgets, try running qtconfig."
}