[gentoo-commits] repo/gentoo:master commit in: app-admin/mcelog/

[Ben Kohler]

commit:     311c7f0ece9291da2cacda6b616b7b1ba1477cc3
Author:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 13 14:17:04 2021 +0000
Commit:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Tue Jul 13 14:23:33 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=311c7f0e

app-admin/mcelog: bump to EAPI=8

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>

 app-admin/mcelog/mcelog-177-r1.ebuild | 52 +++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

diff --git a/app-admin/mcelog/mcelog-177-r1.ebuild b/app-admin/mcelog/mcelog-177-r1.ebuild
new file mode 100644
index 00000000000..2ed1d04cc6a
--- /dev/null
+++ b/app-admin/mcelog/mcelog-177-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit linux-info systemd toolchain-funcs
+
+DESCRIPTION="A tool to log and decode Machine Check Exceptions"
+HOMEPAGE="http://mcelog.org/"
+SRC_URI="https://github.com/andikleen/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="selinux"
+
+RDEPEND="selinux? ( sec-policy/selinux-mcelog )"
+
+# TODO: add mce-inject to the tree to support test phase
+RESTRICT="test"
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != buildonly ]]; then
+		local CONFIG_CHECK="~X86_MCE"
+		kernel_is -ge 4 12 && CONFIG_CHECK+=" ~X86_MCELOG_LEGACY"
+		check_extra_config
+	fi
+}
+
+src_prepare() {
+	eapply "${FILESDIR}"/${PN}-0.8_pre1-timestamp-${PN}.patch \
+		"${FILESDIR}"/${PN}-129-debugflags.patch
+	eapply_user
+	tc-export CC
+}
+
+src_install() {
+	default
+
+	insinto /etc/logrotate.d/
+	newins ${PN}.logrotate ${PN}
+
+	newinitd "${FILESDIR}"/${PN}.init-r1 ${PN}
+	systemd_dounit ${PN}.service
+
+	dodoc *.pdf
+}
+
+pkg_postinst() {
+	einfo "The default configuration set is now installed in /etc/${PN}"
+	einfo "you might want to edit those files."
+}