[gentoo-commits] gentoo-x86 commit in net-misc/lldpd: metadata.xml lldpd-0.7.13.ebuild ChangeLog lldpd-0.7.9-r3.ebuild

[Patrick McLean (chutzpah)]

chutzpah    15/01/31 08:05:54

  Modified:             metadata.xml ChangeLog
  Added:                lldpd-0.7.13.ebuild
  Removed:              lldpd-0.7.9-r3.ebuild
  Log:
  Version bump, clean out old version.
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 0xE3F69979BB4B8928DA78E3D17CBF44EF)

Revision  Changes    Path
1.6                  net-misc/lldpd/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/metadata.xml?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/metadata.xml?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/metadata.xml?r1=1.5&r2=1.6

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/lldpd/metadata.xml,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- metadata.xml	22 Sep 2014 18:09:19 -0000	1.5
+++ metadata.xml	31 Jan 2015 08:05:54 -0000	1.6
@@ -26,7 +26,6 @@
 		<flag name='edp'>Enable Extreme Discovery Protocol</flag>
 		<flag name='fdp'>Enable Foundry Discovery Protocol</flag>
 		<flag name='jansson'>Enable JSON output via Jansson</flag>
-		<flag name='json'>Enable JSON output via Jansson</flag>
 		<flag name='json-c'>Enable JSON output via json-c</flag>
 		<flag name='lldpmed'>Enable LLDP-MED extension</flag>
 		<flag name='seccomp'>Enable use of libseccomp for system call filtering</flag>



1.27                 net-misc/lldpd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/ChangeLog?rev=1.27&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/ChangeLog?rev=1.27&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/ChangeLog?r1=1.26&r2=1.27

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/lldpd/ChangeLog,v
retrieving revision 1.26
retrieving revision 1.27
diff -u -r1.26 -r1.27
--- ChangeLog	26 Jan 2015 09:42:29 -0000	1.26
+++ ChangeLog	31 Jan 2015 08:05:54 -0000	1.27
@@ -1,6 +1,14 @@
 # ChangeLog for net-misc/lldpd
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/lldpd/ChangeLog,v 1.26 2015/01/26 09:42:29 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/lldpd/ChangeLog,v 1.27 2015/01/31 08:05:54 chutzpah Exp $
+
+*lldpd-0.7.13 (31 Jan 2015)
+
+  31 Jan 2015; Patrick McLean <chutzpah@g.o> +lldpd-0.7.13.ebuild,
+  -files/lldpd-0.7.9-dont-fork-after-making-pidfile.patch,
+  -files/lldpd-0.7.9-seccomp-add-syscalls.patch, -files/lldpd-initd-3,
+  -lldpd-0.7.9-r3.ebuild, metadata.xml:
+  Version bump, clean out old version.
 
   26 Jan 2015; Agostino Sarubbo <ago@g.o> lldpd-0.7.11-r3.ebuild:
   Stable for x86, wrt bug #535606



1.1                  net-misc/lldpd/lldpd-0.7.13.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/lldpd-0.7.13.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/lldpd/lldpd-0.7.13.ebuild?rev=1.1&content-type=text/plain

Index: lldpd-0.7.13.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/lldpd/lldpd-0.7.13.ebuild,v 1.1 2015/01/31 08:05:54 chutzpah Exp $

EAPI=5

inherit eutils user systemd bash-completion-r1 autotools

DESCRIPTION="Implementation of IEEE 802.1ab (LLDP)"
HOMEPAGE="http://vincentbernat.github.com/lldpd/"
SRC_URI="http://media.luffy.cx/files/${PN}/${P}.tar.gz"

LICENSE="ISC"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cdp doc +dot1 +dot3 edp fdp graph jansson json-c +lldpmed seccomp sonmp
	snmp static-libs readline xml zsh-completion"

RDEPEND=">=dev-libs/libevent-2.0.5
		snmp? ( net-analyzer/net-snmp[extensible(+)] )
		xml? ( dev-libs/libxml2 )
		jansson? ( dev-libs/jansson )
		json-c? ( dev-libs/json-c )
		seccomp? ( sys-libs/libseccomp )
		zsh-completion? ( app-shells/zsh )"
DEPEND="${RDEPEND}
		virtual/pkgconfig
		doc? (
			graph? ( app-doc/doxygen[dot] )
			!graph? ( app-doc/doxygen )
		)"

REQUIRED_USE="graph? ( doc ) json-c? ( !jansson )"

PATCHES=(
	"${FILESDIR}"/${PN}-0.7.11-zsh-completion-dir.patch
	"${FILESDIR}"/${PN}-0.7.11-bash-completion-dir.patch
)

pkg_setup() {
	ebegin "Creating lldpd user and group"
	enewgroup ${PN}
	enewuser ${PN} -1 -1 -1 ${PN}
	eend $?
}

src_prepare() {
	epatch "${PATCHES[@]}"
	epatch_user
	eautoreconf
	elibtoolize
}

src_configure() {
	econf \
		--without-embedded-libevent \
		--with-privsep-user=${PN} \
		--with-privsep-group=${PN} \
		--with-privsep-chroot=/run/${PN} \
		--with-lldpd-ctl-socket=/run/${PN}.socket \
		--with-lldpd-pid-file=/run/${PN}.pid \
		--docdir=/usr/share/doc/${PF} \
		$(use_enable graph doxygen-dot) \
		$(use_enable doc doxygen-man) \
		$(use_enable doc doxygen-pdf) \
		$(use_enable doc doxygen-html) \
		$(use_enable cdp) \
		$(use_enable dot1) \
		$(use_enable dot3) \
		$(use_enable edp) \
		$(use_enable fdp) \
		$(use_enable lldpmed) \
		$(use_enable sonmp) \
		$(use_enable static-libs static) \
		$(use_with json-c) \
		$(use_with jansson) \
		$(use_with readline) \
		$(use_with seccomp) \
		$(use_with snmp) \
		$(use_with xml)
}

src_compile() {
	emake
	use doc && emake doxygen-doc
}

src_install() {
	emake DESTDIR="${D}" install
	prune_libtool_files

	newinitd "${FILESDIR}"/${PN}-initd-4 ${PN}
	newconfd "${FILESDIR}"/${PN}-confd-1 ${PN}
	newbashcomp src/client/lldpcli.bash-completion lldpcli

	use doc && dohtml -r doxygen/html/*

	keepdir /etc/${PN}.d

	systemd_dounit "${FILESDIR}"/${PN}.service
}