[gentoo-commits] repo/gentoo:master commit in: sys-devel/icecream/

[Conrad Kostecki]

commit:     308c3d52f1b34e45e086d0c5264a86bf943def40
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 18 11:11:28 2021 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Sun Jul 18 16:17:29 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=308c3d52

sys-devel/icecream: migrate to GLEP 81

Bug: https://bugs.gentoo.org/781506
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 sys-devel/icecream/icecream-1.0.0-r3.ebuild | 62 +++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/sys-devel/icecream/icecream-1.0.0-r3.ebuild b/sys-devel/icecream/icecream-1.0.0-r3.ebuild
new file mode 100644
index 00000000000..53e06f4ae2b
--- /dev/null
+++ b/sys-devel/icecream/icecream-1.0.0-r3.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="${P/icecream/icecc}"
+
+DESCRIPTION="Distributed compiling of C(++) code across several machines; based on distcc"
+HOMEPAGE="https://github.com/icecc/icecream"
+SRC_URI="ftp://ftp.suse.com/pub/projects/${PN}/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~sparc ~x86"
+
+DEPEND="sys-libs/libcap-ng"
+RDEPEND="
+	${DEPEND}
+	acct-group/icecream
+	acct-user/icecream
+	dev-util/shadowman
+"
+
+PATCHES=( "${FILESDIR}/${P}-libcap-ng.patch" )
+
+src_configure() {
+	local myeconfargs=(
+		--enable-shared --disable-static
+		--enable-clang-wrappers
+		--enable-clang-rewrite-includes
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	newconfd suse/sysconfig.icecream icecream
+	newinitd "${FILESDIR}"/icecream-r2 icecream
+
+	insinto /etc/logrotate.d
+	newins suse/logrotate icecream
+
+	insinto /usr/share/shadowman/tools
+	newins - icecc <<<'/usr/libexec/icecc/bin'
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_prerm() {
+	if [[ -z ${REPLACED_BY_VERSION} && ${ROOT} == / ]]; then
+		eselect compiler-shadow remove icecc
+	fi
+}
+
+pkg_postinst() {
+	if [[ ${ROOT} == / ]]; then
+		eselect compiler-shadow update icecc
+	fi
+}