[gentoo-commits] gentoo-x86 commit in sys-apps/iproute2: ChangeLog iproute2-9999.ebuild iproute2-2.6.31.ebuild

[Mike Frysinger (vapier)]

vapier      09/12/26 19:54:26

  Modified:             ChangeLog iproute2-9999.ebuild
  Added:                iproute2-2.6.31.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc61/cvs/Linux x86_64)

Revision  Changes    Path
1.146                sys-apps/iproute2/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/iproute2/ChangeLog?rev=1.146&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/iproute2/ChangeLog?rev=1.146&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/iproute2/ChangeLog?r1=1.145&r2=1.146

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/iproute2/ChangeLog,v
retrieving revision 1.145
retrieving revision 1.146
diff -u -r1.145 -r1.146
--- ChangeLog	26 Dec 2009 19:44:40 -0000	1.145
+++ ChangeLog	26 Dec 2009 19:54:26 -0000	1.146
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/iproute2
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/ChangeLog,v 1.145 2009/12/26 19:44:40 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/ChangeLog,v 1.146 2009/12/26 19:54:26 vapier Exp $
+
+*iproute2-2.6.31 (26 Dec 2009)
+
+  26 Dec 2009; Mike Frysinger <vapier@g.o> +iproute2-2.6.31.ebuild,
+  iproute2-9999.ebuild:
+  Version bump.
 
   26 Dec 2009; Mike Frysinger <vapier@g.o>
   iproute2-2.6.29.1-r1.ebuild:



1.9                  sys-apps/iproute2/iproute2-9999.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild?r1=1.8&r2=1.9

Index: iproute2-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- iproute2-9999.ebuild	22 Nov 2009 17:42:45 -0000	1.8
+++ iproute2-9999.ebuild	26 Dec 2009 19:54:26 -0000	1.9
@@ -1,10 +1,10 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild,v 1.8 2009/11/22 17:42:45 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild,v 1.9 2009/12/26 19:54:26 vapier Exp $
 
 EAPI="2"
 
-inherit eutils toolchain-funcs
+inherit eutils toolchain-funcs flag-o-matic
 
 if [[ ${PV} == "9999" ]] ; then
 	EGIT_REPO_URI="git://git.kernel.org/pub/scm/linux/kernel/git/shemminger/iproute2.git"
@@ -13,7 +13,7 @@
 	#KEYWORDS=""
 else
 	if [[ ${PV} == *.*.*.* ]] ; then
-		MY_PV=${PV%.*}
+		MY_PV=${PV%.*}-${PV##*.}
 	else
 		MY_PV=${PV}
 	fi
@@ -51,21 +51,17 @@
 	# build against system headers
 	rm -r include/netinet #include/linux include/ip{,6}tables{,_common}.h include/libiptc
 
-	epatch "${FILESDIR}"/${PN}-2.6.26-ldflags.patch #236861
 	epatch "${FILESDIR}"/${PN}-2.6.29.1-flush.patch #274973
+	epatch "${FILESDIR}"/${PN}-2.6.29.1-hfsc.patch #291907
 
 	epatch_user
 
 	# don't build arpd if USE=-berkdb #81660
 	use berkdb || sed -i '/^TARGETS=/s: arpd : :' misc/Makefile
 	# Multilib fixes
-	sed -i 's:/usr/local:/usr:' tc/m_ipt.c include/iptables.h
 	sed -i "s:/usr/lib:/usr/$(get_libdir):g" \
-		netem/Makefile tc/{Makefile,tc.c,q_netem.c,m_ipt.c} include/iptables.h || die
+		netem/Makefile tc/{Makefile,tc.c,q_netem.c,m_ipt.c} || die
 	sed -i "s:/lib/tc:$(get_libdir)/tc:g" tc/Makefile || die
-	# Use correct iptables dir, #144265
-	sed -i "s:/usr/local/lib/iptables:/$(get_libdir)/iptables:g" \
-		include/iptables.h
 }
 
 src_configure() {
@@ -75,6 +71,9 @@
 		|| echo 'n' >> Config
 
 	use minimal && sed -i -e '/^SUBDIRS=/s:=.*:=lib tc:' Makefile
+
+	# Use correct iptables dir, #144265 #293709
+	append-cppflags -DIPT_LIB_DIR=\\\"`$(tc-getPKG_CONFIG) xtables --variable=xtlibdir`\\\"
 }
 
 src_compile() {
@@ -98,6 +97,7 @@
 		MANDIR=/usr/share/man \
 		install \
 		|| die "make install failed"
+	prepalldocs
 	if use berkdb ; then
 		dodir /var/lib/arpd
 		# bug 47482, arpd doesn't need to be in /sbin



1.1                  sys-apps/iproute2/iproute2-2.6.31.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/iproute2/iproute2-2.6.31.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/iproute2/iproute2-2.6.31.ebuild?rev=1.1&content-type=text/plain

Index: iproute2-2.6.31.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/iproute2-2.6.31.ebuild,v 1.1 2009/12/26 19:54:26 vapier Exp $

EAPI="2"

inherit eutils toolchain-funcs flag-o-matic

if [[ ${PV} == "9999" ]] ; then
	EGIT_REPO_URI="git://git.kernel.org/pub/scm/linux/kernel/git/shemminger/iproute2.git"
	inherit git
	SRC_URI=""
	#KEYWORDS=""
else
	if [[ ${PV} == *.*.*.* ]] ; then
		MY_PV=${PV%.*}-${PV##*.}
	else
		MY_PV=${PV}
	fi
	MY_P="${PN}-${MY_PV}"
	SRC_URI="http://developer.osdl.org/dev/iproute2/download/${MY_P}.tar.bz2"
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
	S=${WORKDIR}/${MY_P}
fi

DESCRIPTION="kernel routing and traffic control utilities"
HOMEPAGE="http://www.linuxfoundation.org/collaborate/workgroups/networking/iproute2"

LICENSE="GPL-2"
SLOT="0"
IUSE="atm berkdb minimal"

RDEPEND="!net-misc/arpd
	!minimal? ( berkdb? ( sys-libs/db ) )
	atm? ( net-dialup/linux-atm )"
DEPEND="${RDEPEND}
	elibc_glibc? ( >=sys-libs/glibc-2.7 )
	>=virtual/os-headers-2.6.27"

src_unpack() {
	if [[ ${PV} == "9999" ]] ; then
		git_src_unpack
	else
		unpack ${A}
	fi
}

src_prepare() {
	sed -i "s:-O2:${CFLAGS} ${CPPFLAGS}:" Makefile || die "sed Makefile failed"

	# build against system headers
	rm -r include/netinet #include/linux include/ip{,6}tables{,_common}.h include/libiptc

	epatch "${FILESDIR}"/${PN}-2.6.29.1-flush.patch #274973
	epatch "${FILESDIR}"/${PN}-2.6.29.1-hfsc.patch #291907

	epatch_user

	# don't build arpd if USE=-berkdb #81660
	use berkdb || sed -i '/^TARGETS=/s: arpd : :' misc/Makefile
	# Multilib fixes
	sed -i "s:/usr/lib:/usr/$(get_libdir):g" \
		netem/Makefile tc/{Makefile,tc.c,q_netem.c,m_ipt.c} || die
	sed -i "s:/lib/tc:$(get_libdir)/tc:g" tc/Makefile || die
}

src_configure() {
	echo -n 'TC_CONFIG_ATM:=' > Config
	use atm \
		&& echo 'y' >> Config \
		|| echo 'n' >> Config

	use minimal && sed -i -e '/^SUBDIRS=/s:=.*:=lib tc:' Makefile

	# Use correct iptables dir, #144265 #293709
	append-cppflags -DIPT_LIB_DIR=\\\"`$(tc-getPKG_CONFIG) xtables --variable=xtlibdir`\\\"
}

src_compile() {
	emake \
		CC="$(tc-getCC)" \
		AR="$(tc-getAR)" \
		|| die "make failed"
}

src_install() {
	if use minimal ; then
		into /
		dosbin tc/tc || die "minimal"
		return 0
	fi

	emake \
		DESTDIR="${D}" \
		SBINDIR=/sbin \
		DOCDIR=/usr/share/doc/${PF} \
		MANDIR=/usr/share/man \
		install \
		|| die "make install failed"
	prepalldocs
	if use berkdb ; then
		dodir /var/lib/arpd
		# bug 47482, arpd doesn't need to be in /sbin
		dodir /usr/sbin
		mv "${D}"/sbin/arpd "${D}"/usr/sbin/
	fi
}