[gentoo-commits] repo/gentoo:master commit in: dev-python/flask-bootstrap/

[Ian Delaney]

commit:     a6a5a81f8d913697d654fc1c9c2ca12c0062dd00
Author:     Louis Sautier <sautier.louis <AT> gmail <DOT> com>
AuthorDate: Mon Apr 25 23:09:19 2016 +0000
Commit:     Ian Delaney <idella4 <AT> gentoo <DOT> org>
CommitDate: Fri Apr 29 07:09:44 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a6a5a81f

dev-python/flask-bootstrap: new package, version 3.3.5.7

Package-Manager: portage-2.2.28
Closes: https://github.com/gentoo/gentoo/pull/1353

Signed-off-by: Ian Delaney <idella4 <AT> gentoo.org>

 dev-python/flask-bootstrap/Manifest                |  1 +
 .../flask-bootstrap/flask-bootstrap-3.3.5.7.ebuild | 57 ++++++++++++++++++++++
 dev-python/flask-bootstrap/metadata.xml            | 17 +++++++
 3 files changed, 75 insertions(+)

diff --git a/dev-python/flask-bootstrap/Manifest b/dev-python/flask-bootstrap/Manifest
new file mode 100644
index 0000000..fd71a78
--- /dev/null
+++ b/dev-python/flask-bootstrap/Manifest
@@ -0,0 +1 @@
+DIST flask-bootstrap-3.3.5.7.tar.gz 485387 SHA256 f0cb530ff85a6756dd42a73f49783484eb06db2153a8ebb2ee2f2bf3152f2fa7 SHA512 2d8ed707ccd0dc028f7d765e1f213890186583b28b3879dae0df0282c5e068c91a285691355acf6742999a8bd96920a614098bf9f79ab67f3f40c1a17ac452a6 WHIRLPOOL 81d31625f2b9e35147c34a265405da561a9f91b9ccaf439588c01df68ec33e00c358bcecd78353e21ac1bc8dc6fbbc0b9aed534976b080efead4b0647a46ced5

diff --git a/dev-python/flask-bootstrap/flask-bootstrap-3.3.5.7.ebuild b/dev-python/flask-bootstrap/flask-bootstrap-3.3.5.7.ebuild
new file mode 100644
index 0000000..62de095
--- /dev/null
+++ b/dev-python/flask-bootstrap/flask-bootstrap-3.3.5.7.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="An extension that includes Bootstrap in your project, without boilerplate code"
+HOMEPAGE="https://pythonhosted.org/Flask-Bootstrap/"
+# PyPI tarballs don't include tests
+# https://github.com/mbr/flask-bootstrap/pull/134
+SRC_URI="https://github.com/mbr/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/dominate[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/visitor[${PYTHON_USEDEP}]
+	dev-python/wtforms[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/flask-appconfig[${PYTHON_USEDEP}]
+		dev-python/flask-debug[${PYTHON_USEDEP}]
+		dev-python/flask-wtf[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		${RDEPEND}
+	)
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+
+python_prepare_all() {
+	sed -i "s/, 'sphinx.ext.intersphinx'//" docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	# Skip one test which requires network access
+	py.test -k "not test_versions_match" || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}

diff --git a/dev-python/flask-bootstrap/metadata.xml b/dev-python/flask-bootstrap/metadata.xml
new file mode 100644
index 0000000..0811c94
--- /dev/null
+++ b/dev-python/flask-bootstrap/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>sautier.louis@×××××.com</email>
+		<name>Louis Sautier</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@g.o</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">flask-bootstrap</remote-id>
+		<remote-id type="github">mbr/flask-bootstrap</remote-id>
+		<bugs-to>https://github.com/mbr/flask-bootstrap/issues</bugs-to>
+	</upstream>
+</pkgmetadata>