[gentoo-commits] repo/gentoo:master commit in: app-emulation/containers-storage/

[Zac Medico]

commit:     ba154e05856863d5f17c9f2f2ed4987e971df728
Author:     Zac Medico <zmedico <AT> gentoo <DOT> org>
AuthorDate: Thu Jun  6 19:31:57 2019 +0000
Commit:     Zac Medico <zmedico <AT> gentoo <DOT> org>
CommitDate: Thu Jun  6 19:31:57 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ba154e05

app-emulation/containers-storage: Bump to version 1.12.9

Package-Manager: Portage-2.3.67, Repoman-2.3.14
Signed-off-by: Zac Medico <zmedico <AT> gentoo.org>

 app-emulation/containers-storage/Manifest          |   1 +
 .../containers-storage-1.12.9.ebuild               | 110 +++++++++++++++++++++
 2 files changed, 111 insertions(+)

diff --git a/app-emulation/containers-storage/Manifest b/app-emulation/containers-storage/Manifest
index 89e7a21a47e..fa6fac3b2db 100644
--- a/app-emulation/containers-storage/Manifest
+++ b/app-emulation/containers-storage/Manifest
@@ -1,2 +1,3 @@
 DIST containers-storage-1.12.8.tar.gz 1591018 BLAKE2B cbcc46e86d6c00badfa3e9d5988757fca969fb1b61f6cd0f81cf257c6feac6deefbdad8534fd99e52842efcfd5099ca0d7e27966b0eb16f699e6c1c06e90c683 SHA512 2badef5ccd7292c77ad5de70403c6d343c3a19a81c0e7c22539eb939b5a3ea59447176d5d3d99e34e9877a11b3608268f8951bc74378be99c074ba2a31f27fdb
+DIST containers-storage-1.12.9.tar.gz 1593286 BLAKE2B f53ef233e3d08dad84cda9154271254f9fe04e951643f20e8ab5bd37456e4eeb7083c1810656072c2b4bdeea0f6188871d4db566363c8363d2c2087ab9a4d3cb SHA512 0b5ad6cb52b4b74da7c574ec6841d74b92ef20f853e8d8fed83e0f9d529a7749692225e26ae4ab89fbd2a6202651c8a3a44a57bc1f42bcbb755fdba26e9cb3fd
 DIST github.com-pquerna-ffjson-e517b90714f7c0eabe6d2e570a5886ae077d6db6.tar.gz 103470 BLAKE2B 81f0f6ea6648997cb61723d09d456802e60a3d1eb35134c4bbc8af5943b955b1402fe2b3f8d0d4d2d0293ab256a9be66d53262d5f79ca00bf8c18ded39dc44f4 SHA512 fadca5a7bd0c0578b23281720a08c505054f3497daeee8efa36b5acafa4118feb4b8a96c4acb4c279d72ebcd50846307cfbb846a355b62f350c961f9102c93a6

diff --git a/app-emulation/containers-storage/containers-storage-1.12.9.ebuild b/app-emulation/containers-storage/containers-storage-1.12.9.ebuild
new file mode 100644
index 00000000000..312d2cda060
--- /dev/null
+++ b/app-emulation/containers-storage/containers-storage-1.12.9.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+EGO_VENDOR=(
+	"github.com/pquerna/ffjson e517b90714f7c0eabe6d2e570a5886ae077d6db6"
+)
+
+inherit golang-vcs-snapshot
+
+KEYWORDS="~amd64"
+DESCRIPTION="containers/storage library"
+HOMEPAGE="https://github.com/containers/storage"
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="btrfs +device-mapper ostree test"
+EGO_PN="${HOMEPAGE#*//}"
+EGIT_COMMIT="v${PV}"
+SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz
+	${EGO_VENDOR_URI}"
+RDEPEND="
+	btrfs? ( sys-fs/btrfs-progs )
+	device-mapper? ( sys-fs/lvm2:= )
+	ostree? (
+		dev-libs/glib:=
+		dev-util/ostree:=
+	)"
+DEPEND="${RDEPEND}
+	dev-go/go-md2man
+	test? (
+		sys-fs/btrfs-progs
+		sys-fs/lvm2
+		sys-apps/util-linux
+	)"
+RESTRICT="test? ( userpriv ) !test? ( test )"
+
+src_unpack() {
+	golang-vcs-snapshot_src_unpack
+}
+
+src_prepare() {
+	default
+
+	[[ -f ${S}/src/${EGO_PN}/hack/btrfs_tag.sh ]] || die
+	use btrfs || { echo -e "#!/bin/sh\necho btrfs_noversion exclude_graphdriver_btrfs" > \
+		"${S}/src/${EGO_PN}/hack/btrfs_tag.sh" || die; }
+
+	[[ -f ${S}/src/${EGO_PN}/hack/libdm_tag.sh ]] || die
+	use device-mapper || { echo -e "#!/bin/sh\necho btrfs_noversion exclude_graphdriver_devicemapper" > \
+		"${S}/src/${EGO_PN}/hack/libdm_tag.sh" || die; }
+
+	[[ -f ${S}/src/${EGO_PN}/hack/ostree_tag.sh ]] || die
+	use ostree || { echo -e "#!/bin/sh\ntrue" > \
+		"${S}/src/${EGO_PN}/hack/ostree_tag.sh" || die; }
+
+	sed -e 's:TestChrootUntarPath(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/chrootarchive/archive_test.go" || die
+	sed -e 's:TestTarUntar(:_\0:' \
+		-e 's:TestTarWithOptionsChownOptsAlwaysOverridesIdPair(:_\0:' \
+		-e 's:TestTarWithOptions(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/archive/archive_test.go" || die
+	sed -e 's:TestTarUntarWithXattr(:_\0:' \
+		-e 's:TestTarWithBlockCharFifo(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/archive/archive_unix_test.go" || die
+	sed -e 's:TestTarUntarWithXattr(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/archive/archive_test.go" || die
+	sed -e 's:TestApplyLayer(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/archive/changes_test.go" || die
+	sed -e 's:TestApplyLayerInvalidFilenames(:_\0:' \
+		-e 's:TestApplyLayerInvalidHardlink(:_\0:' \
+		-e 's:TestApplyLayerInvalidSymlink(:_\0:' \
+		-e 's:TestApplyLayerWhiteouts(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/archive/diff_test.go" || die
+	sed -e 's:TestCopyCaseE(:_\0:' \
+		-e 's:TestCopyCaseEFSym(:_\0:' \
+		-e 's:TestCopyCaseG(:_\0:' \
+		-e 's:TestCopyCaseGFSym(:_\0:' \
+		-e 's:TestCopyCaseH(:_\0:' \
+		-e 's:TestCopyCaseHFSym(:_\0:' \
+		-e 's:TestCopyCaseJ(:_\0:' \
+		-e 's:TestCopyCaseJFSym(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/archive/copy_unix_test.go" || die
+	sed -e 's:TestMount(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/mount/mounter_linux_test.go" || die
+}
+
+src_compile() {
+	export -n GOCACHE XDG_CACHE_HOME #678856
+	mkdir -p "${S}/src/github.com/pquerna" || die
+	ln -s "${S}/src/${EGO_PN}/vendor/github.com/pquerna/ffjson" "${WORKDIR}/${P}/src/github.com/pquerna/ffjson" || die
+	mkdir -p "${S}/bin" || die
+	cd "${S}/bin" || die
+	GOPATH="${S}" GOBIN="${S}/bin" \
+		go build -v -work -x ${EGO_BUILD_FLAGS} "${S}/src/github.com/pquerna/ffjson/ffjson.go" || die
+	GOPATH="${S}" GOBIN="${S}/bin" PATH="${S}/bin:${PATH}" \
+		emake -C "${S}/src/${EGO_PN}" containers-storage docs
+}
+
+src_install() {
+	dobin "${S}/src/${EGO_PN}/${PN}"
+	while read -r -d ''; do
+		mv "${REPLY}" "${REPLY%.1}" || die
+	done < <(find "${S}/src/${EGO_PN}/docs" -name '*.[[:digit:]].1' -print0)
+	find "${S}/src/${EGO_PN}/docs" -name '*.[[:digit:]]' -exec doman '{}' + || die
+}
+
+src_test() {
+	GOPATH="${S}" unshare -m emake -C "${S}/src/${EGO_PN}" FLAGS="-v -work -x" local-test-unit || die
+}