[gentoo-commits] proj/lisp:master commit in: dev-lisp/asdf/

[José María Alonso]

commit:     b8ddc0187d0889662c3c40884729fb35efff959b
Author:     Chema Alonso Josa <nimiux <AT> gentoo <DOT> org>
AuthorDate: Sun Oct  1 18:44:50 2017 +0000
Commit:     José María Alonso <nimiux <AT> gentoo <DOT> org>
CommitDate: Sun Oct  1 18:44:50 2017 +0000
URL:        https://gitweb.gentoo.org/proj/lisp.git/commit/?id=b8ddc018

dev-lisp/asdf: Adds test phase. Installs info file.

Gentoo-Bug: 605752
Gentoo-Bug: 623494

 dev-lisp/asdf/asdf-3.2.1-r1.ebuild | 60 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/dev-lisp/asdf/asdf-3.2.1-r1.ebuild b/dev-lisp/asdf/asdf-3.2.1-r1.ebuild
new file mode 100644
index 00000000..10fefccb
--- /dev/null
+++ b/dev-lisp/asdf/asdf-3.2.1-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils prefix common-lisp-3
+
+DESCRIPTION="ASDF is Another System Definition Facility for Common Lisp"
+HOMEPAGE="http://common-lisp.net/project/asdf/"
+SRC_URI="http://common-lisp.net/project/${PN}/archives/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~x86-solaris"
+IUSE="doc"
+
+SLOT="0/${PVR}"
+
+DEPEND="!dev-lisp/cl-${PN}
+		!dev-lisp/asdf-binary-locations
+		!dev-lisp/gentoo-init
+		!<dev-lisp/asdf-2.33-r3
+		doc? ( virtual/texi2dvi )"
+RDEPEND=""
+PDEPEND="~dev-lisp/uiop-${PV}"
+
+COMMONLISPS="sbcl clisp clozurecl cmucl ecls"
+
+find-lisp-impl() {
+	for lisp in ${COMMONLISPS} ; do
+		[[ "$(best_version dev-lisp/${lisp})" ]] && echo "${lisp}" && return
+	done
+	die "No CommonLisp implementation found"
+}
+
+install_docs() {
+	(cd doc ; dodoc *.{html,css,ico,png} "${PN}.pdf" ; dodoc -r asdf ; doinfo "${PN}.info" )
+}
+
+src_compile() {
+	emake
+	use doc && emake -C doc
+}
+
+src_test() {
+	common-lisp-export-impl-args "$(find-lisp-impl)"
+	test/run-tests.sh ${CL_BINARY}
+}
+
+src_install() {
+	insinto "${CLSOURCEROOT}/${PN}"
+	doins -r build version.lisp-expr
+	dodoc README.md TODO
+	use doc && install_docs
+	insinto /etc/common-lisp
+	cd "${T}" || die
+	cp "${FILESDIR}/gentoo-init.lisp" "${FILESDIR}/source-registry.conf" . || die
+	eprefixify gentoo-init.lisp source-registry.conf
+	doins gentoo-init.lisp source-registry.conf
+}