[gentoo-commits] gentoo-x86 commit in sys-apps/gnome-disk-utility: ChangeLog gnome-disk-utility-2.32.1.ebuild

[Nirbheek Chauhan (nirbheek)]

nirbheek    11/01/31 09:47:32

  Modified:             ChangeLog
  Added:                gnome-disk-utility-2.32.1.ebuild
  Log:
  Add 2.32.1, needs libnotify-0.7
  
  (Portage version: 2.1.9.35/cvs/Linux x86_64)

Revision  Changes    Path
1.31                 sys-apps/gnome-disk-utility/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/gnome-disk-utility/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/gnome-disk-utility/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/gnome-disk-utility/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/gnome-disk-utility/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog	17 Jan 2011 18:30:12 -0000	1.30
+++ ChangeLog	31 Jan 2011 09:47:32 -0000	1.31
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/gnome-disk-utility
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/gnome-disk-utility/ChangeLog,v 1.30 2011/01/17 18:30:12 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/gnome-disk-utility/ChangeLog,v 1.31 2011/01/31 09:47:32 nirbheek Exp $
+
+*gnome-disk-utility-2.32.1 (31 Jan 2011)
+
+  31 Jan 2011; Nirbheek Chauhan <nirbheek@g.o>
+  +gnome-disk-utility-2.32.1.ebuild:
+  Add 2.32.1, needs libnotify-0.7
 
 *gnome-disk-utility-2.32.0-r1 (17 Jan 2011)
 



1.1                  sys-apps/gnome-disk-utility/gnome-disk-utility-2.32.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/gnome-disk-utility/gnome-disk-utility-2.32.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/gnome-disk-utility/gnome-disk-utility-2.32.1.ebuild?rev=1.1&content-type=text/plain

Index: gnome-disk-utility-2.32.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/gnome-disk-utility/gnome-disk-utility-2.32.1.ebuild,v 1.1 2011/01/31 09:47:32 nirbheek Exp $

EAPI="3"
GCONF_DEBUG="no"

inherit autotools eutils gnome2

DESCRIPTION="Disk Utility for GNOME using devicekit-disks"
HOMEPAGE="http://git.gnome.org/browse/gnome-disk-utility"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="avahi doc fat gnome-keyring nautilus remote-access"

CDEPEND="
	>=dev-libs/glib-2.22:2
	>=dev-libs/dbus-glib-0.74
	>=dev-libs/libunique-1
	>=x11-libs/gtk+-2.20:2
	=sys-fs/udisks-1.0*[remote-access?]
	>=dev-libs/libatasmart-0.14
	>=x11-libs/libnotify-0.6.1

	>=gnome-base/nautilus-2.24

	avahi? ( >=net-dns/avahi-0.6.25[gtk] )
	gnome-keyring? ( || (
		gnome-base/libgnome-keyring
		<gnome-base/gnome-keyring-2.29.4 ) )
"
RDEPEND="${CDEPEND}
	fat? ( sys-fs/dosfstools )
	!!sys-apps/udisks"
DEPEND="${CDEPEND}
	sys-devel/gettext
	gnome-base/gnome-common
	app-text/scrollkeeper
	app-text/gnome-doc-utils

	>=dev-util/pkgconfig-0.9
	>=dev-util/intltool-0.35
	>=dev-util/gtk-doc-am-1.13

	doc? ( >=dev-util/gtk-doc-1.3 )"

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-static
		$(use_enable avahi avahi-ui)
		$(use_enable nautilus)
		$(use_enable remote-access)
		$(use_enable gnome-keyring)"
	DOCS="AUTHORS NEWS README TODO"
}

src_prepare() {
	# Keep avahi optional, upstream bug #631986
	epatch "${FILESDIR}/${PN}-2.30.1-optional-avahi.patch"

	intltoolize --force --copy --automake || die
	eautoreconf
}

src_install() {
	gnome2_src_install
	find "${ED}" -name "*.la" -delete || die "remove of la files failed"
}