[gentoo-commits] repo/gentoo:master commit in: games-action/descent2-demodata/

[James Le Cuirot]

commit:     86bcbef9502d4289e40bb64ed68036ce1c035b89
Author:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
AuthorDate: Mon Mar 13 23:20:18 2017 +0000
Commit:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Thu Apr 27 21:41:26 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=86bcbef9

games-action/descent2-demodata: EAPI bump, cleanups, drop dead mirrors

Package-Manager: Portage-2.3.4, Repoman-2.3.2

 .../descent2-demodata-1.0-r1.ebuild                | 54 ++++++++++++++++++++++
 1 file changed, 54 insertions(+)

diff --git a/games-action/descent2-demodata/descent2-demodata-1.0-r1.ebuild b/games-action/descent2-demodata/descent2-demodata-1.0-r1.ebuild
new file mode 100644
index 00000000000..9923919ecad
--- /dev/null
+++ b/games-action/descent2-demodata/descent2-demodata-1.0-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MY_PN="d2demo"
+DEMO="${MY_PN}${PV//.}.zip"
+
+DESCRIPTION="Demo data files for Descent 2"
+HOMEPAGE="http://www.interplay.com/games/descent.php"
+SRC_URI="ftp://ftp.funet.fi/pub/msdos/games/interplay/${DEMO}"
+LICENSE="free-noncomm"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+# <d2x-0.2.5-r3 may include the data.
+RDEPEND="!<games-action/d2x-0.2.5-r3
+	!games-action/descent2-data"
+
+DEPEND="app-arch/unzip
+	app-arch/unarj"
+
+S="${WORKDIR}"
+
+src_unpack() {
+	default
+
+	# This is much more fun than simply downloading
+	# http://www.icculus.org/d2x/data/d2shar10.tar.gz
+	unarj e D2_1.SOW || die
+	mv ${MY_PN}.ham{,1} || die
+	unarj e D2_2.SOW || die
+	mv ${MY_PN}.ham{,2} || die
+	mv ${MY_PN}.pig{,2} || die
+	unarj e D2_3.SOW || die
+	mv ${MY_PN}.pig{,3} || die
+
+	# From the sows, big porkie pies shall grow
+	cat ${MY_PN}.ham{1,2} > ${MY_PN}.ham || die
+	cat ${MY_PN}.pig{2,3} > ${MY_PN}.pig || die
+}
+
+src_install() {
+	insinto /usr/share/games/d2x
+	doins *.{ham,hog,pig}
+	insinto /usr/share/games/d2x/demos
+	doins *.dem
+	dodoc *.txt
+}
+
+pkg_postinst() {
+	elog "A client is needed to run the game, e.g. games-action/dxx-rebirth."
+	echo
+}