[gentoo-commits] repo/gentoo:master commit in: dev-python/tox/

[Michał Górny]

commit:     f5edb71c6069a8ba9a7f1d9f235aa19ba63b8c50
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Jan  3 06:05:16 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Jan  3 06:23:42 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f5edb71c

dev-python/tox: Bump to 4.1.3

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/tox/Manifest         |  1 +
 dev-python/tox/tox-4.1.3.ebuild | 86 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 87 insertions(+)

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 6398af88cf20..ff5617395930 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1,3 +1,4 @@
 DIST tox-3.27.1.gh.tar.gz 309006 BLAKE2B fa8aaa9cd5b03e54c166bb6b748290420b91498b26d2d124d9f88a64806b9ac0578c1886845b25aa024907f6a782c45609fa6c7657d9e1f538b59c2d9f0f4e14 SHA512 5f568bc6c53f871aae91928681dd6f2419b876a8e6ca925e65abae845b548ee3d00513741882875bbbacb78bf64935228d98213f940d3da8c3f788b73f177b79
 DIST tox-3.28.0.gh.tar.gz 309472 BLAKE2B 9896411426f6aebb3efa468c01696ecc5f17ec3e67825672d0efc74c1b1468bc8b8d9c14b6177c181750ba4b9a5e77d616068dd83e21f5641acfc8e2a271cc1f SHA512 64816754e6800661bb564c5c7d21c4139522d540a04fafe3c4591d596072d48d1cbe0ee2abee9c8faf3d5007774f5371431b5a7a8f49912bc879c7b168aab2ca
 DIST tox-4.1.2.gh.tar.gz 286306 BLAKE2B 67e52bf01c383e255b22c5c71eecf01d4a041cf4c4399df60451c74acd79bbd1b30f787bcf4f10896804ca1b0cc8b02f6ff4d5e0b7e7ac64284da33f09c95bc9 SHA512 7ff44624c26d609c33dce2cec5bd177caf70b8628f64c48f1fae5130001c508b82079ea4f2487cf8d10b371d0b95cc998c21c47a5080e964db40a3ebafe01a93
+DIST tox-4.1.3.gh.tar.gz 286917 BLAKE2B 0dc7979be947087a126325947b73bbf832c714d2a5543b72eb7d1eaeff4fffb440c07b2d6cd76842d8a9afb7ea2187fd5e9c2c6ae5eb6001b6aa925a08de3ef4 SHA512 d7502180b363f1f99037e30299cc77ba35259812463c44d82bd4953a3b15e19f44cc33184c23c2f80868cb8b9bdb78efd702482af901b69a2e06984ffd105f1b

diff --git a/dev-python/tox/tox-4.1.3.ebuild b/dev-python/tox/tox-4.1.3.ebuild
new file mode 100644
index 000000000000..b23c53855db0
--- /dev/null
+++ b/dev-python/tox/tox-4.1.3.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+SRC_URI="
+	https://github.com/tox-dev/tox/archive/${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc"
+
+RDEPEND="
+	>=dev-python/cachetools-5.2[${PYTHON_USEDEP}]
+	>=dev-python/chardet-5.1[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.4.6[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3.8.2[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.6[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-api-1.2.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+	>=dev-python/virtualenv-20.17.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/hatch-vcs-0.3[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		>=dev-python/distlib-0.3.6[${PYTHON_USEDEP}]
+		>=dev-python/flaky-3.7[${PYTHON_USEDEP}]
+		>=dev-python/psutil-5.9.4[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-3.1[${PYTHON_USEDEP}]
+		>=dev-python/re-assert-1.1[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/time-machine-2.8.2[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+src_prepare() {
+	# the minimal bounds in tox are entirely meaningless and new packaging
+	# breaks setuptools
+	sed -i -e '/packaging/s:>=22::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	epytest
+}