[gentoo-commits] gentoo-x86 commit in net-fs/autofs: ChangeLog autofs-5.0.5-r3.ebuild autofs-5.0.5-r2.ebuild

[Peter Volkov (pva)]

pva         11/04/30 18:20:50

  Modified:             ChangeLog
  Added:                autofs-5.0.5-r3.ebuild
  Removed:              autofs-5.0.5-r2.ebuild
  Log:
  Fix ldap linkage yet again, bug #362551, thank Joshua Rich for report.
  
  (Portage version: 2.1.9.46/cvs/Linux x86_64)

Revision  Changes    Path
1.104                net-fs/autofs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/autofs/ChangeLog?rev=1.104&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/autofs/ChangeLog?rev=1.104&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/autofs/ChangeLog?r1=1.103&r2=1.104

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/autofs/ChangeLog,v
retrieving revision 1.103
retrieving revision 1.104
diff -u -r1.103 -r1.104
--- ChangeLog	6 Apr 2011 15:03:01 -0000	1.103
+++ ChangeLog	30 Apr 2011 18:20:50 -0000	1.104
@@ -1,6 +1,12 @@
 # ChangeLog for net-fs/autofs
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/autofs/ChangeLog,v 1.103 2011/04/06 15:03:01 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/autofs/ChangeLog,v 1.104 2011/04/30 18:20:50 pva Exp $
+
+*autofs-5.0.5-r3 (30 Apr 2011)
+
+  30 Apr 2011; Peter Volkov <pva@g.o> -autofs-5.0.5-r2.ebuild,
+  +autofs-5.0.5-r3.ebuild, files/autofs-5.0.5-fix-building-without-ldap.patch:
+  Fix ldap linkage yet again, bug #362551, thank Joshua Rich for report.
 
   06 Apr 2011; Peter Volkov <pva@g.o> autofs-5.0.5-r2.ebuild,
   +files/autofs-5.0.5-add-missing-endif-HAVE_SASL-in-modules-lookup_ldap.c.patc



1.1                  net-fs/autofs/autofs-5.0.5-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/autofs/autofs-5.0.5-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/autofs/autofs-5.0.5-r3.ebuild?rev=1.1&content-type=text/plain

Index: autofs-5.0.5-r3.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-fs/autofs/autofs-5.0.5-r3.ebuild,v 1.1 2011/04/30 18:20:50 pva Exp $

EAPI="4"
inherit eutils multilib autotools linux-info

DESCRIPTION="Kernel based automounter"
HOMEPAGE="http://www.linux-consulting.com/Amd_AutoFS/autofs.html"
PATCH_VER="3"
SRC_URI="mirror://kernel/linux/daemons/${PN}/v5/${P}.tar.bz2
	mirror://gentoo/${P}-patches-${PATCH_VER}.tar.lzma"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="hesiod ldap sasl"

# USE="sasl" adds SASL support to the LDAP module which will not be build. If
# SASL support should be available, please add "ldap" to the USE flags.
REQUIRED_USE="sasl? ( ldap )"

# currently, sasl code assumes the presence of kerberosV
RDEPEND="hesiod? ( net-dns/hesiod )
	ldap? ( >=net-nds/openldap-2.0
		sasl? ( dev-libs/cyrus-sasl
			dev-libs/libxml2
			virtual/krb5 ) )"
DEPEND="${RDEPEND}"

src_prepare() {
	# Upstream's patchset
	EPATCH_SUFFIX="patch" \
		epatch "${WORKDIR}"/patches

	# Fix for bug #210762
	# Upstream reference: http://thread.gmane.org/gmane.linux.kernel.autofs/4203
	epatch "${FILESDIR}"/${PN}-5.0.3-heimdal.patch

	# Accumulated fixes for bugs
	#    #154797: Respect CC and CFLAGS
	#    #253412: Respect LDFLAGS
	#    #247969: Link order for --as-needed
	epatch "${FILESDIR}"/${P}-respect-user-flags-and-fix-asneeded-v1.patch

	# do not include <nfs/nfs.h>, rather <linux/nfs.h>,
	# as the former is a lame header for the latter (bug #157968)
	sed 's@nfs/nfs.h@linux/nfs.h@' -i include/rpc_subs.h || die

	# Upstream reference: http://thread.gmane.org/gmane.linux.kernel.autofs/5591
	epatch "${FILESDIR}"/${P}-fix-building-without-sasl.patch

	# Upstream reference: http://thread.gmane.org/gmane.linux.kernel.autofs/5371
	epatch "${FILESDIR}"/${P}-fix-install-deadlink.patch

	# Upstream reference: http://thread.gmane.org/gmane.linux.kernel.autofs/6039
	# Disable LDAP specific code if USE="-ldap", let's see what upstream says...
	epatch "${FILESDIR}"/${P}-fix-building-without-ldap.patch

	# https://bugs.gentoo.org/show_bug.cgi?id=361899
	epatch "${FILESDIR}"/${P}-add-missing-endif-HAVE_SASL-in-modules-lookup_ldap.c.patch

	eautoreconf
}

src_configure() {
	# work around bug #355975 (mount modifies timestamp of /etc/mtab)
	# with >=sys-apps/util-linux-2.19,
	addpredict "/etc/mtab"

	# --with-confdir is for bug #361481
	econf \
		--with-confdir=/etc/conf.d \
		$(use_with ldap openldap) \
		$(use_with sasl) \
		$(use_with hesiod) \
		--enable-ignore-busy
}

src_install() {
	emake DESTDIR="${D}" install

	dodoc README* CHANGELOG CREDITS COPYRIGHT INSTALL

	# kernel patches
	docinto patches
	dodoc patches/${PN}4-2.6.??{,.?{,?}}-v5-update-????????.patch

	newinitd "${FILESDIR}"/autofs5.initd autofs
}

pkg_postinst() {
	if kernel_is -lt 2 6 30; then
		elog "This version of ${PN} requires a kernel with autofs4 supporting"
		elog "protocol version 5.00. Patches for kernels older than 2.6.30 have"
		elog "been installed into"
		elog "${EROOT}usr/share/doc/${P}/patches."
		elog "For further instructions how to patch the kernel, please refer to"
		elog "${EROOT}usr/share/doc/${P}/INSTALL."
		elog
	fi
	elog "If you plan on using autofs for automounting remote NFS mounts,"
	elog "please check that both portmap (or rpcbind) and rpc.statd/lockd"
	elog "are running."
}