[gentoo-commits] repo/gentoo:master commit in: games-action/wordwarvi/

[Austin English]

commit:     c0e216403830d361b699643b6d6f0555c840d23c
Author:     Austin English <wizardedit <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 31 00:22:46 2017 +0000
Commit:     Austin English <wizardedit <AT> gentoo <DOT> org>
CommitDate: Tue Jan 31 00:59:21 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c0e21640

games-action/wordwarvi: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082

Package-Manager: Portage-2.3.2, Repoman-2.3.1

 games-action/wordwarvi/wordwarvi-1.00-r1.ebuild | 60 +++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/games-action/wordwarvi/wordwarvi-1.00-r1.ebuild b/games-action/wordwarvi/wordwarvi-1.00-r1.ebuild
new file mode 100644
index 00000000..1d6096e
--- /dev/null
+++ b/games-action/wordwarvi/wordwarvi-1.00-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils
+
+DESCRIPTION="A retro side-scrolling shoot'em up based on the editor war story"
+HOMEPAGE="http://wordwarvi.sourceforge.net"
+SRC_URI="mirror://sourceforge/wordwarvi/${P}.tar.gz"
+
+LICENSE="GPL-2 CC-BY-2.0 CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="portaudio"
+
+RDEPEND="x11-libs/gtk+:2
+	portaudio? ( media-libs/libvorbis
+		>=media-libs/portaudio-19_pre1 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-sound.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/^WITHAUDIO/s/yes/$(use portaudio && echo yes || echo no)/" \
+		Makefile || die
+	sed -i \
+		-e "s:GENTOO_DATADIR:/usr/share/${PN}:" \
+		wwviaudio.c || die
+}
+
+src_compile() {
+	emake \
+		PREFIX="/usr" \
+		DATADIR="/usr/share/${PN}" \
+		MANDIR="/usr/share/man"
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		PREFIX="/usr" \
+		DATADIR="/usr/share/${PN}" \
+		MANDIR="/usr/share/man" \
+		install
+
+	if ! use portaudio ; then
+		rm -rf "${D}/usr/share" || die
+	fi
+
+	dodoc README AUTHORS changelog.txt AAA_HOW_TO_MAKE_NEW_LEVELS.txt
+	newicon icons/wordwarvi_icon_128x128.png ${PN}.png
+	make_desktop_entry ${PN} "Word War vi"
+}