[gentoo-commits] repo/gentoo:master commit in: dev-db/pgbouncer/

[罗百科]

commit:     818aff7e81b904bc5b145b068b3114fce92125a3
Author:     Patrick Lauer <patrick <AT> gentoo <DOT> org>
AuthorDate: Thu Oct  7 14:23:40 2021 +0000
Commit:     罗百科 <patrick <AT> gentoo <DOT> org>
CommitDate: Thu Oct  7 14:23:52 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=818aff7e

dev-db/pgbouncer: Bump to 1.16.0

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Patrick Lauer <patrick <AT> gentoo.org>

 dev-db/pgbouncer/Manifest                |  1 +
 dev-db/pgbouncer/pgbouncer-1.16.0.ebuild | 81 ++++++++++++++++++++++++++++++++
 2 files changed, 82 insertions(+)

diff --git a/dev-db/pgbouncer/Manifest b/dev-db/pgbouncer/Manifest
index 91aec86d5e0..8b5fb7e6634 100644
--- a/dev-db/pgbouncer/Manifest
+++ b/dev-db/pgbouncer/Manifest
@@ -1 +1,2 @@
 DIST pgbouncer-1.15.0.tar.gz 588042 BLAKE2B 3dac09303e1c86126dd9cb44823c6f3fca4195e3155b360719c736c6e1327cc10d05e7f1e45c08d14c1dd0cb5c074b32263eee3be9e6350db9a8c5cbdfe61aa1 SHA512 5f78018ab80ab8d81f20ef3df1314ffc9557f1c6469d485d11ac822f596e3d4b554743fd9e9fe19b008a8aaf93bcf3673b42a8fb82bbd9611bd735cd2cbb98c6
+DIST pgbouncer-1.16.0.tar.gz 592136 BLAKE2B 752d5cfa18dacfdb72e9e9f12d5a1ac5346649e3a0c49ef530dd29ca16039949af0993d54080a7cf558c6eb6a919254c1dc4a36ab22f38992e790469ecd973bf SHA512 3b6f23052ca3b8af40a618da6bed2577b92ffe27b627f8980cda2d645991434bf298f720c1d423a272961c9f3f52a9d1b28154ed7f355d539f71dc68c028b617

diff --git a/dev-db/pgbouncer/pgbouncer-1.16.0.ebuild b/dev-db/pgbouncer/pgbouncer-1.16.0.ebuild
new file mode 100644
index 00000000000..abad489902b
--- /dev/null
+++ b/dev-db/pgbouncer/pgbouncer-1.16.0.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit systemd
+
+DESCRIPTION="Lightweight connection pooler for PostgreSQL"
+HOMEPAGE="https://www.pgbouncer.org/"
+SRC_URI="https://www.pgbouncer.org/downloads/files/${PV}/pgbouncer-${PV}.tar.gz"
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+c-ares debug doc pam ssl systemd udns"
+
+# At-most-one-of, one can be enabled but not both
+REQUIRED_USE="?? ( c-ares udns )"
+
+RDEPEND="
+	>=dev-libs/libevent-2.0:=
+	>=sys-libs/glibc-2.10
+	acct-user/pgbouncer
+	c-ares? ( >=net-dns/c-ares-1.10 )
+	ssl? ( >=dev-libs/openssl-1.0.1:=[-bindist(-)] )
+	systemd? ( sys-apps/systemd )
+	udns? ( >=net-libs/udns-0.1 )
+"
+
+DEPEND="${RDEPEND}"
+
+# Tests require a local database server, wants to fiddle with iptables,
+# and doesn't support overriding.
+RESTRICT="test"
+
+src_prepare() {
+	eapply "${FILESDIR}"/pgbouncer-1.12-dirs.patch
+
+	default
+}
+
+src_configure() {
+	# --enable-debug is only used to disable stripping
+	econf \
+		--docdir=/usr/share/doc/${PF} \
+		--enable-debug \
+		$(use_with c-ares cares) \
+		$(use_enable debug cassert) \
+		$(use_with pam) \
+		$(use_with ssl openssl) \
+		$(use_with systemd) \
+		$(use_with udns)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dodoc AUTHORS
+	use doc && dodoc doc/*.rst
+
+	newconfd "${FILESDIR}/${PN}.confd-r1" "${PN}"
+	newinitd "${FILESDIR}/${PN}.initd-r2" "${PN}"
+
+	insinto /etc
+	doins etc/pgbouncer.ini
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/logrotate" pgbouncer
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]] ; then
+		einfo "Please read the config.txt for Configuration Directives"
+		einfo
+		einfo "For Administration Commands, see:"
+		einfo "    man pgbouncer"
+		einfo
+		einfo "By default, PgBouncer does not have access to any database."
+		einfo "GRANT the permissions needed for your application and make sure that it"
+		einfo "exists in PgBouncer's auth_file."
+	fi
+}