[gentoo-commits] gentoo-x86 commit in app-admin/syslog-ng: syslog-ng-3.3.0_beta2.ebuild ChangeLog metadata.xml

[Michael Sterrett (mr_bones_)]

mr_bones_    11/09/29 21:21:13

  Modified:             ChangeLog metadata.xml
  Added:                syslog-ng-3.3.0_beta2.ebuild
  Log:
  masked version bump for ebuild testing
  
  (Portage version: 2.1.10.11/cvs/Linux i686)

Revision  Changes    Path
1.303                app-admin/syslog-ng/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/syslog-ng/ChangeLog?rev=1.303&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/syslog-ng/ChangeLog?rev=1.303&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/syslog-ng/ChangeLog?r1=1.302&r2=1.303

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/ChangeLog,v
retrieving revision 1.302
retrieving revision 1.303
diff -u -r1.302 -r1.303
--- ChangeLog	22 Sep 2011 22:11:44 -0000	1.302
+++ ChangeLog	29 Sep 2011 21:21:13 -0000	1.303
@@ -1,6 +1,14 @@
 # ChangeLog for app-admin/syslog-ng
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/ChangeLog,v 1.302 2011/09/22 22:11:44 idl0r Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/ChangeLog,v 1.303 2011/09/29 21:21:13 mr_bones_ Exp $
+
+*syslog-ng-3.3.0_beta2 (29 Sep 2011)
+
+  29 Sep 2011; Michael Sterrett <mr_bones_@g.o>
+  +syslog-ng-3.3.0_beta2.ebuild, +files/syslog-ng.conf.gentoo.3.3,
+  +files/syslog-ng.conf.gentoo.fbsd.3.3,
+  +files/syslog-ng.conf.gentoo.hardened.3.3:
+  masked version bump for ebuild testing
 
   22 Sep 2011; Christian Ruppert <idl0r@g.o> files/syslog-ng.rc6.3:
   Whitespace. Don't use --stop for reload().



1.6                  app-admin/syslog-ng/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/syslog-ng/metadata.xml?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/syslog-ng/metadata.xml?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/syslog-ng/metadata.xml?r1=1.5&r2=1.6

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/metadata.xml,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- metadata.xml	23 Sep 2011 21:04:46 -0000	1.5
+++ metadata.xml	29 Sep 2011 21:21:13 -0000	1.6
@@ -8,5 +8,7 @@
 <use>
 	<flag name='spoof-source'>Enable support for spoofed source addresses</flag>
 	<flag name='sql'>Enable support for SQL destinations</flag>
+	<flag name='json'>Enable support for JSON template formatting via <pkg>dev-libs/json-glib</pkg></flag>
+	<flag name='mongodb'>Enable support for mongodb destinations</flag>
 </use>
 </pkgmetadata>



1.1                  app-admin/syslog-ng/syslog-ng-3.3.0_beta2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/syslog-ng/syslog-ng-3.3.0_beta2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/syslog-ng/syslog-ng-3.3.0_beta2.ebuild?rev=1.1&content-type=text/plain

Index: syslog-ng-3.3.0_beta2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/syslog-ng-3.3.0_beta2.ebuild,v 1.1 2011/09/29 21:21:12 mr_bones_ Exp $

EAPI=2
inherit autotools fixheadtails eutils multilib

MY_PV=${PV/_/}
DESCRIPTION="syslog replacement with advanced filtering features"
HOMEPAGE="http://www.balabit.com/products/syslog_ng/"
SRC_URI="http://www.balabit.com/downloads/files/syslog-ng/sources/${MY_PV}/source/syslog-ng_${MY_PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="caps hardened ipv6 json mongodb +pcre selinux spoof-source sql ssl static tcpd"
RESTRICT="test"

LIBS_DEPEND="
	spoof-source? ( net-libs/libnet )
	ssl? ( dev-libs/openssl )
	tcpd? ( >=sys-apps/tcp-wrappers-7.6 )
	!static? ( >=dev-libs/eventlog-0.2.12 )
	>=dev-libs/glib-2.10.1:2
	json? ( >=dev-libs/json-glib-0.12 )
	caps? ( sys-libs/libcap )
	sql? ( >=dev-db/libdbi-0.8.3 )"
RDEPEND="
	!static? (
		pcre? ( dev-libs/libpcre )
		${LIBS_DEPEND}
	)"
DEPEND="${RDEPEND}
	${LIBS_DEPEND}
	static? ( >=dev-libs/eventlog-0.2.12[static-libs] )
	dev-util/pkgconfig
	sys-devel/flex"

S=${WORKDIR}/${PN}-${MY_PV}

src_prepare() {
	ht_fix_file configure.in
	eautoreconf
}

src_configure() {
	local myconf

	if use static ; then
		myconf="${myconf} --enable-static-linking"
	else
		myconf="${myconf} --enable-dynamic-linking"
	fi
	econf \
		--disable-dependency-tracking \
		--disable-systemd \
		--disable-mongodb \
		--with-ivykis=internal \
		--sysconfdir=/etc/syslog-ng \
		--localstatedir=/var/lib/misc \
		--with-pidfile-dir=/var/run \
		--with-module-dir=/usr/$(get_libdir)/syslog-ng \
		$(use_enable caps linux-caps) \
		$(use_enable ipv6) \
		$(use_enable json) \
		$(use_with json json-glib) \
		$(use_enable mongodb) \
		$(use_enable pcre) \
		$(use_enable spoof-source) \
		$(use_enable sql) \
		$(use_enable ssl) \
		$(use_enable tcpd tcp-wrapper) \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc AUTHORS ChangeLog NEWS README \
		contrib/syslog-ng.conf* \
		contrib/syslog2ng "${FILESDIR}/syslog-ng.conf."*

	# Install default configuration
	insinto /etc/syslog-ng
	if use hardened || use selinux ; then
		newins "${FILESDIR}/syslog-ng.conf.gentoo.hardened.${PV%.*}" syslog-ng.conf || die
	elif use userland_BSD ; then
		newins "${FILESDIR}/syslog-ng.conf.gentoo.fbsd.${PV%.*}" syslog-ng.conf || die
	else
		newins "${FILESDIR}/syslog-ng.conf.gentoo.${PV%.*}" syslog-ng.conf || die
	fi

	insinto /etc/logrotate.d
	# Install snippet for logrotate, which may or may not be installed
	if use hardened || use selinux ; then
		newins "${FILESDIR}/syslog-ng.logrotate.hardened" syslog-ng || die
	else
		newins "${FILESDIR}/syslog-ng.logrotate" syslog-ng || die
	fi

	newinitd "${FILESDIR}/syslog-ng.rc6.${PV%%.*}" syslog-ng || die
	newconfd "${FILESDIR}/syslog-ng.confd" syslog-ng || die
	keepdir /etc/syslog-ng/patterndb.d
	find "${D}" -type f -name '*.la' -exec rm {} + || die
	rmdir "${D}"/usr/libexec
}

pkg_postinst() {
	# bug #355257
	if ! has_version app-admin/logrotate ; then
		echo
		elog "It is highly recommended that app-admin/logrotate be emerged to"
		elog "manage the log files.  ${PN} installs a file in /etc/logrotate.d"
		elog "for logrotate to use."
		echo
	fi
}