[gentoo-commits] gentoo-x86 commit in sys-kernel/dracut: dracut-002.ebuild ChangeLog metadata.xml

[Lance Albertson (ramereth)]

ramereth    09/09/29 05:17:59

  Added:                dracut-002.ebuild ChangeLog metadata.xml
  Log:
  New package dracut, a generic initramfs building tool
  (Portage version: 2.1.6.13/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  sys-kernel/dracut/dracut-002.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-kernel/dracut/dracut-002.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-kernel/dracut/dracut-002.ebuild?rev=1.1&content-type=text/plain

Index: dracut-002.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-002.ebuild,v 1.1 2009/09/29 05:17:59 ramereth Exp $

EAPI=2

inherit eutils mount-boot

DESCRIPTION="Generic initramfs generation tool"
HOMEPAGE="http://sourceforge.net/projects/dracut/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="crypt dmraid iscsi lvm nbd nfs md selinux"

# common networking deps
NETWORK_DEPS="sys-apps/iproute2 net-misc/dhcp net-misc/bridge-utils"

RDEPEND="app-shells/dash
	>=sys-apps/module-init-tools-3.6
	app-arch/cpio
	sys-apps/coreutils
	sys-apps/findutils
	sys-devel/binutils
	sys-apps/grep
	sys-apps/which
	sys-apps/util-linux
	app-shells/bash
	app-arch/gzip
	app-arch/tar
	sys-fs/e2fsprogs
	sys-apps/file
	app-arch/bzip2
	crypt? ( sys-fs/cryptsetup )
	dmraid? ( sys-fs/dmraid )
	lvm? ( >=sys-fs/lvm2-2.02.33 )
	md? ( sys-fs/mdadm )
	nfs? ( net-fs/nfs-utils net-nds/rpcbind ${NETWORK_DEPS} )
	iscsi? ( sys-block/open-iscsi[utils] ${NETWORK_DEPS} )
	nbd? ( sys-block/nbd ${NETWORK_DEPS} )
	selinux? ( sys-libs/libselinux sys-libs/libsepol )"
DEPEND="${RDEPEND}"

src_prepare() {
	epatch "${FILESDIR}/${P}-unmount.patch"
	epatch "${FILESDIR}/${P}-custom-paths.patch"
	epatch "${FILESDIR}/${P}-dir-symlinks.patch"
	epatch "${FILESDIR}/${P}-add-missing-functions.patch"
	epatch "${FILESDIR}/${P}-gencmdline-check-for-keyboard-i18n-files.patch"
}

src_compile() {
	emake prefix=/usr sysconfdir=/etc || die "emake failed"
}

src_install() {
	local modules_dir="${D}/usr/share/dracut/modules.d"

	emake prefix=/usr sysconfdir=/etc DESTDIR="${D}" install || die "emake install failed"
	echo "${PF}" > "${modules_dir}"/10rpmversion/dracut-version
	dodir /boot/dracut /var/lib/dracut/overlay
	dodoc HACKING TODO AUTHORS NEWS README*
	# disable modules not enabled by use flags
	for module in crypt dmraid lvm md ; do
		! use ${module} && rm -rf ${modules_dir}/90${module}
	done
	# disable all network modules
	for module in iscsi nbd nfs ; do
		! use ${module} && rm -rf ${modules_dir}/95${module}
	done
	# if no networking at all, disable the rest
	if ! use iscsi && ! use nbd && ! use nfs ; then
		rm -rf ${modules_dir}/40network
		rm -rf ${modules_dir}/95fcoe
	fi
}

pkg_postinst() {
	elog 'To generate the initramfs:'
	elog ' # mount /boot (if necessary)'
	elog ' # dracut "" <kernel-version>'
	elog ''
	elog 'For command line documentation, see:'
	elog 'http://sourceforge.net/apps/trac/dracut/wiki/commandline'
	elog ''
	elog 'Simple example to select root and resume partition:'
	elog ' root=/dev/???? resume=/dev/????'
	elog ''
	elog 'Configuration is in /etc/dracut.conf.'
	elog 'The default config is very minimal and is highly recommended you'
	elog 'adjust based on your needs. To include only drivers for this system,'
	elog 'use the "-H" option.'
}



1.1                  sys-kernel/dracut/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-kernel/dracut/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-kernel/dracut/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for sys-kernel/dracut
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/ChangeLog,v 1.1 2009/09/29 05:17:59 ramereth Exp $

  29 Sep 2009; Lance Albertson <ramereth@g.o> dracut-002.ebuild,
  +files/dracut-002-add-missing-functions.patch,
  +files/dracut-002-gencmdline-check-for-keyboard-i18n-files.patch:
  Fix dracut-gencmdline issues

*dracut-002 (27 Sep 2009)

  27 Sep 2009; Lance Albertson <ramereth@g.o> +dracut-002.ebuild,
  +files/dracut-002-custom-paths.patch,
  +files/dracut-002-dir-symlinks.patch, +files/dracut-002-unmount.patch,
  +metadata.xml:
  Initial ebuild based from #278442

  Thanks to Ambroz Bizjak <ambro@××××××.net> for the initial ebuild and
  patches




1.1                  sys-kernel/dracut/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-kernel/dracut/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-kernel/dracut/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd></herd>
	<maintainer>
		<email>ramereth@g.o</email>
		<name>Lance Albertson</name>
	</maintainer>
	<use>
		<flag name="dmraid">Add support for dmraid devices, also known as
		ATA-RAID, or Fake RAID.</flag>
		<flag name="iscsi">Add support for iSCSI</flag>
		<flag name="lvm">Add support for the Logical Volume Manager
		sys-apps/lvm2</flag>
		<flag name="nbd">Add support for network block devices</flag>
		<flag name="nfs">Add support for NFS</flag>
		<flag name="md">Add support for MD devices, also known as software raid devices</flag>
	</use>
	<longdescription lang="en">
	Generic, modular initramfs generation tool that can be used across various
	distributions.
	</longdescription>
</pkgmetadata>