[gentoo-commits] gentoo-x86 commit in app-text/dictd: ChangeLog dictd-1.11.1.ebuild

[Peter Volkov (pva)]

pva         09/03/01 09:29:08

  Modified:             ChangeLog
  Added:                dictd-1.11.1.ebuild
  Log:
  Version bump. Most patches are applied upstream (or upstream suggested different solutions).
  (Portage version: 2.2_rc23/cvs/Linux i686)

Revision  Changes    Path
1.62                 app-text/dictd/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/dictd/ChangeLog?rev=1.62&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/dictd/ChangeLog?rev=1.62&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/dictd/ChangeLog?r1=1.61&r2=1.62

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/dictd/ChangeLog,v
retrieving revision 1.61
retrieving revision 1.62
diff -u -r1.61 -r1.62
--- ChangeLog	22 Dec 2008 20:39:35 -0000	1.61
+++ ChangeLog	1 Mar 2009 09:29:08 -0000	1.62
@@ -1,6 +1,12 @@
 # ChangeLog for app-text/dictd
-# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/dictd/ChangeLog,v 1.61 2008/12/22 20:39:35 armin76 Exp $
+# Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/dictd/ChangeLog,v 1.62 2009/03/01 09:29:08 pva Exp $
+
+*dictd-1.11.1 (01 Mar 2009)
+
+  01 Mar 2009; Peter Volkov <pva@g.o> +dictd-1.11.1.ebuild:
+  Version bump. Most patches are applied upstream (or upstream suggested
+  different solutions).
 
   22 Dec 2008; Raúl Porcel <armin76@g.o> dictd-1.11.0.ebuild:
   Re-add ~ia64 wrt #250390



1.1                  app-text/dictd/dictd-1.11.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/dictd/dictd-1.11.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/dictd/dictd-1.11.1.ebuild?rev=1.1&content-type=text/plain

Index: dictd-1.11.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/dictd/dictd-1.11.1.ebuild,v 1.1 2009/03/01 09:29:08 pva Exp $

inherit eutils

DESCRIPTION="Dictionary Client/Server for the DICT protocol"
HOMEPAGE="http://www.dict.org/"
SRC_URI="mirror://sourceforge/dict/${P}.tar.gz"

SLOT="0"
# We install rfc so - ISOC-rfc
LICENSE="GPL-2 ISOC-rfc"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~sparc ~x86"
IUSE="dbi judy"

# <gawk-3.1.6 makes tests fail.
DEPEND="sys-apps/coreutils
		sys-libs/zlib
		dev-libs/libmaa
		dbi? ( dev-db/libdbi )
		judy? ( dev-libs/judy )
		|| ( >=sys-apps/coreutils-6.10 sys-apps/mktemp )"
RDEPEND="${DEPEND}
		>=sys-apps/gawk-3.1.6"

pkg_setup() {
	enewgroup dictd # used in src_test()
	enewuser dictd -1 -1 -1 dictd
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/dictd-1.10.11-colorit-nopp-fix.patch"
}

src_compile() {
	econf \
		$(use_with dbi plugin-dbi) \
		$(use_with judy plugin-judy) \
		--sysconfdir=/etc/dict
	emake || die "make failed"
}

src_test() {
	if ! hasq userpriv "${FEATURES}"; then
		# If dictd is run as root user (-userpriv) it drops its privileges to
		# dictd user and group. Give dictd group write access to test directory.
		chown :dictd "${WORKDIR}" "${S}/test"
		chmod 770 "${WORKDIR}" "${S}/test"
	fi
	emake test || die
}

src_install() {
	emake DESTDIR="${D}" install || die "install failed"

	# Install docs
	dodoc README TODO ChangeLog ANNOUNCE NEWS || die "installing docs part 1 failed"
	dodoc doc/{dicf.ms,rfc.ms,rfc.sh,rfc2229.txt} || die "installing docs part 2 failed"
	dodoc doc/{security.doc,toc.ms} || die "installing docs part 3 failed"

	# conf files.
	insinto /etc/dict
	for f in dict.conf dictd.conf site.info colorit.conf; do
		doins "${FILESDIR}/1.10.11/${f}" || die "failed to install ${f}"
	done

	# startups for dictd
	newinitd "${FILESDIR}/1.10.11/dictd.initd" dictd || die "failed to install dictd.initd"
	newconfd "${FILESDIR}/1.10.11/dictd.confd" dictd || die "failed to install dictd.confd"
}

pkg_postinst() {
	echo
	elog "To start and use ${PN} you need to emerge at least one dictionary from"
	elog "the app-dicts category with the package name starting with 'dictd-'."
	elog "To install all available dictionaries, emerge app-dicts/dictd-dicts."
	elog "${PN} will NOT start without at least one dictionary."
	echo
}