[gentoo-commits] repo/gentoo:master commit in: dev-ruby/capybara/

[Hans de Graaff]

commit:     a885b8fc33b8fb7ee927eaca1bee3d70f7ed6d89
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Sat Jul  8 07:26:12 2017 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Sat Jul  8 07:29:25 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a885b8fc

dev-ruby/capybara: add ruby24

Package-Manager: Portage-2.3.6, Repoman-2.3.1

 dev-ruby/capybara/capybara-2.14.4-r1.ebuild | 50 +++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/dev-ruby/capybara/capybara-2.14.4-r1.ebuild b/dev-ruby/capybara/capybara-2.14.4-r1.ebuild
new file mode 100644
index 00000000000..4820acf1d2b
--- /dev/null
+++ b/dev-ruby/capybara/capybara-2.14.4-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+USE_RUBY="ruby21 ruby22 ruby23 ruby24"
+
+RUBY_FAKEGEM_EXTRADOC="History.md README.md"
+
+# Rake tasks are not distributed in the gem.
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_TASK_TEST=""
+
+inherit virtualx ruby-fakegem
+
+DESCRIPTION="Capybara aims to simplify the process of integration testing Rack applications"
+HOMEPAGE="https://github.com/jnicklas/capybara"
+LICENSE="MIT"
+
+KEYWORDS="~amd64"
+SLOT="2"
+IUSE="test"
+
+DEPEND="${DEPEND} test? ( www-client/firefox )"
+
+ruby_add_bdepend "test? ( dev-ruby/rspec:3 dev-ruby/launchy >=dev-ruby/selenium-webdriver-2.0 dev-ruby/sinatra )"
+
+ruby_add_rdepend "
+	dev-ruby/addressable
+	>=dev-ruby/mime-types-1.16:*
+	>=dev-ruby/nokogiri-1.3.3
+	>=dev-ruby/rack-1.0.0:*
+	>=dev-ruby/rack-test-0.5.4
+	>=dev-ruby/xpath-2.0.0:2"
+
+all_ruby_prepare() {
+	sed -i -e '/bundler/d' -e '/pry/d' -e '1igem "sinatra"' spec/spec_helper.rb || die
+
+	# Avoid window-manager specific tests (sizes are specific for fluxbox)
+	sed -i -e '/#maximize/,/^  end/ s:^:#:' lib/capybara/spec/session/window/window_spec.rb || die
+
+	# Avoid spec that requires unpackaged geckodriver
+	sed -i -e '/register_server/,/^  end/ s:^:#:' spec/capybara_spec.rb || die
+
+	# Avoid test dependency on puma server for now
+	sed -i -e '/should have :puma registered/,/^    end/ s:^:#:' spec/capybara_spec.rb || die
+}
+
+each_ruby_test() {
+	virtx ${RUBY} -Ilib -S rspec-3 spec || die "Tests failed."
+}