[gentoo-commits] gentoo-x86 commit in games-action/armagetronad: metadata.xml ChangeLog armagetronad-0.2.8.3.2.ebuild Manifest

[Julian Ospald (hasufell)]

hasufell    13/11/07 18:48:05

  Added:                metadata.xml ChangeLog
                        armagetronad-0.2.8.3.2.ebuild Manifest
  Log:
  initial import wrt #481516
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.3                  games-action/armagetronad/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/armagetronad/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/armagetronad/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/armagetronad/metadata.xml?r1=1.2&r2=1.3




1.23                 games-action/armagetronad/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/armagetronad/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/armagetronad/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/armagetronad/ChangeLog?r1=1.22&r2=1.23




1.1                  games-action/armagetronad/armagetronad-0.2.8.3.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/armagetronad/armagetronad-0.2.8.3.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/armagetronad/armagetronad-0.2.8.3.2.ebuild?rev=1.1&content-type=text/plain

Index: armagetronad-0.2.8.3.2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-action/armagetronad/armagetronad-0.2.8.3.2.ebuild,v 1.1 2013/11/07 18:48:05 hasufell Exp $

EAPI=5

inherit eutils gnome2-utils games

DESCRIPTION="Fast-paced 3D lightcycle game based on Tron"
HOMEPAGE="http://armagetronad.org/"
SRC_URI="http://launchpad.net/armagetronad/${PV:0:5}/${PV}/+download/armagetronad-${PV}.src.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="dedicated sound"

RDEPEND="
	dev-libs/libxml2
	!dedicated? (
		media-libs/libpng:0
		media-libs/sdl-image[jpeg,png]
		virtual/glu
		virtual/opengl
		sound? (
			media-libs/libsdl[X,audio,opengl,video]
			media-libs/sdl-mixer
		)
		!sound? ( media-libs/libsdl[X,opengl,video] )
	)"
DEPEND="${RDEPEND}"

src_prepare() {
	sed -i \
		-e 's/"png_check_sig"/"png_sig_cmp"/' \
		-e 's#aa_docdir=.*$#aa_docdir=${docdir}#' \
		configure || die
}

src_configure() {
	# --enable-games just messes up paths
	egamesconf \
		--docdir=/usr/share/doc/${PF} \
		$(use_enable dedicated) \
		$(use_enable sound music) \
		--disable-sysinstall \
		--disable-useradd \
		--disable-uninstall \
		--disable-games
}

src_install() {
	emake -j1 DESTDIR="${D}" install
	einstalldocs

	# misplaced desktop-file/icons
	rm -rf "${ED%/}${GAMES_DATADIR}"/armagetronad/desktop
	doicon -s 48 desktop/icons/large/armagetronad.png
	make_desktop_entry ${PN}

	prepgamesdirs
}

pkg_preinst() {
	games_pkg_preinst
	gnome2_icon_savelist
}

pkg_postinst() {
	games_pkg_postinst
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}



1.36                 games-action/armagetronad/Manifest

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/armagetronad/Manifest?rev=1.36&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/armagetronad/Manifest?rev=1.36&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/armagetronad/Manifest?r1=1.35&r2=1.36