[gentoo-commits] gentoo-x86 commit in dev-db/libdbi-drivers: ChangeLog libdbi-drivers-0.8.1-r2.ebuild

[Robin H. Johnson (robbat2)]

robbat2     07/11/26 00:31:37

  Modified:             ChangeLog
  Added:                libdbi-drivers-0.8.1-r2.ebuild
  Log:
  Block USE=firebird when USE=bindist is in play, per bug #200284 for license conflicts.
  (Portage version: 2.1.3.19)

Revision  Changes    Path
1.25                 dev-db/libdbi-drivers/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/libdbi-drivers/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/libdbi-drivers/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/libdbi-drivers/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-db/libdbi-drivers/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	20 Jun 2007 07:39:57 -0000	1.24
+++ ChangeLog	26 Nov 2007 00:31:37 -0000	1.25
@@ -1,6 +1,13 @@
 # ChangeLog for dev-db/libdbi-drivers
 # Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/libdbi-drivers/ChangeLog,v 1.24 2007/06/20 07:39:57 opfer Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/libdbi-drivers/ChangeLog,v 1.25 2007/11/26 00:31:37 robbat2 Exp $
+
+*libdbi-drivers-0.8.1-r2 (26 Nov 2007)
+
+  26 Nov 2007; Robin H. Johnson <robbat2@g.o>
+  +libdbi-drivers-0.8.1-r2.ebuild:
+  Block USE=firebird when USE=bindist is in play, per bug #200284 for license
+  conflicts.
 
   20 Jun 2007; Christian Faulhammer <opfer@g.o>
   libdbi-drivers-0.8.1-r1.ebuild:



1.1                  dev-db/libdbi-drivers/libdbi-drivers-0.8.1-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/libdbi-drivers/libdbi-drivers-0.8.1-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/libdbi-drivers/libdbi-drivers-0.8.1-r2.ebuild?rev=1.1&content-type=text/plain

Index: libdbi-drivers-0.8.1-r2.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/libdbi-drivers/libdbi-drivers-0.8.1-r2.ebuild,v 1.1 2007/11/26 00:31:37 robbat2 Exp $

inherit eutils

DESCRIPTION="The libdbi-drivers project maintains drivers for libdbi."
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
HOMEPAGE="http://libdbi-drivers.sourceforge.net/"
LICENSE="LGPL-2.1"
DEPEND=">=dev-db/libdbi-0.8.0
		mysql? ( virtual/mysql )
		postgres? ( dev-db/postgresql )
		sqlite? ( <dev-db/sqlite-3 )
		sqlite3? ( >=dev-db/sqlite-3 )
		!bindist? ( firebird? ( dev-db/firebird ) )"

IUSE="mysql postgres sqlite oci8 firebird sqlite3 bindist"
KEYWORDS="~amd64 ~hppa ~ppc ~sparc ~x86"
SLOT=0

src_unpack() {
	unpack ${A}
	EPATCH_OPTS="-p1 -d${S}" epatch "${FILESDIR}"/${P}-oci8.diff
}

pkg_setup() {
	local drivers=""
	use mysql && drivers="${drivers} mysql"
	use postgres && drivers="${drivers} pgsql"
	use sqlite && drivers="${drivers} sqlite"
	use sqlite3 && drivers="${drivers} sqlite3"
	if use firebird; then
		if use bindist; then
			eerror "The Interbase Public License is incompatible with LGPL, see bug #200284."
			eerror "Disabling firebird in the build"
		else
			drivers="${drivers} firebird"
		fi
	fi
	if use oci8; then
		if [ -z "${ORACLE_HOME}" ]; then
			die "\$ORACLE_HOME is not set!"
		fi
		drivers="${drivers} oracle"
	fi
	# safety check
	if [ -z "${drivers// /}" ]; then
		die "No supported databases in your USE flags! (mysql, postgres, sqlite, sqlite3, oracle, firebird)"
	fi
}

src_compile() {
	local myconf=""
	# WARNING: the configure script does NOT work correctly
	# --without-$driver does NOT work
	# so do NOT use `use_with...`
	use mysql && myconf="${myconf} --with-mysql"
	use postgres && myconf="${myconf} --with-pgsql"
	use sqlite && myconf="${myconf} --with-sqlite"
	use sqlite3 && myconf="${myconf} --with-sqlite3"
	use !bindist && use firebird && myconf="${myconf} --with-firebird"
	if use oci8; then
		if [ -z "${ORACLE_HOME}" ]; then
			die "\$ORACLE_HOME is not set!"
		fi
		myconf="${myconf} --with-oracle-dir=${ORACLE_HOME} --with-oracle"
	fi

	econf ${myconf} || die "econf failed"
	emake || die "emake failed"
}

src_install () {
	emake install DESTDIR="${D}" || die "make install failed"
	dodoc AUTHORS ChangeLog NEWS README README.osx TODO
}



-- 
gentoo-commits@g.o mailing list