[gentoo-commits] gentoo-x86 commit in media-video/avidemux: ChangeLog avidemux-2.5.4-r1.ebuild avidemux-2.5.4.ebuild

[Markos Chandras (hwoarang)]

hwoarang    10/10/28 11:03:42

  Modified:             ChangeLog
  Added:                avidemux-2.5.4-r1.ebuild
  Removed:              avidemux-2.5.4.ebuild
  Log:
  Apply patch to fix audio settings dummy device. Bug #342909. Thanks to Eric F. GARIOUD <eric-f.garioud@×××××××.fr>
  
  (Portage version: 2.2.0_alpha1/cvs/Linux x86_64)

Revision  Changes    Path
1.177                media-video/avidemux/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/avidemux/ChangeLog?rev=1.177&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/avidemux/ChangeLog?rev=1.177&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/avidemux/ChangeLog?r1=1.176&r2=1.177

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/avidemux/ChangeLog,v
retrieving revision 1.176
retrieving revision 1.177
diff -u -r1.176 -r1.177
--- ChangeLog	26 Oct 2010 20:47:13 -0000	1.176
+++ ChangeLog	28 Oct 2010 11:03:42 -0000	1.177
@@ -1,6 +1,13 @@
 # ChangeLog for media-video/avidemux
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/ChangeLog,v 1.176 2010/10/26 20:47:13 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/ChangeLog,v 1.177 2010/10/28 11:03:42 hwoarang Exp $
+
+*avidemux-2.5.4-r1 (28 Oct 2010)
+
+  28 Oct 2010; Markos Chandras <hwoarang@g.o> -avidemux-2.5.4.ebuild,
+  +avidemux-2.5.4-r1.ebuild, +files/avidemux-2.5.4-dummy-sound-fix.patch:
+  Apply patch to fix audio settings dummy device. Bug #342909. Thanks to
+  Eric F. GARIOUD <eric-f.garioud@×××××××.fr>
 
 *avidemux-2.5.4 (26 Oct 2010)
 



1.1                  media-video/avidemux/avidemux-2.5.4-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/avidemux/avidemux-2.5.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/avidemux/avidemux-2.5.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: avidemux-2.5.4-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/avidemux-2.5.4-r1.ebuild,v 1.1 2010/10/28 11:03:42 hwoarang Exp $

EAPI="2"

inherit cmake-utils flag-o-matic

MY_P=${PN}_${PV}

DESCRIPTION="Video editor designed for simple cutting, filtering and encoding tasks"
HOMEPAGE="http://fixounet.free.fr/avidemux"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="2"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="+aac +aften +alsa amr +dts esd jack libsamplerate +mp3 nls oss
	pulseaudio +sdl +truetype +vorbis +x264 +xv +xvid gtk +qt4"

RDEPEND="dev-libs/libxml2
	aac? ( media-libs/faac
		media-libs/faad2 )
	aften? ( media-libs/aften )
	alsa? ( media-libs/alsa-lib )
	amr? ( media-libs/opencore-amr )
	dts? ( media-libs/libdca )
	mp3? ( media-sound/lame )
	esd? ( media-sound/esound )
	jack? ( media-sound/jack-audio-connection-kit )
	libsamplerate? ( media-libs/libsamplerate )
	pulseaudio? ( media-sound/pulseaudio )
	sdl? ( media-libs/libsdl )
	truetype? ( media-libs/freetype:2
		media-libs/fontconfig )
	vorbis? ( media-libs/libvorbis )
	x264? ( media-libs/x264 )
	xv? ( x11-libs/libXv )
	xvid? ( media-libs/xvid )
	gtk? ( x11-libs/gtk+:2 )
	qt4? ( x11-libs/qt-gui:4 )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	dev-util/pkgconfig
	dev-util/cmake"

S=${WORKDIR}/${MY_P}
BUILD_S=${WORKDIR}/${P}_build

AVIDEMUX_LANGS="bg ca cs de el es fr it ja pt_BR ru sr sr@latin tr zh_TW"
for L in ${AVIDEMUX_LANGS}; do
	IUSE="${IUSE} linguas_${L}"
done

PATCHES=(
	"${FILESDIR}/${P}-build-plugins-fix.patch"
	#bug 342909
	"${FILESDIR}/${P}-dummy-sound-fix.patch"
)

src_prepare() {
	base_src_prepare

	local po_files=
	local qt_ts_files=
	local avidemux_ts_files=
	for lingua in ${LINGUAS}; do
		if has ${lingua} ${AVIDEMUX_LANGS}; then
			if [[ -e ${S}/po/${lingua}.po ]]; then
				po_files="${po_files} \${po_subdir}/${lingua}.po"
			fi
			if [[ -e ${S}/po/qt_${lingua}.ts ]]; then
				qt_ts_files="${qt_ts_files} \${ts_subdir}/qt_${lingua}.ts"
			fi
			if [[ -e ${S}/po/${PN}_${lingua}.ts ]]; then
				avidemux_ts_files="${avidemux_ts_files} \${ts_subdir}/${PN}_${lingua}.ts"
			fi
		fi
	done

	sed -i -e "s!FILE(GLOB po_files .*)!SET(po_files ${po_files})!" \
		"${S}/cmake/Po.cmake" || die "sed failed"
	sed -i -e "s!FILE(GLOB.*qt.*)!SET(ts_files ${qt_ts_files})!" \
	    -e "s!FILE(GLOB.*avidemux.*)!SET(ts_files ${avidemux_ts_files})!" \
		"${S}/cmake/Ts.cmake" || die "sed failed"
	#fix exec command wrt bug #316599 and #291453
	sed -i "/Exec/s:\[\$e\]::" ${PN}2-gtk.desktop
}

src_configure() {
	### Add lax vector typing for PowerPC
	if use ppc || use ppc64; then
		append-cflags "-flax-vector-conversions"
	fi

	mycmakeargs="${mycmakeargs}
		-DAVIDEMUX_SOURCE_DIR='${S}'
		-DAVIDEMUX_INSTALL_PREFIX='${BUILD_S}'
		-DAVIDEMUX_CORECONFIG_DIR='${BUILD_S}/config'"

	# CMakeLists.txt
	use gtk || mycmakeargs="${mycmakeargs} -DGTK=0"
	use qt4 || mycmakeargs="${mycmakeargs} -DQT4=0"

	# cmake/admCheckMiscLibs.cmake
	use nls || mycmakeargs="${mycmakeargs} -DGETTEXT=0"
	use sdl || mycmakeargs="${mycmakeargs} -DSDL=0"
	use xv || mycmakeargs="${mycmakeargs} -DXVIDEO=0"

	# cmake/admCheckAudioDeviceLibs.cmake
	use alsa || mycmakeargs="${mycmakeargs} -DALSA=0"
	use esd || mycmakeargs="${mycmakeargs} -DESD=0"
	use jack || mycmakeargs="${mycmakeargs} -DJACK=0"
	use oss || mycmakeargs="${mycmakeargs} -DOSS=0"
	use pulseaudio || mycmakeargs="${mycmakeargs} -DPULSEAUDIOSIMPLE=0"

	# cmake/admCheckAudioEncoderLibs.cmake
	use aften || mycmakeargs="${mycmakeargs} -DAFTEN=0"
	use mp3 || mycmakeargs="${mycmakeargs} -DLAME=0"
	use aac || mycmakeargs="${mycmakeargs} -DFAAC=0"
	use vorbis || mycmakeargs="${mycmakeargs} -DVORBIS=0"

	# plugins/ADM_audioDecoders
	use aac || mycmakeargs="${mycmakeargs} -DFAAD=0"
	use dts || mycmakeargs="${mycmakeargs} -DLIBDCA=0"

	# opencore
	use amr || mycmakeargs="${mycmakeargs} -DOPENCORE_AMRNB=0 -DOPENCORE_AMRWB=0"

	# plugins/ADM_videoFilters
	use truetype || mycmakeargs="${mycmakeargs} -DFREETYPE2=0 -DFONTCONFIG=0"

	# plugins/ADM_videoEncoder
	use xvid || mycmakeargs="${mycmakeargs} -DXVID=0"
	use x264 || mycmakeargs="${mycmakeargs} -DX264=0"

	cmake-utils_src_configure
}

src_compile() {
	append-flags -D__STDC_FORMAT_MACROS
	# first build the application
	cmake-utils_src_compile
	# and then go on with plugins
	emake -C "${CMAKE_BUILD_DIR}/plugins" || die "building plugins failed"
}

src_install() {
	# install the application
	cmake-utils_src_install
	# install plugins
	emake -C "${CMAKE_BUILD_DIR}/plugins" DESTDIR="${D}" install \
		|| die "installing plugins failed"

	dodoc AUTHORS || die "dodoc failed"
	newicon ${PN}_icon.png ${PN}.png || die "installing icon failed"

	if use qt4; then
		sed -i "s/\(${PN}2_\)gtk/\1qt4/" ${PN}2.desktop || die "sed failed"
		domenu ${PN}2.desktop || die "installing desktop file failed"
	fi

	if use gtk; then
		domenu ${PN}2-gtk.desktop || die "installing desktop file failed"
	fi
}