[gentoo-commits] gentoo-x86 commit in gnome-extra/zeitgeist: ChangeLog zeitgeist-0.9.15.ebuild

[Gilles Dartiguelongue (eva)]

eva         15/03/03 23:48:32

  Modified:             ChangeLog
  Added:                zeitgeist-0.9.15.ebuild
  Log:
  Version bump, fix bug #518174. Move vala_src_prepare call after potential eautoreconf, fix configure to properly detect/use python, make unittest run within a dbus session, do not install docs in multiple paths.
  
  (Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key C6085806)

Revision  Changes    Path
1.44                 gnome-extra/zeitgeist/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/zeitgeist/ChangeLog?rev=1.44&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/zeitgeist/ChangeLog?rev=1.44&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/zeitgeist/ChangeLog?r1=1.43&r2=1.44

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/zeitgeist/ChangeLog,v
retrieving revision 1.43
retrieving revision 1.44
diff -u -r1.43 -r1.44
--- ChangeLog	4 Jul 2014 02:32:45 -0000	1.43
+++ ChangeLog	3 Mar 2015 23:48:32 -0000	1.44
@@ -1,6 +1,15 @@
 # ChangeLog for gnome-extra/zeitgeist
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/zeitgeist/ChangeLog,v 1.43 2014/07/04 02:32:45 patrick Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/zeitgeist/ChangeLog,v 1.44 2015/03/03 23:48:32 eva Exp $
+
+*zeitgeist-0.9.15 (03 Mar 2015)
+
+  03 Mar 2015; Gilles Dartiguelongue <eva@g.o> +zeitgeist-0.9.15.ebuild,
+  +files/zeitgeist-0.9.15-fix-array-length-string-join.patch,
+  +files/zeitgeist-0.9.15-python-detection.patch:
+  Version bump, fix bug #518174. Move vala_src_prepare call after potential
+  eautoreconf, fix configure to properly detect/use python, make unittest run
+  within a dbus session, do not install docs in multiple paths.
 
   04 Jul 2014; Patrick Lauer <patrick@g.o> metadata.xml:
   Remove unneeded useflag description from metadata.xml



1.1                  gnome-extra/zeitgeist/zeitgeist-0.9.15.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/zeitgeist/zeitgeist-0.9.15.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/zeitgeist/zeitgeist-0.9.15.ebuild?rev=1.1&content-type=text/plain

Index: zeitgeist-0.9.15.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/zeitgeist/zeitgeist-0.9.15.ebuild,v 1.1 2015/03/03 23:48:32 eva Exp $

EAPI=5
AUTOTOOLS_AUTORECONF=true
PYTHON_COMPAT=( python2_7 )
VALA_MIN_API_VERSION=0.22

inherit autotools-utils bash-completion-r1 eutils python-r1 vala versionator

DIR_PV=$(get_version_component_range 1-2)

DESCRIPTION="Service to log activities and present to other apps"
HOMEPAGE="http://launchpad.net/zeitgeist/"
SRC_URI="http://launchpad.net/zeitgeist/${DIR_PV}/${PV}/+download/${P}.tar.xz
	http://dev.gentoo.org/~eva/distfiles/${PN}/${P}.tar.xz"

LICENSE="LGPL-2+ LGPL-3+ GPL-2+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="+datahub downloads-monitor extensions +fts icu introspection nls plugins sql-debug telepathy"

REQUIRED_USE="
	${PYTHON_REQUIRED_USE}
	downloads-monitor? ( datahub )"

RDEPEND="
	${PYTHON_DEPS}
	!gnome-extra/zeitgeist-datahub
	dev-libs/json-glib
	dev-python/dbus-python[${PYTHON_USEDEP}]
	dev-python/pygobject:2[${PYTHON_USEDEP}]
	dev-python/pyxdg[${PYTHON_USEDEP}]
	dev-python/rdflib[${PYTHON_USEDEP}]
	media-libs/raptor:2
	>=dev-libs/glib-2.26.0:2
	>=dev-db/sqlite-3.7.11:3
	sys-apps/dbus
	datahub? ( x11-libs/gtk+:3 )
	extensions? ( gnome-extra/zeitgeist-extensions  )
	fts? ( dev-libs/xapian[inmemory] )
	icu? ( dev-libs/dee[icu?,${PYTHON_USEDEP}] )
	introspection? ( dev-libs/gobject-introspection )
	plugins? ( gnome-extra/zeitgeist-datasources )
	telepathy? ( net-libs/telepathy-glib )
"
DEPEND="${RDEPEND}
	$(vala_depend)
	>=dev-util/intltool-0.35
	virtual/pkgconfig
"

src_prepare() {
	# pure-python module is better managed manually, see src_install 
	sed -e 's:python::g' \
		-i Makefile.am || die

	# Fix direct invocation of python in configure
	epatch "${FILESDIR}"/${PN}-0.9.15-python-detection.patch

	# Fix vapi dependencies
	epatch "${FILESDIR}"/${PN}-0.9.14-gio-backport.patch

	# Fix query generation, from master
	epatch "${FILESDIR}"/${PN}-0.9.15-fix-array-length-string-join.patch

	autotools-utils_src_prepare
	vala_src_prepare
}

src_configure() {
	local myeconfargs=(
		--docdir="${EPREFIX}/usr/share/doc/${PF}"
		--with-session-bus-services-dir="${EPREFIX}/usr/share/dbus-1/services"
		$(use_enable sql-debug explain-queries)
		$(use_enable datahub)
		$(use_enable downloads-monitor)
		$(use_enable telepathy)
		$(use_enable introspection)
		$(use_with icu dee-icu)
	)

	use nls || myeconfargs+=( --disable-nls )
	use fts && myeconfargs+=( --enable-fts )

	python_setup
	autotools-utils_src_configure
}

src_test() {
	autotools-utils_src_test TESTS_ENVIRONMENT="dbus-run-session"
}

src_install() {
	dobashcomp data/completions/zeitgeist-daemon
	autotools-utils_src_install
	cd python || die
	python_moduleinto ${PN}
	python_foreach_impl python_domodule *py

	# Redundant NEWS/AUTHOR installation
	rm -r "${D}"/usr/share/zeitgeist/doc/ || die
}