Gentoo Archives: gentoo-commits

From: "PaweA Hajdan (phajdan.jr)" <phajdan.jr@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in www-client/chromium: ChangeLog chromium-9999-r1.ebuild chromium-15.0.865.0.ebuild chromium-15.0.854.0.ebuild
Date: Tue, 30 Aug 2011 18:49:33
Message-Id: 20110830184922.ED3A32004C@flycatcher.gentoo.org
1 phajdan.jr 11/08/30 18:49:22
2
3 Modified: ChangeLog chromium-9999-r1.ebuild
4 Added: chromium-15.0.865.0.ebuild
5 Removed: chromium-15.0.854.0.ebuild
6 Log:
7 Version bump for dev channel release. Link with Kerberos if requested instead of dlopen. Remove old.
8
9 (Portage version: 2.1.10.11/cvs/Linux i686)
10
11 Revision Changes Path
12 1.423 www-client/chromium/ChangeLog
13
14 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.423&view=markup
15 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.423&content-type=text/plain
16 diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?r1=1.422&r2=1.423
17
18 Index: ChangeLog
19 ===================================================================
20 RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v
21 retrieving revision 1.422
22 retrieving revision 1.423
23 diff -u -r1.422 -r1.423
24 --- ChangeLog 26 Aug 2011 20:56:05 -0000 1.422
25 +++ ChangeLog 30 Aug 2011 18:49:22 -0000 1.423
26 @@ -1,6 +1,14 @@
27 # ChangeLog for www-client/chromium
28 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
29 -# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.422 2011/08/26 20:56:05 phajdan.jr Exp $
30 +# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.423 2011/08/30 18:49:22 phajdan.jr Exp $
31 +
32 +*chromium-15.0.865.0 (30 Aug 2011)
33 +
34 + 30 Aug 2011; Pawel Hajdan jr <phajdan.jr@g.o>
35 + +files/chromium-kerberos-r1.patch, -chromium-15.0.854.0.ebuild,
36 + +chromium-15.0.865.0.ebuild, chromium-9999-r1.ebuild:
37 + Version bump for dev channel release. Link with Kerberos if requested instead
38 + of dlopen. Remove old.
39
40 *chromium-15.0.861.0 (26 Aug 2011)
41
42
43
44
45 1.46 www-client/chromium/chromium-9999-r1.ebuild
46
47 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999-r1.ebuild?rev=1.46&view=markup
48 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999-r1.ebuild?rev=1.46&content-type=text/plain
49 diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999-r1.ebuild?r1=1.45&r2=1.46
50
51 Index: chromium-9999-r1.ebuild
52 ===================================================================
53 RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999-r1.ebuild,v
54 retrieving revision 1.45
55 retrieving revision 1.46
56 diff -u -r1.45 -r1.46
57 --- chromium-9999-r1.ebuild 26 Aug 2011 20:56:05 -0000 1.45
58 +++ chromium-9999-r1.ebuild 30 Aug 2011 18:49:22 -0000 1.46
59 @@ -1,6 +1,6 @@
60 # Copyright 1999-2011 Gentoo Foundation
61 # Distributed under the terms of the GNU General Public License v2
62 -# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999-r1.ebuild,v 1.45 2011/08/26 20:56:05 phajdan.jr Exp $
63 +# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999-r1.ebuild,v 1.46 2011/08/30 18:49:22 phajdan.jr Exp $
64
65 EAPI="3"
66 PYTHON_DEPEND="2:2.6"
67 @@ -225,13 +225,13 @@
68 -Duse_system_zlib=1"
69
70 # Optional dependencies.
71 - # TODO: linux_link_kerberos
72 myconf+="
73 $(gyp_use cups use_cups)
74 $(gyp_use gnome use_gconf)
75 $(gyp_use gnome-keyring use_gnome_keyring)
76 $(gyp_use gnome-keyring linux_link_gnome_keyring)
77 $(gyp_use kerberos use_kerberos)
78 + $(gyp_use kerberos linux_link_kerberos)
79 $(gyp_use pulseaudio use_pulseaudio)"
80
81 # Enable sandbox.
82
83
84
85 1.1 www-client/chromium/chromium-15.0.865.0.ebuild
86
87 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-15.0.865.0.ebuild?rev=1.1&view=markup
88 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-15.0.865.0.ebuild?rev=1.1&content-type=text/plain
89
90 Index: chromium-15.0.865.0.ebuild
91 ===================================================================
92 # Copyright 1999-2011 Gentoo Foundation
93 # Distributed under the terms of the GNU General Public License v2
94 # $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-15.0.865.0.ebuild,v 1.1 2011/08/30 18:49:22 phajdan.jr Exp $
95
96 EAPI="3"
97 PYTHON_DEPEND="2:2.6"
98
99 inherit eutils fdo-mime flag-o-matic gnome2-utils linux-info multilib \
100 pax-utils portability python toolchain-funcs versionator virtualx
101
102 DESCRIPTION="Open-source version of Google Chrome web browser"
103 HOMEPAGE="http://chromium.org/"
104 SRC_URI="http://build.chromium.org/official/${P}.tar.bz2"
105
106 LICENSE="BSD"
107 SLOT="0"
108 KEYWORDS="~amd64 ~x86"
109 IUSE="chromedriver cups gnome gnome-keyring kerberos pulseaudio"
110
111 # en_US is ommitted on purpose from the list below. It must always be available.
112 LANGS="am ar bg bn ca cs da de el en_GB es es_LA et fa fi fil fr gu he hi hr
113 hu id it ja kn ko lt lv ml mr nb nl pl pt_BR pt_PT ro ru sk sl sr sv sw ta te th
114 tr uk vi zh_CN zh_TW"
115 for lang in ${LANGS}; do
116 IUSE+=" linguas_${lang}"
117 done
118
119 RDEPEND="app-arch/bzip2
120 dev-libs/dbus-glib
121 >=dev-libs/icu-4.4.1
122 >=dev-libs/libevent-1.4.13
123 dev-libs/libxml2[icu]
124 dev-libs/libxslt
125 >=dev-libs/nss-3.12.3
126 gnome? ( >=gnome-base/gconf-2.24.0 )
127 gnome-keyring? ( >=gnome-base/gnome-keyring-2.28.2 )
128 >=media-libs/alsa-lib-1.0.19
129 media-libs/flac
130 virtual/jpeg
131 media-libs/libpng
132 >=media-libs/libwebp-0.1.2
133 media-libs/speex
134 pulseaudio? ( media-sound/pulseaudio )
135 cups? (
136 dev-libs/libgcrypt
137 >=net-print/cups-1.3.11
138 )
139 sys-libs/zlib
140 x11-libs/gtk+:2
141 x11-libs/libXinerama
142 x11-libs/libXScrnSaver
143 x11-libs/libXtst
144 kerberos? ( virtual/krb5 )"
145 DEPEND="${RDEPEND}
146 dev-lang/perl
147 >=dev-util/gperf-3.0.3
148 >=dev-util/pkgconfig-0.23
149 >=sys-devel/bison-2.4.3
150 sys-devel/flex
151 >=sys-devel/make-3.81-r2
152 test? (
153 dev-python/pyftpdlib
154 dev-python/simplejson
155 )"
156 RDEPEND+="
157 x11-misc/xdg-utils
158 virtual/ttf-fonts"
159
160 gyp_use() {
161 if [[ $# -lt 2 ]]; then
162 echo "!!! usage: gyp_use <USEFLAG> <GYPFLAG>" >&2
163 return 1
164 fi
165 if use "$1"; then echo "-D$2=1"; else echo "-D$2=0"; fi
166 }
167
168 egyp() {
169 set -- build/gyp_chromium --depth=. "${@}"
170 echo "${@}" >&2
171 "${@}"
172 }
173
174 # Chromium uses different names for some langs,
175 # return Chromium name corresponding to a Gentoo lang.
176 chromium_lang() {
177 if [[ "$1" == "es_LA" ]]; then
178 echo "es_419"
179 else
180 echo "$1"
181 fi
182 }
183
184 pkg_setup() {
185 CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser"
186
187 # Make sure the build system will use the right tools, bug #340795.
188 tc-export AR CC CXX RANLIB
189
190 # Make sure the build system will use the right python, bug #344367.
191 python_set_active_version 2
192 python_pkg_setup
193
194 # Prevent user problems like bug #348235.
195 eshopts_push -s extglob
196 if is-flagq '-g?(gdb)?([1-9])'; then
197 ewarn "You have enabled debug info (probably have -g or -ggdb in your \$C{,XX}FLAGS)."
198 ewarn "You may experience really long compilation times and/or increased memory usage."
199 ewarn "If compilation fails, please try removing -g{,gdb} before reporting a bug."
200 fi
201 eshopts_pop
202
203 # Warn if the kernel doesn't support features useful for sandboxing,
204 # bug #363907.
205 CONFIG_CHECK="~PID_NS ~NET_NS"
206 check_extra_config
207 }
208
209 src_prepare() {
210 # Backport upstream fix for using system Kerberos.
211 epatch "${FILESDIR}/${PN}-kerberos-r1.patch"
212
213 cp "${FILESDIR}/nacl.gypi" chrome/ || die
214
215 # Remove most bundled libraries. Some are still needed.
216 find third_party -type f \! -iname '*.gyp*' \
217 \! -path 'third_party/WebKit/*' \
218 \! -path 'third_party/angle/*' \
219 \! -path 'third_party/cacheinvalidation/*' \
220 \! -path 'third_party/cld/*' \
221 \! -path 'third_party/expat/*' \
222 \! -path 'third_party/ffmpeg/*' \
223 \! -path 'third_party/flac/flac.h' \
224 \! -path 'third_party/gpsd/*' \
225 \! -path 'third_party/harfbuzz/*' \
226 \! -path 'third_party/hunspell/*' \
227 \! -path 'third_party/iccjpeg/*' \
228 \! -path 'third_party/launchpad_translations/*' \
229 \! -path 'third_party/leveldb/*' \
230 \! -path 'third_party/leveldatabase/*' \
231 \! -path 'third_party/libjingle/*' \
232 \! -path 'third_party/libphonenumber/*' \
233 \! -path 'third_party/libvpx/*' \
234 \! -path 'third_party/mesa/*' \
235 \! -path 'third_party/modp_b64/*' \
236 \! -path 'third_party/mongoose/*' \
237 \! -path 'third_party/npapi/*' \
238 \! -path 'third_party/openmax/*' \
239 \! -path 'third_party/ots/*' \
240 \! -path 'third_party/protobuf/*' \
241 \! -path 'third_party/sfntly/*' \
242 \! -path 'third_party/skia/*' \
243 \! -path 'third_party/speex/speex.h' \
244 \! -path 'third_party/sqlite/*' \
245 \! -path 'third_party/tcmalloc/*' \
246 \! -path 'third_party/tlslite/*' \
247 \! -path 'third_party/undoview/*' \
248 \! -path 'third_party/v8-i18n/*' \
249 \! -path 'third_party/webdriver/*' \
250 \! -path 'third_party/webgl_conformance/*' \
251 \! -path 'third_party/webrtc/*' \
252 \! -path 'third_party/yasm/*' \
253 \! -path 'third_party/zlib/contrib/minizip/*' \
254 -delete || die
255
256 # Make sure the build system will use the right python, bug #344367.
257 # Only convert directories that need it, to save time.
258 python_convert_shebangs -q -r 2 build tools
259 }
260
261 src_configure() {
262 local myconf=""
263
264 # Never tell the build system to "enable" SSE2, it has a few unexpected
265 # additions, bug #336871.
266 myconf+=" -Ddisable_sse2=1"
267
268 # Disable NaCl temporarily, this tarball doesn't have IRT.
269 myconf+=" -Ddisable_nacl=1"
270
271 # Disable WebRTC until they make PulseAudio dependency optional,
272 # bug #377847.
273 myconf+=" -Denable_webrtc=0"
274
275 # Use system-provided libraries.
276 # TODO: use_system_ffmpeg
277 # TODO: use_system_hunspell (upstream changes needed).
278 # TODO: use_system_ssl (http://crbug.com/58087).
279 # TODO: use_system_sqlite (http://crbug.com/22208).
280 # TODO: use_system_vpx
281 myconf+="
282 -Duse_system_bzip2=1
283 -Duse_system_flac=1
284 -Duse_system_icu=1
285 -Duse_system_libevent=1
286 -Duse_system_libjpeg=1
287 -Duse_system_libpng=1
288 -Duse_system_libwebp=1
289 -Duse_system_libxml=1
290 -Duse_system_speex=1
291 -Duse_system_xdg_utils=1
292 -Duse_system_zlib=1"
293
294 # Optional dependencies.
295 myconf+="
296 $(gyp_use cups use_cups)
297 $(gyp_use gnome use_gconf)
298 $(gyp_use gnome-keyring use_gnome_keyring)
299 $(gyp_use gnome-keyring linux_link_gnome_keyring)
300 $(gyp_use kerberos use_kerberos)
301 $(gyp_use kerberos linux_link_kerberos)
302 $(gyp_use pulseaudio use_pulseaudio)"
303
304 # Enable sandbox.
305 myconf+="
306 -Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
307 -Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
308
309 if host-is-pax; then
310 # Prevent the build from failing (bug #301880). The performance
311 # difference is very small.
312 myconf+=" -Dv8_use_snapshot=0"
313 fi
314
315 # Our system ffmpeg should support more codecs than the bundled one
316 # for Chromium.
317 # myconf+=" -Dproprietary_codecs=1"
318
319 local myarch="$(tc-arch)"
320 if [[ $myarch = amd64 ]] ; then
321 myconf+=" -Dtarget_arch=x64"
322 elif [[ $myarch = x86 ]] ; then
323 myconf+=" -Dtarget_arch=ia32"
324 elif [[ $myarch = arm ]] ; then
325 # TODO: check this again after
326 # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39509 is fixed.
327 append-flags -fno-tree-sink
328
329 myconf+=" -Dtarget_arch=arm -Ddisable_nacl=1 -Dlinux_use_tcmalloc=0"
330 else
331 die "Failed to determine target arch, got '$myarch'."
332 fi
333
334 # Make sure that -Werror doesn't get added to CFLAGS by the build system.
335 # Depending on GCC version the warnings are different and we don't want
336 # the build to fail because of that.
337 myconf+=" -Dwerror="
338
339 # Avoid a build error with -Os, bug #352457.
340 replace-flags "-Os" "-O2"
341
342 egyp ${myconf} || die
343 }
344
345 src_compile() {
346 emake chrome chrome_sandbox BUILDTYPE=Release V=1 || die
347 pax-mark m out/Release/chrome
348 if use chromedriver; then
349 emake chromedriver BUILDTYPE=Release V=1 || die
350 fi
351 if use test; then
352 emake {base,crypto,googleurl,net}_unittests BUILDTYPE=Release V=1 || die
353 pax-mark m out/Release/{base,crypto,googleurl,net}_unittests
354 fi
355 }
356
357 src_test() {
358 # For more info see bug #350349.
359 local mylocale='en_US.utf8'
360 if ! locale -a | grep -q "$mylocale"; then
361 eerror "${PN} requires ${mylocale} locale for tests"
362 eerror "Please read the following guides for more information:"
363 eerror " http://www.gentoo.org/doc/en/guide-localization.xml"
364 eerror " http://www.gentoo.org/doc/en/utf-8.xml"
365 die "locale ${mylocale} is not supported"
366 fi
367
368 # For more info see bug #370957.
369 if [[ $UID -eq 0 ]]; then
370 die "Tests must be run as non-root. Please use FEATURES=userpriv."
371 fi
372
373 # For more info see bug #350347.
374 LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/base_unittests virtualmake \
375 '--gtest_filter=-ICUStringConversionsTest.*'
376
377 LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/crypto_unittests virtualmake
378 LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/googleurl_unittests virtualmake
379
380 # NetUtilTest: bug #361885.
381 # NetUtilTest.GenerateFileName: some locale-related mismatch.
382 # UDP: unstable, active development. We should revisit this later.
383 LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/net_unittests virtualmake \
384 '--gtest_filter=-NetUtilTest.IDNToUnicode*:NetUtilTest.FormatUrl*:NetUtilTest.GenerateFileName:*UDP*'
385 }
386
387 src_install() {
388 exeinto "${CHROMIUM_HOME}"
389 doexe out/Release/chrome || die
390 doexe out/Release/chrome_sandbox || die
391 fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox"
392
393 if use chromedriver; then
394 doexe out/Release/chromedriver || die
395 fi
396
397 # Install Native Client files on platforms that support it.
398 # insinto "${CHROMIUM_HOME}"
399 # case "$(tc-arch)" in
400 # amd64)
401 # doins native_client/irt_binaries/nacl_irt_x86_64.nexe || die
402 # doins out/Release/libppGoogleNaClPluginChrome.so || die
403 # ;;
404 # x86)
405 # doins native_client/irt_binaries/nacl_irt_x86_32.nexe || die
406 # doins out/Release/libppGoogleNaClPluginChrome.so || die
407 # ;;
408 # esac
409
410 newexe "${FILESDIR}"/chromium-launcher-r2.sh chromium-launcher.sh || die
411
412 # It is important that we name the target "chromium-browser",
413 # xdg-utils expect it; bug #355517.
414 dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium-browser || die
415 # keep the old symlink around for consistency
416 dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium || die
417
418 # Allow users to override command-line options, bug #357629.
419 dodir /etc/chromium || die
420 insinto /etc/chromium
421 newins "${FILESDIR}/chromium.default" "default" || die
422
423 # Support LINGUAS, bug #332751.
424 local pak
425 for pak in out/Release/locales/*.pak; do
426 local pakbasename="$(basename ${pak})"
427 local pakname="${pakbasename%.pak}"
428 local langname="${pakname//-/_}"
429
430 # Do not issue warning for en_US locale. This is the fallback
431 # locale so it should always be installed.
432 if [[ "${langname}" == "en_US" ]]; then
433 continue
434 fi
435
436 local found=false
437 local lang
438 for lang in ${LANGS}; do
439 local crlang="$(chromium_lang ${lang})"
440 if [[ "${langname}" == "${crlang}" ]]; then
441 found=true
442 break
443 fi
444 done
445 if ! $found; then
446 ewarn "LINGUAS warning: no ${langname} in LANGS"
447 fi
448 done
449 local lang
450 for lang in ${LANGS}; do
451 local crlang="$(chromium_lang ${lang})"
452 local pakfile="out/Release/locales/${crlang//_/-}.pak"
453 if [ ! -f "${pakfile}" ]; then
454 ewarn "LINGUAS warning: no .pak file for ${lang} (${pakfile} not found)"
455 fi
456 if ! use linguas_${lang}; then
457 rm "${pakfile}" || die
458 fi
459 done
460
461 insinto "${CHROMIUM_HOME}"
462 doins out/Release/chrome.pak || die
463 doins out/Release/resources.pak || die
464
465 doins -r out/Release/locales || die
466 doins -r out/Release/resources || die
467
468 newman out/Release/chrome.1 chromium.1 || die
469 newman out/Release/chrome.1 chromium-browser.1 || die
470
471 # Chromium looks for these in its folder
472 # See media_posix.cc and base_paths_linux.cc
473 # dosym /usr/$(get_libdir)/libavcodec.so.52 "${CHROMIUM_HOME}" || die
474 # dosym /usr/$(get_libdir)/libavformat.so.52 "${CHROMIUM_HOME}" || die
475 # dosym /usr/$(get_libdir)/libavutil.so.50 "${CHROMIUM_HOME}" || die
476 doexe out/Release/libffmpegsumo.so || die
477
478 # Install icons and desktop entry.
479 # size 64: bug #378777.
480 for SIZE in 16 22 24 32 48 128 256 ; do
481 insinto /usr/share/icons/hicolor/${SIZE}x${SIZE}/apps
482 newins chrome/app/theme/chromium/product_logo_${SIZE}.png \
483 chromium-browser.png || die
484 done
485 local mime_types="text/html;text/xml;application/xhtml+xml;"
486 mime_types+="x-scheme-handler/http;x-scheme-handler/https;" # bug #360797
487 make_desktop_entry chromium-browser "Chromium" chromium-browser \
488 "Network;WebBrowser" \
489 "MimeType=${mime_types}\nStartupWMClass=chromium-browser"
490 sed -e "/^Exec/s/$/ %U/" -i "${ED}"/usr/share/applications/*.desktop || die
491
492 # Install GNOME default application entry (bug #303100).
493 if use gnome; then
494 dodir /usr/share/gnome-control-center/default-apps || die
495 insinto /usr/share/gnome-control-center/default-apps
496 doins "${FILESDIR}"/chromium-browser.xml || die
497 fi
498 }
499
500 pkg_preinst() {
501 gnome2_icon_savelist
502 }
503
504 pkg_postinst() {
505 fdo-mime_desktop_database_update
506 gnome2_icon_cache_update
507
508 # For more info see bug #292201, bug #352263, bug #361859.
509 elog
510 elog "Depending on your desktop environment, you may need"
511 elog "to install additional packages to get icons on the Downloads page."
512 elog
513 elog "For KDE, the required package is kde-base/oxygen-icons."
514 elog
515 elog "For other desktop environments, try one of the following:"
516 elog " - x11-themes/gnome-icon-theme"
517 elog " - x11-themes/tango-icon-theme"
518
519 # For more info see bug #359153.
520 elog
521 elog "Some web pages may require additional fonts to display properly."
522 elog "Try installing some of the following packages if some characters"
523 elog "are not displayed properly:"
524 elog " - media-fonts/arphicfonts"
525 elog " - media-fonts/bitstream-cyberbit"
526 elog " - media-fonts/droid"
527 elog " - media-fonts/ipamonafont"
528 elog " - media-fonts/ja-ipafonts"
529 elog " - media-fonts/takao-fonts"
530 elog " - media-fonts/wqy-microhei"
531 elog " - media-fonts/wqy-zenhei"
532 }
533
534 pkg_postrm() {
535 gnome2_icon_cache_update
536 }