[gentoo-commits] proj/kde:master commit in: dev-util/kdevplatform/

[Chris Reffett]

commit:     05360efdfd989b30d4dc8a9760d46890464d077e
Author:     Chris Reffett <creffett <AT> gentoo <DOT> org>
AuthorDate: Fri Dec 27 15:19:11 2013 +0000
Commit:     Chris Reffett <creffett <AT> gentoo <DOT> org>
CommitDate: Fri Dec 27 15:19:11 2013 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/kde.git;a=commit;h=05360efd

[dev-util/kdevplatform] Bump to 1.6.0, add RESTRICT=test due to test hang

Package-Manager: portage-2.2.7

---
 dev-util/kdevplatform/kdevplatform-1.6.0.ebuild | 53 +++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/dev-util/kdevplatform/kdevplatform-1.6.0.ebuild b/dev-util/kdevplatform/kdevplatform-1.6.0.ebuild
new file mode 100644
index 0000000..f61dd1c
--- /dev/null
+++ b/dev-util/kdevplatform/kdevplatform-1.6.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kdevelop"
+KDE_MINIMAL="4.7"
+KDE_LINGUAS="bs ca ca@valencia da de el en_GB es et fi fr gl it kk nb nds nl pl
+pt pt_BR ru sk sl sv th uk zh_CN zh_TW"
+VIRTUALDBUS_TEST="true"
+VIRTUALX_REQUIRED="test"
+EGIT_REPONAME="${PN}"
+inherit kde4-base
+
+DESCRIPTION="KDE development support libraries and apps"
+LICENSE="GPL-2 LGPL-2"
+IUSE="cvs debug reviewboard subversion"
+SRC_URI="mirror://kde/stable/kdevelop/${KDEVELOP_VERSION}/src/${P}.tar.xz"
+
+if [[ $PV == *9999 ]]; then
+	KEYWORDS=""
+else
+	KEYWORDS="~amd64 ~ppc ~x86"
+fi
+
+RESTRICT="test"
+
+DEPEND="
+	dev-libs/boost:=
+	dev-libs/grantlee
+	reviewboard? ( dev-libs/qjson )
+	subversion? (
+		dev-libs/apr
+		dev-libs/apr-util
+		dev-vcs/subversion
+	)
+"
+RDEPEND="${DEPEND}
+	!<dev-util/kdevelop-${KDEVELOP_VERSION}:4
+	$(add_kdebase_dep konsole)
+	cvs? ( dev-vcs/cvs )
+"
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_build cvs)
+		$(cmake-utils_use_find_package reviewboard QJSON)
+		$(cmake-utils_use_build subversion)
+	)
+
+	kde4-base_src_configure
+}