[gentoo-commits] gentoo-x86 commit in gnome-extra/gnome-games: gnome-games-3.2.1-r1.ebuild gnome-games-3.2.1.ebuild gnome-games-2.30.2-r1.ebuild gnome-games-2.28.2.ebuild ChangeLog gnome-games-2.30.2-r2.ebuild

[Alexandre Rostovtsev (tetromino)]

tetromino    12/01/04 23:30:10

  Modified:             gnome-games-3.2.1.ebuild
                        gnome-games-2.30.2-r1.ebuild
                        gnome-games-2.28.2.ebuild ChangeLog
                        gnome-games-2.30.2-r2.ebuild
  Added:                gnome-games-3.2.1-r1.ebuild
  Log:
  Fix py-compile idiom for automake-1.11.2 compatibility (bugs #396585, #397335). Move gnome2_src_prepare after eautoreconf. Revbump to fix sudoku set_bg_color traceback and pygobject-3.0.3 crashes (bug #397501), and to not install libgames-support-gi.a.
  
  (Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

Revision  Changes    Path
1.2                  gnome-extra/gnome-games/gnome-games-3.2.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-games/gnome-games-3.2.1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-games/gnome-games-3.2.1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-games/gnome-games-3.2.1.ebuild?r1=1.1&r2=1.2

Index: gnome-games-3.2.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/gnome-games-3.2.1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- gnome-games-3.2.1.ebuild	7 Nov 2011 04:03:58 -0000	1.1
+++ gnome-games-3.2.1.ebuild	4 Jan 2012 23:30:09 -0000	1.2
@@ -1,6 +1,6 @@
-# Copyright 1999-2011 Gentoo Foundation
+# Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/gnome-games-3.2.1.ebuild,v 1.1 2011/11/07 04:03:58 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/gnome-games-3.2.1.ebuild,v 1.2 2012/01/04 23:30:09 tetromino Exp $
 
 EAPI="3"
 GNOME_TARBALL_SUFFIX="xz"
@@ -128,8 +128,6 @@
 }
 
 src_prepare() {
-	gnome2_src_prepare
-
 	use sudoku && python_convert_shebangs -r 2 gnome-sudoku/src
 
 	# TODO: File upstream bug for this
@@ -141,8 +139,9 @@
 	eautoreconf
 
 	# disable pyc compiling
-	mv py-compile py-compile.orig
-	ln -s $(type -P true) py-compile
+	echo > py-compile
+
+	gnome2_src_prepare
 }
 
 src_test() {



1.15                 gnome-extra/gnome-games/gnome-games-2.30.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.30.2-r1.ebuild?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.30.2-r1.ebuild?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.30.2-r1.ebuild?r1=1.14&r2=1.15

Index: gnome-games-2.30.2-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.30.2-r1.ebuild,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- gnome-games-2.30.2-r1.ebuild	25 Apr 2011 21:17:50 -0000	1.14
+++ gnome-games-2.30.2-r1.ebuild	4 Jan 2012 23:30:09 -0000	1.15
@@ -1,6 +1,6 @@
-# Copyright 1999-2011 Gentoo Foundation
+# Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.30.2-r1.ebuild,v 1.14 2011/04/25 21:17:50 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.30.2-r1.ebuild,v 1.15 2012/01/04 23:30:09 tetromino Exp $
 
 EAPI="3"
 GCONF_DEBUG="no"
@@ -120,8 +120,7 @@
 	gnome2_src_prepare
 
 	# disable pyc compiling
-	mv py-compile py-compile.orig
-	ln -s $(type -P true) py-compile
+	echo > py-compile
 }
 
 src_test() {



1.11                 gnome-extra/gnome-games/gnome-games-2.28.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.28.2.ebuild?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.28.2.ebuild?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.28.2.ebuild?r1=1.10&r2=1.11

Index: gnome-games-2.28.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.28.2.ebuild,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- gnome-games-2.28.2.ebuild	25 Apr 2011 21:17:50 -0000	1.10
+++ gnome-games-2.28.2.ebuild	4 Jan 2012 23:30:09 -0000	1.11
@@ -1,6 +1,6 @@
-# Copyright 1999-2011 Gentoo Foundation
+# Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.28.2.ebuild,v 1.10 2011/04/25 21:17:50 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.28.2.ebuild,v 1.11 2012/01/04 23:30:09 tetromino Exp $
 
 EAPI="3"
 GCONF_DEBUG="no"
@@ -122,8 +122,7 @@
 	gnome2_src_prepare
 
 	# disable pyc compiling
-	mv py-compile py-compile.orig
-	ln -s $(type -P true) py-compile
+	echo > py-compile
 
 	# Fix implicit declaration of yylex.
 	epatch "${FILESDIR}/${PN}-2.26.3-implicit-declaration.patch"



1.313                gnome-extra/gnome-games/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-games/ChangeLog?rev=1.313&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-games/ChangeLog?rev=1.313&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-games/ChangeLog?r1=1.312&r2=1.313

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/ChangeLog,v
retrieving revision 1.312
retrieving revision 1.313
diff -u -r1.312 -r1.313
--- ChangeLog	7 Nov 2011 04:03:58 -0000	1.312
+++ ChangeLog	4 Jan 2012 23:30:09 -0000	1.313
@@ -1,6 +1,18 @@
 # ChangeLog for gnome-extra/gnome-games
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/ChangeLog,v 1.312 2011/11/07 04:03:58 tetromino Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/ChangeLog,v 1.313 2012/01/04 23:30:09 tetromino Exp $
+
+*gnome-games-3.2.1-r1 (04 Jan 2012)
+
+  04 Jan 2012; Alexandre Rostovtsev <tetromino@g.o>
+  gnome-games-2.28.2.ebuild, gnome-games-2.30.2-r1.ebuild,
+  gnome-games-2.30.2-r2.ebuild, gnome-games-3.2.1.ebuild,
+  +gnome-games-3.2.1-r1.ebuild, +files/gnome-games-3.2.1-pygobject-3.0.3.patch,
+  +files/gnome-games-3.2.1-sudoku-borders.patch:
+  Fix py-compile idiom for automake-1.11.2 compatibility (bugs #396585,
+  #397335). Move gnome2_src_prepare after eautoreconf. Revbump to fix sudoku
+  set_bg_color traceback and pygobject-3.0.3 crashes (bug #397501), and to not
+  install libgames-support-gi.a.
 
 *gnome-games-3.2.1 (07 Nov 2011)
 



1.2                  gnome-extra/gnome-games/gnome-games-2.30.2-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.30.2-r2.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.30.2-r2.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.30.2-r2.ebuild?r1=1.1&r2=1.2

Index: gnome-games-2.30.2-r2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.30.2-r2.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- gnome-games-2.30.2-r2.ebuild	6 Nov 2011 05:50:58 -0000	1.1
+++ gnome-games-2.30.2-r2.ebuild	4 Jan 2012 23:30:09 -0000	1.2
@@ -1,6 +1,6 @@
-# Copyright 1999-2011 Gentoo Foundation
+# Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.30.2-r2.ebuild,v 1.1 2011/11/06 05:50:58 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/gnome-games-2.30.2-r2.ebuild,v 1.2 2012/01/04 23:30:09 tetromino Exp $
 
 EAPI="3"
 GCONF_DEBUG="no"
@@ -122,8 +122,7 @@
 	python_convert_shebangs -r 2 gnome-sudoku/src
 
 	# disable pyc compiling
-	mv py-compile py-compile.orig
-	ln -s $(type -P true) py-compile
+	echo > py-compile
 }
 
 src_test() {



1.1                  gnome-extra/gnome-games/gnome-games-3.2.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-games/gnome-games-3.2.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-games/gnome-games-3.2.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: gnome-games-3.2.1-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-games/gnome-games-3.2.1-r1.ebuild,v 1.1 2012/01/04 23:30:09 tetromino Exp $

EAPI="3"
GNOME_TARBALL_SUFFIX="xz"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
WANT_AUTOMAKE="1.11"
PYTHON_DEPEND="2:2.4"
PYTHON_USE_WITH="xml"

# make sure games is inherited first so that the gnome2
# functions will be called if they are not overridden
inherit autotools games eutils gnome2 python virtualx

DESCRIPTION="Collection of games for the GNOME desktop"
HOMEPAGE="http://live.gnome.org/GnomeGames/"

LICENSE="GPL-2 GPL-3 FDL-1.1"
SLOT="0"
# TODO: file KEYWORDREQ bug once it's determined that seed is usable
KEYWORDS="~amd64 ~x86"
IUSE="artworkextra +aisleriot +clutter +introspection glchess seed +sudoku test"

COMMON_DEPEND="
	>=dev-libs/dbus-glib-0.75
	>=dev-libs/glib-2.25.7
	>=dev-libs/libxml2-2.4.0
	>=gnome-base/gconf-2.31.1
	>=gnome-base/librsvg-2.32
	>=x11-libs/cairo-1
	>=x11-libs/gtk+-2.91.7:3[introspection?]

	media-libs/libcanberra[gtk3]
	x11-libs/libSM

	artworkextra? ( >=gnome-extra/gnome-games-extra-data-3.0.0 )
	clutter? (
		>=dev-libs/gobject-introspection-0.6.3
		>=x11-libs/gtk+-2.90:3[introspection]
		>=gnome-base/gconf-2.31.1[introspection]
		>=media-libs/clutter-gtk-0.91.6:1.0[introspection]
		seed? ( >=dev-libs/seed-2.91.90 ) )
	introspection? (
		>=dev-libs/gobject-introspection-0.6.3
		media-libs/clutter:1.0[introspection] )
	glchess? (
		dev-db/sqlite:3
		>=gnome-base/librsvg-2.32
		virtual/opengl
		x11-libs/libX11 )"
RDEPEND="${COMMON_DEPEND}
	sudoku? (
		|| ( dev-python/pygobject:3 >=dev-python/pygobject-2.28.3:2[introspection] )
		x11-libs/gdk-pixbuf:2[introspection]
		x11-libs/pango[introspection]
		>=x11-libs/gtk+-3.0.0:3[introspection] )

	!<gnome-extra/gnome-games-extra-data-3.0.0"
DEPEND="${COMMON_DEPEND}
	glchess? ( >=dev-lang/vala-0.13.0:0.14 )
	>=dev-util/pkgconfig-0.15
	>=dev-util/intltool-0.40.4
	>=sys-devel/gettext-0.10.40
	>=gnome-base/gnome-common-2.12.0
	>=app-text/scrollkeeper-0.3.8
	>=app-text/gnome-doc-utils-0.10
	test? ( >=dev-libs/check-0.9.4 )"

# For compatibility with older versions of the gnome-games package
PDEPEND="aisleriot? ( games-board/aisleriot )"

# Others are installed below; multiples in this package.
DOCS="AUTHORS HACKING MAINTAINERS TODO"

_omitgame() {
	G2CONF="${G2CONF},${1}"
}

pkg_setup() {
	# create the games user / group
	games_pkg_setup

	python_set_active_version 2
	python_pkg_setup

	G2CONF="${G2CONF}
		--disable-schemas-compile
		--disable-static
		--enable-sound
		$(use_enable introspection)"

	# Should be after $(use_enable introspection), but before --enable-omitgames
	use clutter && G2CONF="${G2CONF} --enable-introspection"

	use glchess && G2CONF="${G2CONF} VALAC=$(type -p valac-0.14)"

	# Staging games are needed for swell-foop and lightsoff
	G2CONF="${G2CONF}
		--enable-staging
		--with-scores-group=${GAMES_GROUP}
		--with-platform=gnome
		--with-smclient
		--with-gtk=3.0
		--enable-omitgames=none" # This line should be last for _omitgame

	# FIXME: Use REQUIRED_USE once games.eclass is ported to EAPI 4
	if ! use clutter; then
		ewarn "USE='-clutter' => quadrapassel, swell-foop, lightsoff, gnibbles won't be installed"
		_omitgame quadrapassel
		_omitgame gnibbles
		_omitgame swell-foop
		_omitgame lightsoff
		use seed && ewarn "USE='seed' has no effect with USE='-clutter'"
	elif ! use seed; then
		ewarn "USE='-seed' => swell-foop, lightsoff won't be installed"
		_omitgame swell-foop
		_omitgame lightsoff
	fi

	if ! use glchess; then
		_omitgame glchess
	fi

	if ! use sudoku; then
		_omitgame gnome-sudoku
	fi
}

src_prepare() {
	use sudoku && python_convert_shebangs -r 2 gnome-sudoku/src

	# TODO: File upstream bug for this
	epatch "${FILESDIR}/${PN}-2.91.90-fix-conditional-ac-prog-cxx.patch"

	# Without this, --enable-staging enables all those games unconditionally
	epatch "${FILESDIR}/${PN}-fix-staging-games.patch"

	# gnome-sudoku patch, will be in next release
	epatch "${FILESDIR}/${P}-sudoku-borders.patch"

	# patch from upstream git master fixing sudoku with pygobject-3.0.3, #397501
	epatch "${FILESDIR}/${P}-pygobject-3.0.3.patch"

	eautoreconf

	# disable pyc compiling
	echo > py-compile

	gnome2_src_prepare
}

src_test() {
	Xemake check || die "tests failed"
}

src_install() {
	gnome2_src_install

	# Documentation install for each of the games
	for game in \
	$(find . -maxdepth 1 -type d ! -name po ! -name libgames-support); do
		docinto ${game}
		for doc in AUTHORS ChangeLog NEWS README TODO; do
			[ -s ${game}/${doc} ] && dodoc ${game}/${doc}
		done
	done
}

pkg_preinst() {
	gnome2_pkg_preinst
	# Avoid overwriting previous .scores files
	local basefile
	for scorefile in "${ED}"/var/lib/games/*.scores; do
		basefile=$(basename $scorefile)
		if [ -s "${EROOT}/var/lib/games/${basefile}" ]; then
			cp "${EROOT}/var/lib/games/${basefile}" \
			"${ED}/var/lib/games/${basefile}"
		fi
	done
}

pkg_postinst() {
	games_pkg_postinst
	gnome2_pkg_postinst
	python_need_rebuild
	use sudoku && python_mod_optimize gnome_sudoku
}

pkg_postrm() {
	gnome2_pkg_postrm
	python_mod_cleanup gnome_sudoku
}