[gentoo-commits] repo/gentoo:master commit in: mate-extra/mate-screensaver/

[Adam Feldman]

commit:     8b6824edda98005b7755573409d127ad5d5b0e4c
Author:     Adam Feldman <NP-Hardass <AT> gentoo <DOT> org>
AuthorDate: Fri Sep  4 17:23:40 2020 +0000
Commit:     Adam Feldman <np-hardass <AT> gentoo <DOT> org>
CommitDate: Fri Sep 25 20:32:08 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8b6824ed

mate-extra/mate-screensaver: Bump to 1.24.1

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Adam Feldman <NP-Hardass <AT> gentoo.org>

 mate-extra/mate-screensaver/Manifest               |   1 +
 .../mate-screensaver-1.24.1.ebuild                 | 121 +++++++++++++++++++++
 2 files changed, 122 insertions(+)

diff --git a/mate-extra/mate-screensaver/Manifest b/mate-extra/mate-screensaver/Manifest
index 1af2c5137fb..8c093767512 100644
--- a/mate-extra/mate-screensaver/Manifest
+++ b/mate-extra/mate-screensaver/Manifest
@@ -1 +1,2 @@
 DIST mate-screensaver-1.24.0.tar.xz 5075860 BLAKE2B f669cb9ce1c84cdd2dd84b1c88b668ad1910102ae5d9765117d313b6ece03e535b5fdaae600d8f3315346ac1109d1316e15c0dcac5bd4a637b682fa7b5d1e22b SHA512 8947b85ab8b006a1756649131a9184e4eb8f44c563f5a1b55840aa8280820713bca1ce46fece92b5ac44a73193bfe965e8ef0d17e8e403a751807ee72c674cc0
+DIST mate-screensaver-1.24.1.tar.xz 5073836 BLAKE2B 501c8dffbb5e53b88414c799a6e4d25cf89dfe490e6a902901c339b142e2b687dc2e668f65349a2ff43b6eb44d7721658de771b1a698624f95d1828da2fbda67 SHA512 f7cab280da90623ad265beb84770e48431ae6685fbb1eabc7cd2ad07b0f8ed5da2426017243d83271b969d2e020b8afcc93a6135b4c8e42a29f454a4e826b277

diff --git a/mate-extra/mate-screensaver/mate-screensaver-1.24.1.ebuild b/mate-extra/mate-screensaver/mate-screensaver-1.24.1.ebuild
new file mode 100644
index 00000000000..485f4ee1e39
--- /dev/null
+++ b/mate-extra/mate-screensaver/mate-screensaver-1.24.1.ebuild
@@ -0,0 +1,121 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit mate readme.gentoo-r1
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+DESCRIPTION="Replaces xscreensaver, integrating with the MATE desktop"
+
+LICENSE="GPL-2+ HPND LGPL-2+"
+SLOT="0"
+IUSE="X debug consolekit elogind kernel_linux libnotify opengl pam systemd"
+REQUIRED_USE="?? ( elogind systemd )"
+
+COMMON_DEPEND="
+	>=dev-libs/dbus-glib-0.71:0
+	>=dev-libs/glib-2.50:2
+	gnome-base/dconf
+	>=mate-base/libmatekbd-1.17.0
+	>=mate-base/mate-desktop-1.17.0
+	>=mate-base/mate-menus-1.21.0
+	>=sys-apps/dbus-0.30
+	>=x11-libs/gdk-pixbuf-2.14:2
+	>=x11-libs/libX11-1
+	x11-libs/cairo
+	>=x11-libs/gtk+-3.22:3
+	x11-libs/libXext
+	x11-libs/libXrandr
+	x11-libs/libXScrnSaver
+	x11-libs/libXxf86vm
+	x11-libs/libxklavier
+	x11-libs/pango
+	consolekit? ( sys-auth/consolekit )
+	libnotify? ( >=x11-libs/libnotify-0.7:0 )
+	opengl? ( virtual/opengl )
+	pam? ( gnome-base/gnome-keyring sys-libs/pam )
+	!pam? ( kernel_linux? ( sys-apps/shadow ) )
+	elogind? ( sys-auth/elogind )
+	systemd? ( sys-apps/systemd:= )
+"
+
+RDEPEND="${COMMON_DEPEND}
+	>=mate-base/mate-session-manager-1.6
+	virtual/libintl
+	!!<gnome-extra/gnome-screensaver-3
+"
+
+DEPEND="${COMMON_DEPEND}
+	dev-libs/libxml2
+	>=sys-devel/gettext-0.19.8:*
+	x11-base/xorg-proto
+	virtual/pkgconfig:*
+"
+
+DOC_CONTENTS="
+	Information for converting screensavers is located in
+	/usr/share/doc/${PF}/xss-conversion.txt*
+"
+
+src_configure() {
+	local myconf=(
+		--enable-locking
+		--with-kbd-layout-indicator
+		--with-xf86gamma-ext
+		--with-xscreensaverdir=/usr/share/xscreensaver/config
+		--with-xscreensaverhackdir=/usr/$(get_libdir)/misc/xscreensaver
+		$(use_with X x)
+		$(use_with consolekit console-kit)
+		$(use_with elogind)
+		$(use_with libnotify)
+		$(use_with opengl libgl)
+		$(use_with systemd)
+		$(use_enable debug)
+		$(use_enable pam)
+	)
+
+	mate_src_configure "${myconf[@]}"
+}
+
+src_install() {
+	mate_src_install
+
+	# Install the conversion script in the documentation.
+	dodoc "${S}"/data/migrate-xscreensaver-config.sh
+	dodoc "${S}"/data/xscreensaver-config.xsl
+	dodoc "${FILESDIR}"/xss-conversion.txt
+
+	# Non PAM users will need this suid to read the password hashes.
+	# OpenPAM users will probably need this too when
+	# https://bugzilla.gnome.org/show_bug.cgi?id=370847
+	# is fixed.
+	if ! use pam ; then
+		fperms u+s /usr/libexec/mate-screensaver-dialog
+	fi
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	mate_pkg_postinst
+
+	if has_version "<x11-base/xorg-server-1.5.3-r4" ; then
+		ewarn "You have a too old xorg-server installation. This will cause"
+		ewarn "mate-screensaver to eat up your CPU. Please consider upgrading."
+		echo
+	fi
+
+	if has_version "<x11-misc/xscreensaver-4.22-r2" ; then
+		ewarn "You have xscreensaver installed, you probably want to disable it."
+		ewarn "To prevent a duplicate screensaver entry in the menu, you need to"
+		ewarn "build xscreensaver with -gnome in the USE flags."
+		ewarn "echo \"x11-misc/xscreensaver -gnome\" >> /etc/portage/package.use"
+		echo
+	fi
+
+	readme.gentoo_print_elog
+}