[gentoo-commits] gentoo-x86 commit in media-video/dvdrip: dvdrip-0.98.11-r2.ebuild ChangeLog dvdrip-0.98.11-r1.ebuild

[Ian Stakenvicius (axs)]

axs         14/08/27 17:21:14

  Modified:             ChangeLog
  Added:                dvdrip-0.98.11-r2.ebuild
  Removed:              dvdrip-0.98.11-r1.ebuild
  Log:
  bumped EAPI to 5 ; committed directly to stable as no other changes and the EAPI bump helps stable users when upgrading to dev-lang/perl-5.18
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, RepoMan options: --force, signed Manifest commit with key 2B6559ED)

Revision  Changes    Path
1.143                media-video/dvdrip/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/dvdrip/ChangeLog?rev=1.143&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/dvdrip/ChangeLog?rev=1.143&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/dvdrip/ChangeLog?r1=1.142&r2=1.143

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/dvdrip/ChangeLog,v
retrieving revision 1.142
retrieving revision 1.143
diff -u -r1.142 -r1.143
--- ChangeLog	27 Mar 2014 19:18:33 -0000	1.142
+++ ChangeLog	27 Aug 2014 17:21:14 -0000	1.143
@@ -1,6 +1,13 @@
 # ChangeLog for media-video/dvdrip
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/dvdrip/ChangeLog,v 1.142 2014/03/27 19:18:33 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/dvdrip/ChangeLog,v 1.143 2014/08/27 17:21:14 axs Exp $
+
+*dvdrip-0.98.11-r2 (27 Aug 2014)
+
+  27 Aug 2014; Ian Stakenvicius (_AxS_) <axs@g.o>
+  +dvdrip-0.98.11-r2.ebuild, -dvdrip-0.98.11-r1.ebuild:
+  bumped EAPI to 5 ; committed directly to stable as no other changes and the
+  EAPI bump helps stable users when upgrading to dev-lang/perl-5.18
 
   27 Mar 2014; Samuli Suominen <ssuominen@g.o> dvdrip-0.98.11-r1.ebuild:
   Fix default path to the optical device w/ current udev wrt #224559 by DEMAINE



1.1                  media-video/dvdrip/dvdrip-0.98.11-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/dvdrip/dvdrip-0.98.11-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/dvdrip/dvdrip-0.98.11-r2.ebuild?rev=1.1&content-type=text/plain

Index: dvdrip-0.98.11-r2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/dvdrip/dvdrip-0.98.11-r2.ebuild,v 1.1 2014/08/27 17:21:14 axs Exp $

EAPI=5
inherit eutils flag-o-matic perl-module

DESCRIPTION="dvd::rip is a graphical frontend for transcode"
HOMEPAGE="http://www.exit1.org/dvdrip/"
SRC_URI="http://www.exit1.org/dvdrip/dist/${P}.tar.gz"

SLOT="0"
KEYWORDS="amd64 ppc ppc64 x86"
IUSE="ffmpeg fping mplayer ogg subtitles vcd vorbis xine xvid"

DEPEND=">=dev-perl/Event-ExecFlow-0.64
	>=dev-perl/Event-RPC-0.89
	dev-perl/gtk2-perl
	>=dev-perl/gtk2-ex-formfactory-0.65
	>=dev-perl/libintl-perl-1.16
	|| ( media-gfx/graphicsmagick[imagemagick] media-gfx/imagemagick )
	>=media-video/transcode-1.1.0[dvd,jpeg,mp3,ogg,vorbis]"
RDEPEND="${DEPEND}
	x11-libs/gdk-pixbuf:2[jpeg]
	x11-libs/gtk+:2
	ffmpeg? ( virtual/ffmpeg )
	fping? ( >=net-analyzer/fping-2.2 )
	mplayer? ( media-video/mplayer )
	ogg? ( media-sound/ogmtools )
	subtitles? ( media-video/subtitleripper )
	vcd? (
		media-video/transcode[mjpeg]
		>=media-video/mjpegtools-1.6.0
	)
	vorbis? ( media-sound/vorbis-tools )
	xine? ( media-video/xine-ui )
	xvid? ( media-video/xvid4conf )
	>=media-video/lsdvd-0.15"

pkg_setup() {
	filter-flags -ftracer
	export SKIP_UNPACK_REQUIRED_MODULES=1 #255269

	perl-module_pkg_setup
}

src_prepare() {
	sed -i -e 's:$(CC):$(CC) $(OTHERLDFLAGS):' src/Makefile || die #333739
	epatch "${FILESDIR}"/${P}-fix_parallel_make.patch
	# Fix default device for >=udev-180 wrt #224559
	sed -i -e 's:/dev/dvd:/dev/cdrom:' lib/Video/DVDRip/Config.pm || die
}

src_install() {
	newicon lib/Video/DVDRip/icon.xpm dvdrip.xpm
	make_desktop_entry dvdrip dvd::rip

	mydoc="Changes* Credits README TODO" perl-module_src_install
}

pkg_postinst() {
	# bug 173924
	if use fping; then
		ewarn "For dvdrip-master to work correctly with cluster mode,"
		ewarn "the fping binary must be setuid."
		ewarn ""
		ewarn "Run this command to fix it:"
		ewarn "chmod u=rwsx,g=rx,o=rx /usr/sbin/fping"
		ewarn ""
		ewarn "Note that this is a security risk when enabled."
	fi
}