[gentoo-commits] gentoo-x86 commit in media-libs/giflib: giflib-4.1.6-r3.ebuild ChangeLog

[Michal Gorny (mgorny)]

mgorny      14/07/03 20:19:00

  Modified:             ChangeLog
  Added:                giflib-4.1.6-r3.ebuild
  Log:
  Backport the multilib support to giflib-4.1.6 to ease stabilization.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

Revision  Changes    Path
1.78                 media-libs/giflib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/giflib/ChangeLog?rev=1.78&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/giflib/ChangeLog?rev=1.78&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/giflib/ChangeLog?r1=1.77&r2=1.78

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/giflib/ChangeLog,v
retrieving revision 1.77
retrieving revision 1.78
diff -u -r1.77 -r1.78
--- ChangeLog	18 Jun 2014 19:30:10 -0000	1.77
+++ ChangeLog	3 Jul 2014 20:19:00 -0000	1.78
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/giflib
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/giflib/ChangeLog,v 1.77 2014/06/18 19:30:10 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/giflib/ChangeLog,v 1.78 2014/07/03 20:19:00 mgorny Exp $
+
+*giflib-4.1.6-r3 (03 Jul 2014)
+
+  03 Jul 2014; Michał Górny <mgorny@g.o> +giflib-4.1.6-r3.ebuild:
+  Backport the multilib support to giflib-4.1.6 to ease stabilization.
 
   18 Jun 2014; Michał Górny <mgorny@g.o> giflib-4.2.3-r1.ebuild:
   Update dependencies to require guaranteed EAPI=5 or multilib ebuilds, bug



1.1                  media-libs/giflib/giflib-4.1.6-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/giflib/giflib-4.1.6-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/giflib/giflib-4.1.6-r3.ebuild?rev=1.1&content-type=text/plain

Index: giflib-4.1.6-r3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/giflib/giflib-4.1.6-r3.ebuild,v 1.1 2014/07/03 20:19:00 mgorny Exp $

EAPI=5

inherit eutils libtool multilib-minimal

DESCRIPTION="Library to handle, display and manipulate GIF images"
HOMEPAGE="http://sourceforge.net/projects/giflib/"
SRC_URI="mirror://sourceforge/giflib/${P}.tar.bz2"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="rle static-libs X"

RDEPEND="
	rle? ( media-libs/urt )
	X? ( >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}] )
	abi_x86_32? (
		!<=app-emulation/emul-linux-x86-baselibs-20140406-r1
		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32]
	)"
DEPEND="${RDEPEND}"

src_prepare() {
	epatch "${FILESDIR}"/${P}-gif2rle.patch
	epatch "${FILESDIR}"/${P}-giffix-null-Extension-fix.patch
	elibtoolize
	epunt_cxx
}

multilib_src_configure() {
	local myconf=()

	# prevent circular depend #111455
	if multilib_is_native_abi && has_version media-libs/urt ; then
		myconf+=( $(use_enable rle) )
	else
		myconf+=( --disable-rle )
	fi

	ECONF_SOURCE=${S} \
	econf \
		--disable-gl \
		$(use_enable static-libs static) \
		$(use_enable X x11) \
		"${myconf[@]}"
}

multilib_src_install_all() {
	# for static libs the .la file is required if build with +rle or +X
	use static-libs || prune_libtool_files --all

	dodoc AUTHORS BUGS ChangeLog NEWS ONEWS README TODO doc/*.txt
	dohtml -r doc
}