[gentoo-commits] repo/gentoo:master commit in: media-sound/bluez-alsa/

[Lars Wendler]

commit:     f8583e492242ffce07979b2e00e615dc4472dafd
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 26 16:46:04 2020 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Sun Jan 26 16:54:27 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f8583e49

media-sound/bluez-alsa: Bump to version 2.1.0

Package-Manager: Portage-2.3.85, Repoman-2.3.20
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 media-sound/bluez-alsa/Manifest                |  1 +
 media-sound/bluez-alsa/bluez-alsa-2.1.0.ebuild | 74 ++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/media-sound/bluez-alsa/Manifest b/media-sound/bluez-alsa/Manifest
index c5f539c2891..ca261553f76 100644
--- a/media-sound/bluez-alsa/Manifest
+++ b/media-sound/bluez-alsa/Manifest
@@ -1,2 +1,3 @@
 DIST bluez-alsa-1.4.0.tar.gz 102539 BLAKE2B 8e640ba5c0cadfa5478885dc6affef790bd50fe04821602156a598082efc8733f0917a91240af7881f980e89ec0e36801e537feedec3ce357087b040f852eeb0 SHA512 fa4ad21c7b9ac200cdc7628bf0276bbb0beac94066a6c5e69c47a5286f6e13a7dc61caab23acbb14a37c2b97894c425052a09adb8f967038f6fd99557208629f
 DIST bluez-alsa-2.0.0.tar.gz 116895 BLAKE2B 97dfd3364259e8a633de0259c84efe4dc4a80a9f388620200c44136844af6f3e101bf6d49931e1b5cd466d4b1ff13b2a7b9284d4599db72039ee3c5afa5800ba SHA512 21152be594421cd00056e94065dcf767ca01f7b040117974315f97aab45db020264e33dabddac7fee12834a4ada9073b9ff680c25d8775b47604cb0bec638a7b
+DIST bluez-alsa-2.1.0.tar.gz 129650 BLAKE2B 6ab1b618828b5ad6f35c62a711cd24a51536ae4e013227addff8193bb522e0e7322d054fa8e688b5322ec59f6d08a654760ebb5792a637fa11536afc41c5dba5 SHA512 8b6d520f5733799b1c509052ac527377cbe5e0106b75180f783f83071246937b5dc7a22c2d27f3e9e331c52c74be59f3bc6d78caab97b41f06cfd6ed5191b584

diff --git a/media-sound/bluez-alsa/bluez-alsa-2.1.0.ebuild b/media-sound/bluez-alsa/bluez-alsa-2.1.0.ebuild
new file mode 100644
index 00000000000..fc03fb3b79e
--- /dev/null
+++ b/media-sound/bluez-alsa/bluez-alsa-2.1.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools multilib-minimal systemd
+
+DESCRIPTION="Bluetooth Audio ALSA Backend"
+HOMEPAGE="https://github.com/Arkq/bluez-alsa"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Arkq/${PN}"
+else
+	SRC_URI="https://github.com/Arkq/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="aac debug hcitop ldac ofono static-libs test upower"
+RESTRICT="!test? ( test )"
+
+# bluez-alsa does not directly link to upower but
+# is using the upower interface via dbus calls.
+RDEPEND="
+	>=dev-libs/glib-2.26[dbus,${MULTILIB_USEDEP}]
+	>=media-libs/alsa-lib-1.1.2[${MULTILIB_USEDEP}]
+	>=media-libs/sbc-1.2[${MULTILIB_USEDEP}]
+	>=net-wireless/bluez-5.0[${MULTILIB_USEDEP}]
+	sys-apps/dbus[${MULTILIB_USEDEP}]
+	sys-libs/readline:0=
+	aac? ( >=media-libs/fdk-aac-0.1.1:=[${MULTILIB_USEDEP}] )
+	hcitop? (
+		dev-libs/libbsd
+		sys-libs/ncurses:0=
+	)
+	ldac? ( >=media-libs/libldac-2.0.0 )
+	upower? ( sys-power/upower )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--enable-rfcomm
+		$(use_enable aac)
+		$(use_enable debug)
+		$(use_enable ofono)
+		$(use_enable static-libs static)
+		$(use_enable test)
+		$(multilib_native_use_enable hcitop)
+		$(multilib_native_use_enable ldac)
+		$(multilib_native_use_enable upower)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	default
+	find "${ED}" -type f -name "*.la" -delete || die
+
+	newinitd "${FILESDIR}"/bluealsa-init.d bluealsa
+	newconfd "${FILESDIR}"/bluealsa-conf.d-2 bluealsa
+	systemd_dounit "${FILESDIR}"/bluealsa.service
+}
+
+pkg_postinst() {
+	elog "Users can use this service when they are members of the \"audio\" group."
+}