[gentoo-commits] repo/gentoo:master commit in: dev-python/mkdocs/

[Andrew Ammerlaan]

commit:     8d113c5851b2fcbd9387cae5e4622536b69bfbbb
Author:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
AuthorDate: Fri Jun 11 13:41:54 2021 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Fri Jun 11 13:43:16 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8d113c58

dev-python/mkdocs: add version 1.2.1

Package-Manager: Portage-3.0.19, Repoman-3.0.3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>

 dev-python/mkdocs/Manifest            |  1 +
 dev-python/mkdocs/mkdocs-1.2.1.ebuild | 75 +++++++++++++++++++++++++++++++++++
 2 files changed, 76 insertions(+)

diff --git a/dev-python/mkdocs/Manifest b/dev-python/mkdocs/Manifest
index 05f2d1a46f5..99a2771b865 100644
--- a/dev-python/mkdocs/Manifest
+++ b/dev-python/mkdocs/Manifest
@@ -1 +1,2 @@
 DIST mkdocs-1.1.2.tar.gz 6987352 BLAKE2B 98bf604aa15eac693368e77e6658c3906909a0cdc323772550a65c35cc301929cdc136919a612438563cefd74c9076b2e273cb89e3ffbe04bff2a419e6e36513 SHA512 bf0e5ba8a15524ebe433fce9f2d16404922850ca562339d60e7860e243f9523321cbab5dca1f276a71d3158c7b1bfadfa25b134da50ef1cedc0b1a9658b6f10c
+DIST mkdocs-1.2.1.tar.gz 6918891 BLAKE2B a17fc551735de28391809971fdf8973c5adf23e512286041eab73bde02ae9ae597e357f4dcbb3fa9ea90a4b47e12a8390c3626641e89da45770b4df6f9d66029 SHA512 c1f9c3a46fd2c5d6819ea069bd48a82cbf5816bc1586a88e9eb776b2376106d9d5f8a0d9a70a9f9f56e39e9f29eaa3cbfa26a8c588acf568bde86f4028af9796

diff --git a/dev-python/mkdocs/mkdocs-1.2.1.ebuild b/dev-python/mkdocs/mkdocs-1.2.1.ebuild
new file mode 100644
index 00000000000..842e38bc6ad
--- /dev/null
+++ b/dev-python/mkdocs/mkdocs-1.2.1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Project documentation with Markdown"
+HOMEPAGE="https://www.mkdocs.org https://github.com/mkdocs/mkdocs"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="doc"
+
+BDEPEND="
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/mdx_gh_links[${PYTHON_USEDEP}]
+			dev-python/mkdocs-redirects[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+RDEPEND="
+	>=dev-python/Babel-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/click-3.3[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/markdown-3.2.1[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+	>=dev-python/watchdog-2.0[${PYTHON_USEDEP}]
+	>=dev-python/ghp-import-1.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml_env_tag-0.1[${PYTHON_USEDEP}]
+	>=dev-python/importlib_metadata-3.10[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.5[${PYTHON_USEDEP}]
+	>=dev-python/mergedeep-1.3.4[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests --install nose
+
+python_prepare_all() {
+	# Tests fails if additional themes are installed
+	sed -i -e 's:test_get_themes:_&:' \
+		mkdocs/tests/utils/utils_tests.py || die
+
+	# Skip this network test, "does not appear to be an IPv4 or IPv6 address"
+	sed -i -e 's/test_IP_normalization/_&/' \
+		mkdocs/tests/config/config_options_tests.py || die
+
+	# livereload has been dropped in this release, this test is a remnant
+	rm mkdocs/tests/livereload_tests.py || die
+
+	# fix apparent typo in test (importing wrong thing)
+	sed -i -e 's/from localization import/from mkdocs.localization import/g' \
+		mkdocs/tests/theme_tests.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	default
+	if use doc; then
+		# cannot just do mkdocs build, because that fails if
+		# the package isn't already installed
+		python -m mkdocs build || die "Failed to make docs"
+		# Colliding files found by ecompress:
+		rm site/sitemap.xml.gz || die
+		HTML_DOCS=( "site/." )
+	fi
+}