[gentoo-commits] repo/gentoo:master commit in: sci-geosciences/liblas/

[Andreas Sturmlechner]

commit:     0a0b83a051241dfce7d23401f5abe1436c014e74
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri May 24 19:07:21 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri May 24 19:25:47 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0a0b83a0

sci-geosciences/liblas: EAPI-7 bump, add missing slot ops

Package-Manager: Portage-2.3.66, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 sci-geosciences/liblas/liblas-1.8.1-r2.ebuild | 49 +++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/sci-geosciences/liblas/liblas-1.8.1-r2.ebuild b/sci-geosciences/liblas/liblas-1.8.1-r2.ebuild
new file mode 100644
index 00000000000..11e130b1404
--- /dev/null
+++ b/sci-geosciences/liblas/liblas-1.8.1-r2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils
+
+DESCRIPTION="C/C++ library for manipulating the LAS LiDAR format common in GIS"
+HOMEPAGE="https://github.com/libLAS/libLAS/"
+SRC_URI="https://github.com/libLAS/libLAS/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="gdal"
+
+DEPEND="
+	dev-libs/boost:=
+	sci-geosciences/laszip
+	sci-libs/libgeotiff:=
+	gdal? ( sci-libs/gdal:= )
+"
+RDEPEND="${DEPEND}"
+
+# tests known to fail due to LD_LIBRARY_PATH issue
+RESTRICT="test"
+
+S="${WORKDIR}/libLAS-${PV}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.8.0_remove-std-c++98.patch
+	"${FILESDIR}"/${P}-fix-overload-call.patch # bug 661654
+)
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	# add missing linkage
+	sed -e 's:${LAS2COL} ${LIBLAS_C_LIB_NAME}:& ${CMAKE_THREAD_LIBS_INIT}:' \
+		-i "${S}/apps/CMakeLists.txt" || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DLIBLAS_LIB_SUBDIR=$(get_libdir)
+		-DWITH_GDAL=$(usex gdal)
+	)
+	cmake-utils_src_configure
+}