[gentoo-commits] repo/gentoo:master commit in: x11-misc/redshift/

[Sebastian Pipping]

commit:     fb6b2788618c34808d25853f4625afb63a7d0bcc
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Sun Jan  3 04:15:04 2016 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Sun Jan  3 04:16:30 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fb6b2788

x11-misc/redshift: 1.11 (bug #568164)

 x11-misc/redshift/Manifest             |  1 +
 x11-misc/redshift/redshift-1.11.ebuild | 86 ++++++++++++++++++++++++++++++++++
 2 files changed, 87 insertions(+)

diff --git a/x11-misc/redshift/Manifest b/x11-misc/redshift/Manifest
index f4580aa..f4c71a7 100644
--- a/x11-misc/redshift/Manifest
+++ b/x11-misc/redshift/Manifest
@@ -1 +1,2 @@
 DIST redshift-1.10.tar.gz 519595 SHA256 f7a1ca1eccf662995737e14f894c2b15193923fbbe378d151e346a8013644f16 SHA512 0fd3867d883268279b6297a0eec1bcdc20022a893b935fd4767fbfc0797ad044777af4cf1efcfec7a1f362306ae88869f73b20c91b29844e9e201881c5b56260 WHIRLPOOL 3aa705a5afedb4ebb7fcab98afec0d69ea5c8c7cd280eee72fc2aff260df85d00b0af722ce6fc1e3e04d000e30d37eb2ddca8b82d6a25e9d587f4e0d98bfc626
+DIST redshift-1.11.tar.gz 543804 SHA256 a89cee0dc822fa2bfda0703d8ecedeccc08da3aebdf1880593f28da81c3dc879 SHA512 bcdb4c120efec3955f4f91f1290db0679e987e25d6610bd90ee8540a96bb11338e36b10680736490ea0b7e9eca5bc195b51767a5badf0b80495dc3da44c4ed8c WHIRLPOOL c8bb70fde237bc7fc841d9272c029fe92c7ad564711a377a578cb6c126ae5a24d2756d3df3dc2de8053738301170040284c65a5e1da66fb29755a8e4a4bf5f17

diff --git a/x11-misc/redshift/redshift-1.11.ebuild b/x11-misc/redshift/redshift-1.11.ebuild
new file mode 100644
index 0000000..e27ddad
--- /dev/null
+++ b/x11-misc/redshift/redshift-1.11.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{3_3,3_4} )
+
+inherit systemd autotools eutils gnome2-utils python-r1
+
+DESCRIPTION="A screen color temperature adjusting software"
+HOMEPAGE="http://jonls.dk/redshift/"
+SRC_URI="https://github.com/jonls/redshift/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="appindicator geoclue gtk nls"
+
+COMMON_DEPEND=">=x11-libs/libX11-1.4
+	x11-libs/libXxf86vm
+	x11-libs/libxcb
+	x11-libs/libdrm
+	geoclue? ( app-misc/geoclue:2.0 dev-libs/glib:2 )
+	gtk? ( ${PYTHON_DEPS} )"
+RDEPEND="${COMMON_DEPEND}
+	gtk? ( dev-python/pygobject[${PYTHON_USEDEP}]
+		x11-libs/gtk+:3[introspection]
+		dev-python/pyxdg[${PYTHON_USEDEP}] )"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.50
+	nls? ( sys-devel/gettext )
+	appindicator? ( dev-libs/libappindicator )
+"
+
+src_prepare() {
+	epatch_user
+	eautoreconf
+}
+
+src_configure() {
+	python_export_best
+
+	econf \
+		--disable-silent-rules \
+		$(use_enable nls) \
+		--enable-drm \
+		--enable-randr \
+		--enable-vidmode \
+		--disable-wingdi \
+		\
+		--disable-corelocation \
+		--disable-geoclue \
+		$(use_enable geoclue geoclue2) \
+		\
+		$(use_enable gtk gui) \
+		--with-systemduserunitdir="$(systemd_get_userunitdir)" \
+		--disable-quartz \
+		--disable-ubuntu
+}
+
+_impl_specific_src_install() {
+	emake DESTDIR="${D}" pythondir="$(python_get_sitedir)" \
+			-C src/redshift-gtk install
+}
+
+src_install() {
+	emake DESTDIR="${D}" UPDATE_ICON_CACHE=/bin/true install
+
+	if use gtk; then
+		python_foreach_impl _impl_specific_src_install
+		python_replicate_script "${D}"/usr/bin/redshift-gtk
+		dosym redshift-gtk /usr/bin/gtk-redshift
+	fi
+}
+
+pkg_preinst() {
+	use gtk && gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	use gtk && gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	use gtk && gnome2_icon_cache_update
+}