[gentoo-commits] gentoo-x86 commit in net-proxy/tsocks: ChangeLog tsocks-1.8_beta5-r5.ebuild

[Alin Nastac (mrness)]

mrness      09/06/20 12:03:13

  Modified:             ChangeLog
  Added:                tsocks-1.8_beta5-r5.ebuild
  Log:
  Link tsocks-saveme dinamically (#273339). Migrate to EAPI 2.
  (Portage version: 2.1.6.13/cvs/Linux x86_64)

Revision  Changes    Path
1.29                 net-proxy/tsocks/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/tsocks/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/tsocks/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/tsocks/ChangeLog?r1=1.28&r2=1.29

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-proxy/tsocks/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog	18 Feb 2009 00:01:46 -0000	1.28
+++ ChangeLog	20 Jun 2009 12:03:13 -0000	1.29
@@ -1,6 +1,12 @@
 # ChangeLog for net-proxy/tsocks
 # Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/tsocks/ChangeLog,v 1.28 2009/02/18 00:01:46 mrness Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/tsocks/ChangeLog,v 1.29 2009/06/20 12:03:13 mrness Exp $
+
+*tsocks-1.8_beta5-r5 (20 Jun 2009)
+
+  20 Jun 2009; Alin Năstac <mrness@g.o>
+  +files/tsocks-1.8_beta5-gentoo-r3.patch, +tsocks-1.8_beta5-r5.ebuild:
+  Link tsocks-saveme dinamically (#273339). Migrate to EAPI 2.
 
 *tsocks-1.8_beta5-r4 (18 Feb 2009)
 



1.1                  net-proxy/tsocks/tsocks-1.8_beta5-r5.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/tsocks/tsocks-1.8_beta5-r5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/tsocks/tsocks-1.8_beta5-r5.ebuild?rev=1.1&content-type=text/plain

Index: tsocks-1.8_beta5-r5.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-proxy/tsocks/tsocks-1.8_beta5-r5.ebuild,v 1.1 2009/06/20 12:03:13 mrness Exp $

EAPI="2"

inherit multilib eutils autotools toolchain-funcs

DESCRIPTION="Transparent SOCKS v4 proxying library"
HOMEPAGE="http://tsocks.sourceforge.net/"
SRC_URI="mirror://sourceforge/tsocks/${PN}-${PV/_}.tar.gz
	tordns? ( mirror://gentoo/${PN}-${PV/_beta/b}-tordns1-gentoo-r1.patch.gz )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="tordns"

S="${WORKDIR}/${P%%_*}"

src_prepare() {
	epatch "${FILESDIR}/${P}-gentoo-r3.patch"
	epatch "${FILESDIR}/${P}-bsd.patch"
	use tordns && epatch "../${PN}-${PV/_beta/b}-tordns1-gentoo-r1.patch"
	eautoreconf
}

src_configure() {
	tc-export CC

	# NOTE: the docs say to install it into /lib. If you put it into
	# /usr/lib and add it to /etc/ld.so.preload on many systems /usr isn't
	# mounted in time :-( (Ben Lutgens) <lamer@g.o>
	econf \
		--with-conf=/etc/socks/tsocks.conf \
		--libdir=/$(get_libdir) || die "configure failed"
}

src_compile() {
	# Fix QA notice lack of SONAME
	emake DYNLIB_FLAGS=-Wl,--soname,libtsocks.so.${PV/_beta*} || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
	newbin validateconf tsocks-validateconf
	newbin saveme tsocks-saveme
	dobin inspectsocks
	insinto /etc/socks
	doins tsocks.conf.*.example
	dodoc FAQ
	use tordns && dodoc README*
}

pkg_postinst() {
	einfo "Make sure you create /etc/socks/tsocks.conf from one of the examples in that directory"
	einfo "The following executables have been renamed:"
	einfo "    /usr/bin/saveme renamed to tsocks-saveme"
	einfo "    /usr/bin/validateconf renamed to tsocks-validateconf"
}