[gentoo-commits] gentoo-x86 commit in media-gfx/openmesh: openmesh-2.2.ebuild ChangeLog

[Justin Bronder (jsbronder)]

jsbronder    12/06/28 19:35:06

  Modified:             ChangeLog
  Added:                openmesh-2.2.ebuild
  Log:
  bump to 2.2
  
  (Portage version: 2.1.10.57/cvs/Linux x86_64)

Revision  Changes    Path
1.23                 media-gfx/openmesh/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/openmesh/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/openmesh/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/openmesh/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/openmesh/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	8 Jun 2012 02:55:55 -0000	1.22
+++ ChangeLog	28 Jun 2012 19:35:06 -0000	1.23
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/openmesh
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/openmesh/ChangeLog,v 1.22 2012/06/08 02:55:55 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/openmesh/ChangeLog,v 1.23 2012/06/28 19:35:06 jsbronder Exp $
+
+*openmesh-2.2 (28 Jun 2012)
+
+  28 Jun 2012; Justin Bronder <jsbronder@g.o> +openmesh-2.2.ebuild:
+  bump to 2.2
 
   08 Jun 2012; Zac Medico <zmedico@g.o> openmesh-2.0_rc5.ebuild:
   inherit flag-o-matic for append-cppflags



1.1                  media-gfx/openmesh/openmesh-2.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/openmesh/openmesh-2.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/openmesh/openmesh-2.2.ebuild?rev=1.1&content-type=text/plain

Index: openmesh-2.2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/openmesh/openmesh-2.2.ebuild,v 1.1 2012/06/28 19:35:06 jsbronder Exp $

EAPI="3"
inherit eutils cmake-utils

MY_PN="OpenMesh"
MY_PV="${PV/_rc/-RC}"
S="${WORKDIR}/${MY_PN}-${MY_PV}"

DESCRIPTION="A generic and efficient data structure for representing and manipulating polygonal meshes"
HOMEPAGE="http://www.openmesh.org/"
SRC_URI="http://openmesh.org/fileadmin/${PN}-files/${MY_PV/-RC/RC}/${MY_PN}-${MY_PV}.tar.bz2"

# See COPYING.EXCEPTIONS
LICENSE="LGPL-3 as-is"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="qt4 static-libs"

RDEPEND="qt4? ( x11-libs/qt-gui:4
	x11-libs/qt-opengl:4
	media-libs/freeglut )"
DEPEND="${RDEPEND}"

src_prepare() {
	# Fix libdir and remove rpath.
	sed -i \
		-e "s|\(set (ACG_PROJECT_LIBDIR \"\).*|\1$(get_libdir)/\")|" \
		-e "s|\(set (ACG_PROJECT_PLUGINDIR \"\)lib\(.*\)|\1$(get_libdir)\2|" \
		-e "s|\(BUILD_WITH_INSTALL_RPATH \)1|\1 0|" \
		-e "s|\(SKIP_BUILD_RPATH\) 0|\1 1|" \
		-e '/^ *INSTALL_RPATH/d' \
		cmake/ACGCommon.cmake || die

	if ! use static-libs; then
		sed -i "s|\(SHARED\)ANDSTATIC|\1|" \
			src/${MY_PN}/{Core,Tools}/CMakeLists.txt || die
		sed -i '/OpenMeshCoreStatic/d' \
			src/${MY_PN}/Tools/CMakeLists.txt || die
	fi
}

src_configure() {
	mycmakeargs="$(cmake-utils_use_build "qt4" "APPS")"
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	dodoc LICENSE/* README CHANGELOG || die
}