[gentoo-commits] repo/gentoo:master commit in: dev-python/paste/

[Matthew Thode]

commit:     17fdfcf014ab5f0a78a46f936c972c28f8377094
Author:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
AuthorDate: Wed Apr 10 04:05:18 2019 +0000
Commit:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
CommitDate: Wed Apr 10 05:07:56 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=17fdfcf0

dev-python/paste: 3.0.7 bump

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Matthew Thode <prometheanfire <AT> gentoo.org>

 dev-python/paste/Manifest           |  1 +
 dev-python/paste/paste-3.0.7.ebuild | 72 +++++++++++++++++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/dev-python/paste/Manifest b/dev-python/paste/Manifest
index 8f60a664adb..6d88e672f4f 100644
--- a/dev-python/paste/Manifest
+++ b/dev-python/paste/Manifest
@@ -1 +1,2 @@
 DIST Paste-2.0.3.tar.gz 643935 BLAKE2B 140f88cbab40728713a052e5aca0c7f14336d526a2c7bcd6a279fcdd13b14ed83938f69997182b43d2a83a76f51586c3b9132428f0f9c9e9ba08b6ff820827b9 SHA512 174b06d77bc6e1d4079e8de7df40412ffda098364efd4e3f915f858be1188c8a6fb546fe4ab981ccc067ec77b7171083b2469e7db6fc3b777d5a24151c928362
+DIST Paste-3.0.7.tar.gz 628999 BLAKE2B c91bb228fc2c36da1e7d487d521b9f57df19f4cb76731ec8ac17786aae087fe820760d19798a8da0ab6ce50f24b8a1fcb9d5189e6c48cffbda75ddfc9cf9f617 SHA512 adf823d208065b00a4bf1473e7550a1e0907d1da88000e87ea3a5dfb36f22c2bb33dda21ccf096da1512a0f2db2ad540a66efe751bbab8bfb49cd4ad456d5460

diff --git a/dev-python/paste/paste-3.0.7.ebuild b/dev-python/paste/paste-3.0.7.ebuild
new file mode 100644
index 00000000000..0191f718b00
--- /dev/null
+++ b/dev-python/paste/paste-3.0.7.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} )
+
+inherit distutils-r1
+
+MY_PN="Paste"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Tools for using a Web Server Gateway Interface stack"
+HOMEPAGE="https://pypi.org/project/Paste/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris"
+IUSE="doc flup openid"
+
+RDEPEND="dev-python/namespace-paste[${PYTHON_USEDEP}]
+	>=dev-python/six-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/tempita-0.5.2_pre20130828[${PYTHON_USEDEP}]
+	flup? ( dev-python/flup[$(python_gen_usedep 'python2*')] )
+	openid? ( dev-python/python-openid[$(python_gen_usedep 'python2*')] )"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	# Disable failing tests.
+	rm -f tests/test_cgiapp.py || die
+	sed \
+		-e "s/test_find_file/_&/" \
+		-e "s/test_deep/_&/" \
+		-e "s/test_static_parser/_&/" \
+		-i tests/test_urlparser.py || die "sed failed"
+
+	# Remove a test that runs against the paste website.
+	rm -f tests/test_proxy.py || die
+
+	local PATCHES=(
+		"${FILESDIR}"/${PN}-2.0.3-unbundle-tempita.patch
+		)
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile egg_info --egg-base "${BUILD_DIR}/lib"
+}
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	nosetests -P -v || die "Tests fail with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install egg_info --egg-base "${BUILD_DIR}/lib"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+	distutils-r1_python_install_all
+
+	find "${D}" -name '*.pth' -delete || die
+}