[gentoo-commits] gentoo-x86 commit in gnome-extra/avant-window-navigator: ChangeLog avant-window-navigator-0.4.2.ebuild

[Jeroen Roovers (jer)]

jer         14/05/21 14:16:16

  Modified:             ChangeLog
  Added:                avant-window-navigator-0.4.2.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.42                 gnome-extra/avant-window-navigator/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/avant-window-navigator/ChangeLog?rev=1.42&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/avant-window-navigator/ChangeLog?rev=1.42&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/avant-window-navigator/ChangeLog?r1=1.41&r2=1.42

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/avant-window-navigator/ChangeLog,v
retrieving revision 1.41
retrieving revision 1.42
diff -u -r1.41 -r1.42
--- ChangeLog	21 May 2014 14:01:32 -0000	1.41
+++ ChangeLog	21 May 2014 14:16:16 -0000	1.42
@@ -1,6 +1,13 @@
 # ChangeLog for gnome-extra/avant-window-navigator
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/avant-window-navigator/ChangeLog,v 1.41 2014/05/21 14:01:32 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/avant-window-navigator/ChangeLog,v 1.42 2014/05/21 14:16:16 jer Exp $
+
+*avant-window-navigator-0.4.2 (21 May 2014)
+
+  21 May 2014; Jeroen Roovers <jer@g.o>
+  +avant-window-navigator-0.4.2.ebuild,
+  +files/avant-window-navigator-0.4.2-Timeout.patch:
+  Version bump.
 
   21 May 2014; Jeroen Roovers <jer@g.o>
   files/avant-window-navigator-0.4.0-underlinking.patch:



1.1                  gnome-extra/avant-window-navigator/avant-window-navigator-0.4.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/avant-window-navigator/avant-window-navigator-0.4.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/avant-window-navigator/avant-window-navigator-0.4.2.ebuild?rev=1.1&content-type=text/plain

Index: avant-window-navigator-0.4.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/avant-window-navigator/avant-window-navigator-0.4.2.ebuild,v 1.1 2014/05/21 14:16:16 jer Exp $

EAPI=5
GCONF_DEBUG=no
GNOME2_LA_PUNT=yes
PYTHON_COMPAT=( python2_7 )
VALA_MIN_API_VERSION=0.10
VALA_USE_DEPEND=vapigen

inherit autotools eutils gnome2 python-single-r1 vala

DESCRIPTION="A dock-like bar which sits at the bottom of the screen"
HOMEPAGE="https://github.com/p12tic/awn"
SRC_URI="${HOMEPAGE}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2 LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc +gconf"

RDEPEND="
	${PYTHON_DEPS}
	>=dev-libs/dbus-glib-0.80
	>=dev-libs/glib-2.16
	>=dev-python/pygtk-2.12:2
	>=gnome-base/libgtop-2
	>=x11-libs/gtk+-2.12:2
	>=x11-libs/libdesktop-agnostic-0.3.9[gconf?]
	>=x11-libs/libwnck-2.22:1
	dev-python/dbus-python
	dev-python/librsvg-python
	dev-python/pycairo
	dev-python/pygobject:2
	dev-python/pyxdg
	dev-vcs/bzr
	x11-libs/libX11
	x11-libs/libXcomposite
	x11-libs/libXext
	x11-libs/libXrender
	gconf? ( >=gnome-base/gconf-2 )
	"
DEPEND="
	${RDEPEND}
	$(vala_depend)
	!<gnome-extra/avant-window-navigator-extras-${PV}
	dev-util/intltool
	sys-devel/gettext
	virtual/pkgconfig
	x11-proto/xproto
	doc? ( dev-util/gtk-doc )
"

S="${WORKDIR}/awn-${PV}"

pkg_setup() {
	python-single-r1_pkg_setup

	G2CONF="--disable-static
		--disable-pymod-checks
		$(use_enable doc gtk-doc)
		$(use_enable gconf schemas-install)
		--disable-shave
		--with-html-dir=/usr/share/doc/${PF}/html"

	DOCS="AUTHORS ChangeLog NEWS README TODO"
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-0.4.0-underlinking.patch
	epatch "${FILESDIR}"/${PN}-0.4.2-Timeout.patch
	eautoreconf

	python_fix_shebang awn-settings/awnSettings{.py.in,Helper.py}

	gnome2_src_prepare
	vala_src_prepare
}